vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

kitty.vim (4946B)


      1 " Vim syntax file
      2 " Language:          Kitty configuration files
      3 " Maintainer:        MD. Mouinul Hossain Shawon <mdmouinulhossainshawon [at] gmail.com>
      4 " Last Change:       Tue Sep 16 19:10:59 +06 2025
      5 " 2026 Jun 02 by Vim project: update kittyMapSeq highlight to match end-of-line #20422
      6 
      7 if exists("b:current_syntax")
      8   finish
      9 endif
     10 
     11 syn sync fromstart
     12 
     13 " Option """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     14 " Format: `<option_name> ...`<
     15 
     16 syn match kittyString /\S\+/ contains=kittyAlpha contained
     17 syn match kittyNumber /[+\-*\/]\{0,1}[0-9.]\+/ contained
     18 syn match kittyAlpha /@[0-9.]\+/ contained
     19 syn match kittyColor /#[0-9a-fA-F]\{3,6}/ nextgroup=kittyAlpha contained
     20 syn keyword kittyBoolean contained yes no
     21 syn keyword kittyConstant contained none auto monospace bold italic ratio always never
     22 
     23 syn match kittyFlag /[+-]\{1,2}[a-zA-Z0-9-_]\+/ contained
     24 syn match kittyParameter /-\{1,2}[a-zA-Z0-9-]\+=\S\+/ contained
     25 
     26 syn cluster kittyPrimitive contains=kittyNumber,kittyBoolean,kittyConstant,kittyColor,kittyString,kittyFlag,kittyParameter,kittyAlpha
     27 
     28 syn region kittyOption start="^\w" skip="[\n\r][ \t]*\\" end="[\r\n]" contains=kittyOptionName
     29 syn match kittyOptionName /\w\+/ nextgroup=kittyOptionValue skipwhite contained
     30 syn region kittyOptionValue start="\S" skip="[\r\n][ \t]*\\" end="\ze[\r\n]" contains=@kittyPrimitive contained
     31 
     32 " Keyboard shortcut """""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     33 " Format: `map <keys> <action>?`
     34 
     35 syn match kittyKey /[^ \t\r\n+>]\+/ contained
     36 syn match kittyCtrl /\<\(ctrl\|control\)\>\|\^/ contained
     37 syn match kittyAlt /\<\(alt\|opt\|option\)\>\|⌥/ contained
     38 syn match kittyShift /\<\(shift\)\>\|⇧/ contained
     39 syn match kittySuper /\<\(cmd\|super\|command\)\>\|⌘/ contained
     40 
     41 syn match kittyAnd /+/ contained
     42 syn match kittyWith />/ contained
     43 
     44 syn region kittyMap start="^\s*map" skip="[\r\n][ \t]*\\" end="[\r\n]" contains=kittyMapName,kittyMapValue
     45 
     46 syn keyword kittyMapName nextgroup=kittyMapValue skipwhite contained map
     47 syn region kittyMapValue start="\S" skip="[\r\n][ \t]*\\" end="\ze[\r\n]" contains=kittyMapSeq,kittyMapAction contained
     48 
     49 syn region kittyMapAction start="\S" skip="[\r\n][ \t]*\\" end="\ze[\r\n]" contains=@kittyPrimitive contained
     50 syn region kittyMapSeq start="\S" end="\ze\s\|^\ze[ \t]*\\\|\ze$" nextgroup=kittyMapAction,kittyMouseMapType skipwhite contains=kittyCtrl,kittyAlt,kittyShift,kittySuper,kittyAnd,kittyWith,kittyKey contained
     51 
     52 " Mouse shortcut """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     53 " Format: `mouse_map <keys> <type> <grabbed> <action>?`
     54 
     55 syn region kittyMouseMap start="^\s*mouse_map" skip="[\r\n][ \t]*\\" end="[\r\n]" contains=kittyMouseMapName,kittyMouseMapValue
     56 
     57 syn keyword kittyMouseMapName nextgroup=kittyMouseMapValue contained mouse_map
     58 syn region kittyMouseMapValue start="\S" skip="[\r\n][ \t]*\\" end="\ze[\r\n]" contains=kittyMapSeq,kittyMouseMapType,kittyMouseMapGrabbed contained
     59 
     60 syn region kittyMouseMapAction start="\S" skip="[\r\n][ \t]*\\" end="\ze[\r\n]" contains=@kittyPrimitive contained
     61 
     62 syn keyword kittyMouseMapType nextgroup=kittyMouseMapGrabbed skipwhite contained press release doublepress triplepress click doubleclick
     63 syn match kittyMouseMapGrabbed /\(grabbed\|ungrabbed\)\%(,\(grabbed\|ungrabbed\)\)\?/ nextgroup=kittyMouseMapAction skipwhite contained
     64 
     65 " Kitty modifier """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     66 " Format: `kitty_mod <keys>`
     67 
     68 syn region kittyMod start="^\s*kitty_mod" end="[\r\n]" contains=kittyModName,kittyMapSeq
     69 
     70 syn keyword kittyModName nextgroup=kittyMapSeq contained kitty_mod
     71 
     72 " Comment """""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     73 " Format: `# <content>``
     74 
     75 syn match kittyComment /^#.*$/
     76 
     77 " Line continuation """""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     78 " Allows continuing lines by adding `\` at the start of a line.
     79 " May have leading spaces & tabs.
     80 
     81 syn match kittyLineContinue /^[ \t]*\\[ \t]*/ containedin=kittyOptionValue,kittyMap,kittyMapAction,kittyMouseMap,kittyMouseMapValue contained
     82 
     83 " Highlight groups """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""
     84 
     85 hi link kittyString String
     86 hi link kittyNumber Number
     87 hi link kittyAlpha Type
     88 hi link kittyColor Constant
     89 hi link kittyBoolean Boolean
     90 hi link kittyConstant Constant
     91 
     92 hi link kittyFlag Constant
     93 hi link kittyParameter Special
     94 
     95 hi link kittyOptionName Keyword
     96 hi link kittyModName Keyword
     97 
     98 hi link kittyKey Special
     99 hi link kittyCtrl Constant
    100 hi link kittyAlt Constant
    101 hi link kittyShift Constant
    102 hi link kittySuper Constant
    103 
    104 hi link kittyAnd Operator
    105 hi link kittyWith Operator
    106 
    107 hi link kittyMapName Function
    108 
    109 hi link kittyMouseMapName Function
    110 hi link kittyMouseMapType Type
    111 hi link kittyMouseMapGrabbed Constant
    112 
    113 hi link kittyComment Comment
    114 hi link kittyLineContinue Comment
    115 
    116 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
    117 
    118 let b:current_syntax = "kitty"
    119