vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

sed.vim (5879B)


      1 " Vim syntax file
      2 " Language:		sed
      3 " Maintainer:		Doug Kearns <dougkearns@gmail.com>
      4 " Previous Maintainer:	Haakon Riiser <hakonrk@fys.uio.no>
      5 " Contributor:		Jack Haden-Enneking
      6 " Last Change:		2026 Mar 06
      7 
      8 " quit when a syntax file was already loaded
      9 if exists("b:current_syntax")
     10   finish
     11 endif
     12 
     13 syn keyword sedTodo	contained TODO FIXME XXX
     14 
     15 syn match sedError	"\S"
     16 
     17 syn match sedWhitespace "\s\+" contained
     18 syn match sedSemicolon	";"
     19 
     20 " Addresses {{{1
     21 syn match sedAddress	"\d\+\|\$"
     22 
     23 " GNU extensions
     24 syn match sedAddress	"\d\+\~\d\+"
     25 syn match sedAddress	"\~\d\+"
     26 syn match sedAddress	"[-+]\d\+"
     27 
     28 syn region sedAddress
     29       \ matchgroup=Delimiter
     30       \ start="[{,;]\s*/\%(\\/\)\="lc=1
     31       \ skip="[^\\]\%(\\\\\)*\\/"
     32       "\ GNU extensions
     33       \ end="/\%(IM\|MI\|[IM]\)\="
     34       \ contains=sedTab,sedRegexpMeta
     35 syn region sedAddress
     36       \ matchgroup=Delimiter
     37       \ start="^\s*/\%(\\/\)\="
     38       "\ GNU extensions
     39       \ skip="[^\\]\%(\\\\\)*\\/"
     40       \ end="/\%(IM\|MI\|[IM]\)\="
     41       \ contains=sedTab,sedRegexpMeta
     42 " }}}
     43 
     44 syn match sedFunction	"[dDgGhHlnNpPqQx=]\s*\%($\|;\)" contains=sedSemicolon,sedWhitespace
     45 if exists("g:sed_dialect") && g:sed_dialect ==? "bsd"
     46   syn match sedComment	"^\s*#.*$" contains=sedTodo
     47 else
     48   syn match sedFunction	"[dDgGhHlnNpPqQx=]\s*\ze#" contains=sedSemicolon,sedWhitespace
     49   syn match sedComment	"#.*$" contains=sedTodo
     50 endif
     51 syn match sedLabel	":[^;]*"
     52 syn match sedLineCont	"^\%(\\\\\)*\\$" contained
     53 syn match sedLineCont	"[^\\]\%(\\\\\)*\\$"ms=e contained
     54 syn match sedSpecial	"[{},!]"
     55 
     56 " continue to silently support the old name
     57 let s:highlight_tabs = v:false
     58 if exists("g:highlight_sedtabs") || get(g:, "sed_highlight_tabs", 0)
     59   let s:highlight_tabs = v:true
     60   syn match sedTab	"\t" contained
     61 endif
     62 
     63 " Append/Change/Insert
     64 syn region sedACI	matchgroup=sedFunction start="[aci]\\$" matchgroup=NONE end="^.*$" contains=sedLineCont,sedTab
     65 
     66 syn region sedBranch	matchgroup=sedFunction start="[bt]" matchgroup=sedSemicolon end=";\|$" contains=sedWhitespace
     67 syn region sedRW	matchgroup=sedFunction start="[rw]" matchgroup=sedSemicolon end=";\|$" contains=sedWhitespace
     68 
     69 " Substitution/transform with various delimiters
     70 syn region sedFlagWrite	    matchgroup=sedFlag start="w" matchgroup=sedSemicolon end=";\|$" contains=sedWhitespace contained
     71 syn match sedFlag	    "[[:digit:]gpI]*w\=" contains=sedFlagWrite contained
     72 syn match sedRegexpMeta	    "[.*^$]" contained
     73 syn match sedRegexpMeta	    "\\." contains=sedTab contained
     74 syn match sedRegexpMeta	    "\[\^\=\]\=\%(\[:.\{-}:\]\|\[\..\{-}\.\]\|\[=.\{-}=\]\|[^]]\)*\]" contains=sedTab contained
     75 syn match sedRegexpMeta	    "\\{\d\*,\d*\\}" contained
     76 syn match sedRegexpMeta	    "\\%(.\{-}\\)" contains=sedTab contained
     77 syn match sedReplaceMeta    "&\|\\\%($\|.\)" contains=sedTab contained
     78 
     79 " Metacharacters: $ * . \ ^ [ ~
     80 " @ is used as delimiter and treated on its own below
     81 let s:at = char2nr("@")
     82 let s:i = char2nr(" ") " ASCII: 32, EBCDIC: 64
     83 if has("ebcdic")
     84   let s:last = 255
     85 else
     86   let s:last = 126
     87 endif
     88 let s:metacharacters = '$*.\^[~'
     89 while s:i <= s:last
     90   let s:delimiter = escape(nr2char(s:i), s:metacharacters)
     91   if s:i != s:at
     92     exe 'syn region sedAddress'
     93 	  \ 'matchgroup=Delimiter'
     94 	  \ 'start=@\\' .. s:delimiter .. '\%(\\' .. s:delimiter .. '\)\=@'
     95 	  \ 'skip=@[^\\]\%(\\\\\)*\\' .. s:delimiter .. '\|\[.\{-}' .. s:delimiter .. '@'
     96 	  \ 'end=@' .. s:delimiter .. '\%(IM\|MI\|[IM]\)\=@'
     97 	  \ 'contains=sedTab,sedRegexpMeta'
     98     exe 'syn region sedRegexp' .. s:i 'contained'
     99 	  \ 'matchgroup=Delimiter'
    100 	  \ 'start=@' .. s:delimiter .. '\%(\\\\\|\\' .. s:delimiter .. '\)*@'
    101 	  \ 'end=@' .. s:delimiter .. '@me=e-1'
    102 	  \ 'nextgroup=sedReplacement' .. s:i
    103 	  \ 'contains=sedTab,sedRegexpMeta'
    104     exe 'syn region sedReplacement' .. s:i 'contained'
    105 	  \ 'matchgroup=Delimiter'
    106 	  \ 'start=@' .. s:delimiter .. '\%(\\\\\|\\' .. s:delimiter .. '\)*@'
    107 	  \ 'end=@' .. s:delimiter .. '@'
    108 	  \ 'nextgroup=@sedFlags'
    109 	  \ 'contains=sedTab,sedReplaceMeta'
    110   endif
    111   let s:i = s:i + 1
    112 endwhile
    113 syn region sedAddress
    114       \ matchgroup=Delimiter
    115       \ start=+\\\z(@\)+
    116       \ end=+\z1\%(IM\|MI\|[IM]\)\=+
    117       \ contains=sedTab,sedRegexpMeta
    118 syn region sedRegexp64 contained
    119       \ matchgroup=Delimiter
    120       \ start=+@\%(\\\\\|\\@\)*+
    121       \ end=+@+me=e-1
    122       \ nextgroup=sedReplacement64
    123       \ contains=sedTab,sedRegexpMeta
    124 syn region sedReplacement64 contained
    125       \ matchgroup=Delimiter
    126       \ start=+@\%(\\\\\|\\@\)*+
    127       \ end=+@+
    128       \ nextgroup=sedFlag
    129       \ contains=sedTab,sedReplaceMeta
    130 
    131 " Since the syntax for the substitution command is very similar to the
    132 " syntax for the transform command, I use the same pattern matching
    133 " for both commands.  There is one problem -- the transform command
    134 " (y) does not allow any flags.  To save memory, I ignore this problem.
    135 syn match sedST	"[sy]" nextgroup=sedRegexp\d\+
    136 
    137 
    138 hi def link sedAddress		Macro
    139 hi def link sedACI		NONE
    140 hi def link sedBranch		Label
    141 hi def link sedComment		Comment
    142 hi def link sedDelete		Function
    143 hi def link sedError		Error
    144 hi def link sedFlag		Type
    145 hi def link sedFlagWrite	Constant
    146 hi def link sedFunction		Function
    147 hi def link sedLabel		Label
    148 hi def link sedLineCont		Special
    149 hi def link sedPutHoldspc	Function
    150 hi def link sedReplaceMeta	Special
    151 hi def link sedRegexpMeta	Special
    152 hi def link sedRW		Constant
    153 hi def link sedSemicolon	Special
    154 hi def link sedST		Function
    155 hi def link sedSpecial		Special
    156 hi def link sedTodo		Todo
    157 hi def link sedWhitespace	NONE
    158 if s:highlight_tabs
    159   hi def link sedTab		Todo
    160 endif
    161 let s:i = char2nr(" ") " ASCII: 32, EBCDIC: 64
    162 while s:i <= s:last
    163   exe "hi def link sedRegexp" .. s:i		"Macro"
    164   exe "hi def link sedReplacement" .. s:i	"NONE"
    165   let s:i = s:i + 1
    166 endwhile
    167 
    168 unlet s:i s:last s:delimiter s:metacharacters s:at
    169 unlet s:highlight_tabs
    170 
    171 let b:current_syntax = "sed"
    172 
    173 " vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: