vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

log.vim (9598B)


      1 " Vim syntax file
      2 " Language:         Generic log file
      3 " Maintainer:       Mao-Yining <mao.yining@outlook.com>
      4 " Former Maintainer:	MTDL9 <https://github.com/MTDL9>
      5 " Latest Revision:  2025-10-31
      6 
      7 if exists('b:current_syntax')
      8   finish
      9 endif
     10 
     11 syntax case ignore
     12 
     13 " Symbols / special characters
     14 "---------------------------------------------------------------------------
     15 syn match logSymbol      display '[!@#$%^&*;:?]'
     16 
     17 " For Visual Separator and Apache CLF
     18 "---------------------------------------------------------------------------
     19 syn match logSeparator   display '-\{3,}\|=\{3,}\|#\{3,}\|\*\{3,}\|<\{3,}\|>\{3,}'
     20 syn match logSeparator   display '- - '
     21 
     22 " Strings
     23 " ------------------------------
     24 syn region logString     start=/"/  end=/"/  end=/$/  skip=/\\./ contains=logJavaError
     25 syn region logString     start=/`/  end=/`/  end=/$/  skip=/\\./ contains=logJavaError
     26 " Quoted strings, but no match on quotes like `don't`, possessive `s'` and `'s`
     27 syn region logString     start=/\(s\)\@<!'\(s \|t \)\@!/  end=/'/  end=/$/  skip=/\\./ contains=logJavaError
     28 
     29 " Numbers
     30 "---------------------------------------------------------------------------
     31 syn match logNumber      display '\<\d\+\>'
     32 syn match logNumberFloat display '\<\d\+\.\d\+\([eE][-+]\=\d\+\)\=\>'
     33 syn match logNumberFloat display '\<\d\+[eE][-+]\=\d\+\>'
     34 syn match logNumberBin   display '\<0[bB][01]\+\>'
     35 syn match logNumberOct   display '\<0[oO]\o\+\>'
     36 syn match logNumberHex   display '\<0[xX]\x\+\>'
     37 
     38 " Possible hex numbers without the '0x' prefix
     39 syn match logNumberHex   display '\<\x\{4,}\>'
     40 
     41 " Numbers in Hardware Description Languages e.g. Verilog
     42 " These must be placed after logString to ensure they take precedence
     43 syn match logNumber      display '\'d\d\+\>'
     44 syn match logNumberBin   display '\'b[01]\+\>'
     45 syn match logNumberOct   display '\'o\o\+\>'
     46 syn match logNumberHex   display '\'h\x\+\>'
     47 
     48 " Constants
     49 "---------------------------------------------------------------------------
     50 syn keyword logBoolean   true false
     51 syn keyword logNull      null nil none
     52 
     53 " Dates and Times
     54 "---------------------------------------------------------------------------
     55 " MM-DD, DD-MM, MM/DD, DD/MM
     56 syn match logDate        display '\<\d\{2}[-\/]\d\{2}\>'
     57 " YYYY-MM-DD, YYYY/MM/DD
     58 syn match logDate        display '\<\d\{4}[-\/]\d\{2}[-\/]\d\{2}\>'
     59 " DD-MM-YYYY, DD/MM/YYYY
     60 syn match logDate        display '\<\d\{2}[-\/]\d\{2}[-\/]\d\{4}\>'
     61 " First half of RFC3339 e.g. 2023-01-01T
     62 syn match logDate        display '\<\d\{4}-\d\{2}-\d\{2}T'
     63 " 'Dec 31', 'Dec 31, 2023', 'Dec 31 2023'
     64 syn match logDate        display '\<\a\{3} \d\{1,2}\(,\? \d\{4}\)\?\>'
     65 " '31-Dec-2023', '31 Dec 2023'
     66 syn match logDate        display '\<\d\{1,2}[- ]\a\{3}[- ]\d\{4}\>'
     67 " Weekday string
     68 syn keyword logDate      Mon Tue Wed Thu Fri Sat Sun
     69 " Matches 12:09:38 or 00:03:38.129Z or 01:32:12.102938 +0700 or 01:32:12.1234567890 or 21:14:18+11:00
     70 syn match logTime        display '\d\{2}:\d\{2}:\d\{2}\(\.\d\{2,9}\)\?\(\s\?[-+]\(\d\{1,2\}:\d\{2\}\|\d\{2,4}\)\|Z\)\?\>' nextgroup=logTimeZone,logSysColumn skipwhite
     71 " Time zone e.g. Z, +08:00, PST
     72 syn match logTimeZone    display 'Z\|[+-]\d\{2}:\d\{2}\|\a\{3}\>'  contained  skipwhite  nextgroup=logSysColumn
     73 " Matches time durations like 1ms or 1y 2d 23ns 3.14s 1.2e4s 3E+20h
     74 syn match logDuration    display '\(\(\(\d\+d\)\?\d\+h\)\?\d\+m\)\?\d\+\(\.\d\+\)\?[mun]\?s\>'
     75 
     76 " Objects
     77 "---------------------------------------------------------------------------
     78 syn match logUrl         display '\<https\?:\/\/\S\+'
     79 syn match logMacAddress  display '\<\x\{2}\([:-]\?\x\{2}\)\{5}\>'
     80 syn match logIPv4        display '\<\d\{1,3}\(\.\d\{1,3}\)\{3}\(\/\d\+\)\?\>'
     81 syn match logIPv6        display '\<\x\{1,4}\(:\x\{1,4}\)\{7}\(\/\d\+\)\?\>'
     82 syn match logUUID        display '\<\x\{8}-\x\{4}-\x\{4}-\x\{4}-\x\{12}\>'
     83 syn match logMD5         display '\<\x\{32}\>'
     84 syn match logSHA         display '\<\(\x\{40}\|\x\{56}\|\x\{64}\|\x\{96}\|\x\{128}\)\>'
     85 
     86 " Only highlight a path which is at the start of a line, or preceded by a space
     87 " or an equal sign (for env vars, e.g. PATH=/usr/bin)
     88 " POSIX-style path    e.g. '/var/log/system.log', './run.sh', '../a/b', '~/c'.
     89 syn match logFilePath    display '\(^\|\s\|=\)\zs\(\.\{0,2}\|\~\)\/\f\+\ze'
     90 " Windows drive path  e.g. 'C:\Users\Test'
     91 syn match logFilePath    display '\(^\|\s\|=\)\zs\a:\\\f\+\ze'
     92 " Windows UNC path    e.g. '\\server\share'
     93 syn match logFilePath    display '\(^\|\s\|=\)\zs\\\\\f\+\ze'
     94 
     95 " Java Errors
     96 "---------------------------------------------------------------------------
     97 syn match logJavaError   '\%(\%(Error\|Exception\):\s*\)\zs\w.\{-}\ze\(\\n\|$\)' contained
     98 
     99 " Syslog Columns
    100 "---------------------------------------------------------------------------
    101 " Syslog hostname, program and process number columns
    102 syn match logSysColumn   '\w\(\w\|\.\|-\)\+ \(\w\|\.\|-\)\+\(\[\d\+\]\)\?:' contained contains=@logLvs,logSysProcess
    103 syn match logSysProcess  '\(\w\|\.\|-\)\+\(\[\d\+\]\)\?:' contained contains=logNumber
    104 
    105 " XML Tags
    106 "---------------------------------------------------------------------------
    107 " Simplified matches, not accurate with the spec to avoid false positives
    108 syn match logXmlHeader    /<?\(\w\|-\)\+\(\s\+\w\+\(="[^"]*"\|='[^']*'\)\?\)*?>/ contains=logString,logXmlAttribute,logXmlNamespace
    109 syn match logXmlDoctype   /<!DOCTYPE[^>]*>/ contains=logString,logXmlAttribute,logXmlNamespace
    110 syn match logXmlTag       /<\/\?\(\(\w\|-\)\+:\)\?\(\w\|-\)\+\(\(\n\|\s\)\+\(\(\w\|-\)\+:\)\?\(\w\|-\)\+\(="[^"]*"\|='[^']*'\)\?\)*\s*\/\?>/ contains=logString,logXmlAttribute,logXmlNamespace
    111 syn match logXmlAttribute contained "\w\+="
    112 syn match logXmlAttribute contained "\(\n\|\s\)\(\(\w\|-\)\+:\)\?\(\w\|-\)\+\(=\)\?" contains=logXmlNamespace
    113 syn match logXmlNamespace contained "\(\w\|-\)\+:"
    114 syn region logXmlComment  start=/<!--/ end=/-->/
    115 syn match logXmlCData     /<!\[CDATA\[.*\]\]>/
    116 syn match logXmlEntity    /&#\?\w\+;/
    117 
    118 " Levels
    119 "---------------------------------------------------------------------------
    120 syn keyword logLvFatal      FATAL
    121 syn keyword logLvEmergency  EMERG[ENCY]
    122 syn keyword logLvAlert      ALERT
    123 syn keyword logLvCritical   CRIT[ICAL]
    124 syn keyword logLvError      E ERR[ORS]
    125 syn keyword logLvFail       F FAIL[ED] FAILURE
    126 syn keyword logLvFault      FAULT
    127 syn keyword logLvNack       NACK NAK
    128 syn keyword logLvWarning    W WARN[ING]
    129 syn keyword logLvBad        BAD
    130 syn keyword logLvNotice     NOTICE
    131 syn keyword logLvInfo       I INFO
    132 syn keyword logLvDebug      D DEBUG
    133 syn keyword logLvTrace      TRACE Trace
    134 syn keyword logLvVerbose    V VERBOSE
    135 syn keyword logLvPass       PASS[ED]
    136 syn keyword logLvSuccess    SUCCEED[ED] SUCCESS
    137 
    138 " Composite log levels e.g. *_INFO
    139 syn match logLvFatal     display '\<\u\+_FATAL\>'
    140 syn match logLvEmergency display '\<\u\+_EMERG\(ENCY\)\?\>'
    141 syn match logLvAlert     display '\<\u\+_ALERT\>'
    142 syn match logLvCritical  display '\<\u\+_CRIT\(ICAL\)\?\>'
    143 syn match logLvError     display '\<\u\+_ERR\(OR\)\?\>'
    144 syn match logLvFail      display '\<\u\+_FAIL\(URE\)\?\>'
    145 syn match logLvWarning   display '\<\u\+_WARN\(ING\)\?\>'
    146 syn match logLvNotice    display '\<\u\+_NOTICE\>'
    147 syn match logLvInfo      display '\<\u\+_INFO\>'
    148 syn match logLvDebug     display '\<\u\+_DEBUG\>'
    149 syn match logLvTrace     display '\<\u\+_TRACE\>'
    150 
    151 syn cluster logLvs contains=logLvFatal,logLvEmergency,logLvAlert,logLvCritical,logLvError,logLvFail,logLvFault,logLvNack,logLvWarning,logLvBad,logLvNotice,logLvInfo,logLvDebug,logLvTrace,logLvVerbose,logLvPass,logLvSuccess
    152 
    153 " Highlight links
    154 "---------------------------------------------------------------------------
    155 hi def link logNumber       Number
    156 hi def link logNumberHex    Number
    157 hi def link logNumberBin    Number
    158 hi def link logNumberOct    Number
    159 hi def link logNumberFloat  Float
    160 
    161 hi def link logBoolean      Boolean
    162 hi def link logNull         Constant
    163 hi def link logString       String
    164 
    165 hi def link logDate         Type
    166 hi def link logTime         Operator
    167 hi def link logTimeZone     Operator
    168 hi def link logDuration     Operator
    169 
    170 hi def link logUrl          Underlined
    171 hi def link logIPV4         Underlined
    172 hi def link logIPV6         Underlined
    173 hi def link logMacAddress   Underlined
    174 hi def link logUUID         Label
    175 hi def link logMD5          Label
    176 hi def link logSHA          Label
    177 hi def link logFilePath     Structure
    178 
    179 hi def link logJavaError    ErrorMsg
    180 
    181 hi def link logSysColumn   Statement
    182 hi def link logSysProcess   Function
    183 
    184 hi def link logXmlHeader    Function
    185 hi def link logXmlDoctype   Function
    186 hi def link logXmlTag       Identifier
    187 hi def link logXmlAttribute Type
    188 hi def link logXmlNamespace Include
    189 hi def link logXmlComment   Comment
    190 hi def link logXmlCData     String
    191 hi def link logXmlEntity    Special
    192 
    193 hi def link logSymbol       Delimiter
    194 hi def link logSeparator    Comment
    195 
    196 hi def link logLvFatal      ErrorMsg
    197 hi def link logLvEmergency  ErrorMsg
    198 hi def link logLvAlert      ErrorMsg
    199 hi def link logLvCritical   ErrorMsg
    200 hi def link logLvError      ErrorMsg
    201 hi def link logLvFail       ErrorMsg
    202 hi def link logLvFault      ErrorMsg
    203 hi def link logLvNack       ErrorMsg
    204 hi def link logLvWarning    WarningMsg
    205 hi def link logLvBad        WarningMsg
    206 hi def link logLvNotice     Exception
    207 hi def link logLvInfo       logBlue
    208 hi def link logLvDebug      Debug
    209 hi def link logLvTrace      Special
    210 hi def link logLvVerbose    Special
    211 hi def link logLvPass       logGreen
    212 hi def link logLvSuccess    logGreen
    213 
    214 " Custom highlight group
    215 " ------------------------------
    216 hi logGreen ctermfg=LightGreen guifg=LightGreen
    217 hi logBlue  ctermfg=LightBlue guifg=LightBlue
    218 
    219 
    220 let b:current_syntax = 'log'