vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

java.vim (57039B)


      1 " Vim syntax file
      2 " Language:		Java
      3 " Maintainer:		Aliaksei Budavei <0x000c70 AT gmail DOT com>
      4 " Former Maintainer:	Claudio Fleiner <claudio@fleiner.com>
      5 " Repository:		https://github.com/zzzyxwvut/java-vim.git
      6 " Last Change:		2026 Sep 18
      7 
      8 " Please check ":help java.vim" for comments on some of the options
      9 " available.
     10 
     11 " Do not aggregate syntax items from circular inclusion.
     12 if exists("b:current_syntax")
     13   finish
     14 endif
     15 
     16 if exists("g:main_syntax")
     17   " Reject attendant circularity for every :syn-included syntax file,
     18   " but ACCEPT FAILURE when "g:main_syntax" is set to "java".
     19   if g:main_syntax == 'html'
     20     if !exists("g:java_ignore_html")
     21       let g:java_ignore_html = 1
     22       let s:clear_java_ignore_html = 1
     23     endif
     24   elseif g:main_syntax == 'markdown'
     25     if !exists("g:java_ignore_markdown")
     26       let g:java_ignore_markdown = 1
     27       let s:clear_java_ignore_markdown = 1
     28     endif
     29   endif
     30 else
     31   " Allow syntax files that include this file test for its inclusion.
     32   let g:main_syntax = 'java'
     33 endif
     34 
     35 let s:cpo_save = &cpo
     36 set cpo&vim
     37 
     38 """" STRIVE TO REMAIN COMPATIBLE FOR AT LEAST VIM 7.0.
     39 let s:ff = {}
     40 let s:vv = {}
     41 let s:vv.ignore_folding = get(g:, 'java_ignore_folding', '')
     42 
     43 function! s:ff.LeftConstant(x, y) abort
     44   return a:x
     45 endfunction
     46 
     47 function! s:ff.RightConstant(x, y) abort
     48   return a:y
     49 endfunction
     50 
     51 if !empty(get(g:, 'java_syntax_previews', []))
     52   " Fold the value of "g:java_syntax_previews" in this function.
     53   exec printf("%s\n%s\n%s",
     54     \ 'function! s:ff.IsAnyRequestedPreviewFeatureOf(ns) abort',
     55     \ printf('return !empty(filter(a:ns, "index(%s, v:val) + 1"))',
     56 			\ string(g:java_syntax_previews)),
     57     \ 'endfunction')
     58 else
     59   function! s:ff.IsAnyRequestedPreviewFeatureOf(dummy) abort
     60     return 0
     61   endfunction
     62 endif
     63 
     64 function! s:ff.QueryFoldArgForSyntaxItems(kind) abort
     65   return stridx(s:vv.ignore_folding, a:kind) < 0 ? "fold" : ""
     66 endfunction
     67 
     68 if !exists("*s:ReportOnce")
     69   function s:ReportOnce(message) abort
     70     echomsg 'syntax/java.vim: ' . a:message
     71   endfunction
     72 else
     73   function! s:ReportOnce(dummy)
     74   endfunction
     75 endif
     76 
     77 if exists("g:java_foldtext_show_first_or_second_line")
     78   function! s:LazyPrefix(prefix, dashes, count) abort
     79     return empty(a:prefix)
     80       \ ? printf('+-%s%3d lines: ', a:dashes, a:count)
     81       \ : a:prefix
     82   endfunction
     83 
     84   function! JavaSyntaxFoldTextExpr() abort
     85     " Piggyback on NGETTEXT.
     86     let summary = foldtext()
     87     return getline(v:foldstart) !~ '/\*\+\s*$'
     88       \ ? summary
     89       \ : s:LazyPrefix(matchstr(summary, '^+-\+\s*\d\+\s.\{-1,}:\s'),
     90 			\ v:folddashes,
     91 			\ (v:foldend - v:foldstart + 1)) .
     92 	  \ getline(v:foldstart + 1)
     93   endfunction
     94 
     95   " E120 for "fdt=s:JavaSyntaxFoldTextExpr()" before v8.2.3900.
     96   setlocal foldtext=JavaSyntaxFoldTextExpr()
     97 endif
     98 
     99 " Admit the ASCII dollar sign to keyword characters (JLS-17, §3.8):
    100 try
    101   exec 'syntax iskeyword ' . &l:iskeyword . ',$'
    102 catch /\<E410:/
    103   call s:ReportOnce(v:exception)
    104   setlocal iskeyword+=$
    105 endtry
    106 
    107 " some characters that cannot be in a java program (outside a string)
    108 syn match javaError "[\\@`]"
    109 syn match javaError "<<<\|\.\.\|=>\|||=\|&&=\|\*\/"
    110 
    111 " use separate name so that it can be deleted in javacc.vim
    112 syn match   javaError2 "#\|=<"
    113 
    114 " (Without knowing what Java release is being targeted for the source
    115 " file it is found in, an underscore token cannot be reliably matched
    116 " as an identifier _or_ a syntax error _or_ a keyword.)
    117 "
    118 " Keywords (JLS-17, §3.9):
    119 syn keyword javaExternal	native package
    120 syn match   javaExternal	"\<import\>\%(\s\+static\>\)\="
    121 syn keyword javaError		goto const
    122 syn keyword javaConditional	if else switch
    123 syn keyword javaRepeat		while for do
    124 syn keyword javaBoolean		true false
    125 syn keyword javaConstant	null
    126 syn keyword javaTypedef		this super
    127 syn keyword javaOperator	new instanceof
    128 syn match   javaOperator	"\<var\>\%(\s*(\)\@!"
    129 
    130 " Module imports can be used in any source file.
    131 syn match   javaExternal	"\<import\s\+module\>" contains=javaModuleImport
    132 syn keyword javaModuleImport	contained module
    133 
    134 if !empty(s:ff.QueryFoldArgForSyntaxItems('i'))
    135   " Group and fold adjacent "import" declarations.
    136   syn region  javaImportDeclBlock	transparent start="\<import\s\+\K" skip="\<import\s\+\K" end="^" contains=javaExternal,@javaClasses,javaComment,javaLineComment fold
    137 endif
    138 
    139 " Since the yield statement, which could take a parenthesised operand,
    140 " and _qualified_ yield methods get along within the switch block
    141 " (JLS-17, §3.8), it seems futile to make a region definition for this
    142 " block; instead look for the _yield_ word alone, and if found,
    143 " backtrack (arbitrarily) 80 bytes, at most, on the matched line and,
    144 " if necessary, on the line before that (h: \@<=), trying to match
    145 " neither a method reference nor a qualified method invocation.
    146 try
    147   if !empty(get(g:, 'java_lookbehind_byte_counts', {}))
    148     exec 'syn match javaOperator "\%(\%(::\|\.\)[[:space:]\n]*\)\@' . max([0, get(g:java_lookbehind_byte_counts, 'javaOperator', 80)]) . '<!\<yield\>"'
    149 
    150     function! s:ff.PeekFor(item, count) abort
    151       return string(max([0, get(g:java_lookbehind_byte_counts, a:item, a:count)]))
    152     endfunction
    153   else
    154     syn match  javaOperator	"\%(\%(::\|\.\)[[:space:]\n]*\)\@80<!\<yield\>"
    155 
    156     function! s:ff.PeekFor(dummy, count) abort
    157       return string(a:count)
    158     endfunction
    159   endif
    160 
    161   let s:ff.Peek = s:ff.LeftConstant
    162 catch /\<E59:/
    163   call s:ReportOnce(v:exception)
    164   syn match  javaOperator	"\%(\%(::\|\.\)[[:space:]\n]*\)\@<!\<yield\>"
    165 
    166   function! s:ff.PeekFor(dummy_a, dummy_b) abort
    167     return ""
    168   endfunction
    169 
    170   let s:ff.Peek = s:ff.RightConstant
    171 endtry
    172 
    173 syn keyword javaType		boolean char byte short int long float double
    174 syn keyword javaType		void
    175 syn keyword javaStatement	return
    176 syn keyword javaStorageClass	static synchronized transient volatile strictfp
    177 syn keyword javaExceptions	throw try catch finally
    178 syn keyword javaAssert		assert
    179 syn keyword javaMethodDecl	throws
    180 " Differentiate a "MyClass.class" literal from the keyword "class".
    181 syn match   javaTypedef		"\.\s*\<class\>"ms=s+1
    182 syn keyword javaClassDecl	enum extends implements interface
    183 syn match   javaClassDecl	"\<permits\>\%(\s*(\)\@!"
    184 syn match   javaClassDecl	"\<record\>\%(\s*(\)\@!"
    185 syn match   javaClassDecl	"^class\>"
    186 syn match   javaClassDecl	"[^.]\s*\<class\>"ms=s+1
    187 syn match   javaAnnotation	"@\%(\K\k*\.\)*\K\k*\>"
    188 syn region  javaAnnotation	transparent matchgroup=javaAnnotationStart start=/@\%(\K\k*\.\)*\K\k*(/ end=/)/ skip=/\/\*.\{-}\*\/\|\/\/.*$/ contains=javaAnnotation,javaParenT,javaBlock,javaString,javaBoolean,javaNumber,javaTypedef,javaComment,javaLineComment
    189 syn match   javaClassDecl	"@interface\>"
    190 syn keyword javaBranch		break continue nextgroup=javaUserLabelRef skipwhite
    191 syn match   javaUserLabelRef	contained "\k\+"
    192 syn match   javaVarArg		"\.\.\."
    193 syn keyword javaScopeDecl	public protected private
    194 syn keyword javaConceptKind	abstract final
    195 syn match   javaConceptKind	"\<non-sealed\>"
    196 syn match   javaConceptKind	"\<sealed\>\%(\s*(\)\@!"
    197 syn match   javaConceptKind	"\<default\>\%(\s*\%(:\|->\)\)\@!"
    198 
    199 if !(v:version < 704)
    200   " Request the new regexp engine for [:upper:] and [:lower:].
    201   let [s:ff.Engine, s:ff.UpperCase, s:ff.LowerCase] = repeat([s:ff.LeftConstant], 3)
    202 else
    203   " XXX: \C\<[^a-z0-9]\k*\> rejects "type", but matches "τύπος".
    204   " XXX: \C\<[^A-Z0-9]\k*\> rejects "Method", but matches "Μέθοδος".
    205   let [s:ff.Engine, s:ff.UpperCase, s:ff.LowerCase] = repeat([s:ff.RightConstant], 3)
    206 endif
    207 
    208 if exists("g:java_highlight_signature")
    209   let [s:ff.PeekTo, s:ff.PeekFrom, s:ff.GroupArgs] = repeat([s:ff.LeftConstant], 3)
    210 else
    211   let [s:ff.PeekTo, s:ff.PeekFrom, s:ff.GroupArgs] = repeat([s:ff.RightConstant], 3)
    212 endif
    213 
    214 let s:with_html = !exists("g:java_ignore_html")
    215 let s:with_markdown = !exists("g:java_ignore_markdown")
    216 lockvar s:with_html s:with_markdown
    217 
    218 " Note that the delimiting angle brackets are omitted.
    219 let s:vv.type_param_list = '\%([^(){}]\|\n\)\+[[:space:]-]\@' . s:ff.Peek('1', '') . '<!'
    220 " COMBAK: Revisit reference types once JDK-8259731 and JDK-8316779
    221 " will have been resolved.
    222 let s:vv.param_type_head = 'b\%%(oolean\|yte\)\|char\|short\|int\|long\|float\|double\|\%%(\<\K\k*\>\.\)*%s\<' . s:ff.UpperCase('[$_[:upper:]]', '[^a-z0-9]') . '\k*\>'
    223 " Allow for org.example.TopLevelType<T>.MemberType return types.
    224 let s:vv.void_or_param_type = 'void\|\%(' . printf(s:vv.param_type_head, '\%(') . '\%(<' . s:vv.type_param_list . '>\.\=\)\=\)\+\)\%(\[\]\)*'
    225 let s:vv.param_type_head = printf(s:vv.param_type_head, '')
    226 
    227 " Java module declarations (JLS-17, §7.7).
    228 "
    229 " Note that a "module-info" file will be recognised with an arbitrary
    230 " file extension (or no extension at all) so that more than one such
    231 " declaration for the same Java module can be maintained for modular
    232 " testing in a project without attendant confusion for IDEs, with the
    233 " ".java\=" extension used for a production version and an arbitrary
    234 " extension used for a testing version.
    235 if fnamemodify(bufname("%"), ":t") =~ '^module-info\>\%(\.class\>\)\@!'
    236   syn keyword javaModuleStorageClass	module transitive
    237   syn keyword javaModuleStmt		open requires exports opens uses provides
    238   syn keyword javaModuleExternal	to with
    239   hi def link javaModuleStorageClass	StorageClass
    240   hi def link javaModuleStmt		Statement
    241   hi def link javaModuleExternal	Include
    242 
    243   if !exists("g:java_ignore_javadoc") && (s:with_html || s:with_markdown) && g:main_syntax != 'jsp'
    244     syn match javaDocProvidesTag	contained "@provides\_s\+\S\+" contains=javaDocParam
    245     syn match javaDocUsesTag		contained "@uses\_s\+\S\+" contains=javaDocParam
    246     hi def link javaDocProvidesTag	Special
    247     hi def link javaDocUsesTag		Special
    248   endif
    249 endif
    250 
    251 if exists("g:java_highlight_java_lang_ids")
    252   let g:java_highlight_all = 1
    253 endif
    254 
    255 if exists("g:java_highlight_all") || exists("g:java_highlight_java") || exists("g:java_highlight_java_lang")
    256   " java.lang.*
    257   "
    258   " The type names in ":syn-keyword"s (and in ":syn-match"es) of the
    259   " "java[CEIRX]_JavaLang" syntax groups are sub-grouped according to
    260   " the Java version of their introduction, and sub-group names are
    261   " arranged in alphabetical order, so that future newer names can be
    262   " pre-sorted and appended without disturbing their placement.
    263 
    264   syn keyword javaR_JavaLang ArithmeticException ArrayIndexOutOfBoundsException ArrayStoreException ClassCastException IllegalArgumentException IllegalMonitorStateException IllegalThreadStateException IndexOutOfBoundsException NegativeArraySizeException NullPointerException NumberFormatException RuntimeException SecurityException StringIndexOutOfBoundsException IllegalStateException UnsupportedOperationException EnumConstantNotPresentException TypeNotPresentException IllegalCallerException LayerInstantiationException WrongThreadException MatchException
    265   syn cluster javaClasses add=javaR_JavaLang
    266   hi def link javaR_JavaLang javaR_Java
    267   syn keyword javaC_JavaLang Boolean Character ClassLoader Compiler Double Float Integer Long Math Number Object Process Runtime SecurityManager String StringBuffer Thread ThreadGroup Byte Short Void Package RuntimePermission StrictMath StackTraceElement ProcessBuilder StringBuilder Module ModuleLayer StackWalker Record IO
    268   syn match   javaC_JavaLang "\<System\>"	" See javaDebug.
    269   " Generic non-interfaces:
    270   syn match   javaC_JavaLang "\<Class\>"
    271   syn match   javaC_JavaLang "\<InheritableThreadLocal\>"
    272   syn match   javaC_JavaLang "\<ThreadLocal\>"
    273   syn match   javaC_JavaLang "\<Enum\>"
    274   syn match   javaC_JavaLang "\<ClassValue\>"
    275   exec 'syn match javaC_JavaLang "\%(\<Enum\.\)\@' . s:ff.Peek('5', '') . '<=\<EnumDesc\>"'
    276   syn match   javaC_JavaLang "\<ScopedValue\>"
    277   " Member classes:
    278   exec 'syn match javaC_JavaLang "\%(\<Character\.\)\@' . s:ff.Peek('10', '') . '<=\<Subset\>"'
    279   exec 'syn match javaC_JavaLang "\%(\<Character\.\)\@' . s:ff.Peek('10', '') . '<=\<UnicodeBlock\>"'
    280   exec 'syn match javaC_JavaLang "\%(\<ProcessBuilder\.\)\@' . s:ff.Peek('15', '') . '<=\<Redirect\>"'
    281   exec 'syn match javaC_JavaLang "\%(\<ModuleLayer\.\)\@' . s:ff.Peek('12', '') . '<=\<Controller\>"'
    282   exec 'syn match javaC_JavaLang "\%(\<Runtime\.\)\@' . s:ff.Peek('8', '') . '<=\<Version\>"'
    283   exec 'syn match javaC_JavaLang "\%(\<System\.\)\@' . s:ff.Peek('7', '') . '<=\<LoggerFinder\>"'
    284   exec 'syn match javaC_JavaLang "\%(\<ScopedValue\.\)\@' . s:ff.Peek('12', '') . '<=\<Carrier\>"'
    285   " Member enumerations:
    286   exec 'syn match javaC_JavaLang "\%(\<Thread\.\)\@' . s:ff.Peek('7', '') . '<=\<State\>"'
    287   exec 'syn match javaC_JavaLang "\%(\<Character\.\)\@' . s:ff.Peek('10', '') . '<=\<UnicodeScript\>"'
    288   exec 'syn match javaC_JavaLang "\%(\<ProcessBuilder\.Redirect\.\)\@' . s:ff.Peek('24', '') . '<=\<Type\>"'
    289   exec 'syn match javaC_JavaLang "\%(\<StackWalker\.\)\@' . s:ff.Peek('12', '') . '<=\<Option\>"'
    290   exec 'syn match javaC_JavaLang "\%(\<System\.Logger\.\)\@' . s:ff.Peek('14', '') . '<=\<Level\>"'
    291   syn cluster javaClasses add=javaC_JavaLang
    292   hi def link javaC_JavaLang javaC_Java
    293   syn keyword javaE_JavaLang AbstractMethodError ClassCircularityError ClassFormatError Error IllegalAccessError IncompatibleClassChangeError InstantiationError InternalError LinkageError NoClassDefFoundError NoSuchFieldError NoSuchMethodError OutOfMemoryError StackOverflowError ThreadDeath UnknownError UnsatisfiedLinkError VerifyError VirtualMachineError ExceptionInInitializerError UnsupportedClassVersionError AssertionError BootstrapMethodError
    294   syn cluster javaClasses add=javaE_JavaLang
    295   hi def link javaE_JavaLang javaE_Java
    296   syn keyword javaX_JavaLang ClassNotFoundException CloneNotSupportedException Exception IllegalAccessException InstantiationException InterruptedException NoSuchMethodException Throwable NoSuchFieldException ReflectiveOperationException
    297   syn cluster javaClasses add=javaX_JavaLang
    298   hi def link javaX_JavaLang javaX_Java
    299   syn keyword javaI_JavaLang Cloneable Runnable CharSequence Appendable Deprecated Override Readable SuppressWarnings AutoCloseable SafeVarargs FunctionalInterface ProcessHandle
    300   " Generic non-classes:
    301   syn match   javaI_JavaLang "\<Comparable\>"
    302   syn match   javaI_JavaLang "\<Iterable\>"
    303   " Member interfaces:
    304   exec 'syn match javaI_JavaLang "\%(\<Thread\.\)\@' . s:ff.Peek('7', '') . '<=\<UncaughtExceptionHandler\>"'
    305   exec 'syn match javaI_JavaLang "\%(\<ProcessHandle\.\)\@' . s:ff.Peek('14', '') . '<=\<Info\>"'
    306   exec 'syn match javaI_JavaLang "\%(\<System\.\)\@' . s:ff.Peek('7', '') . '<=\<Logger\>"'
    307   exec 'syn match javaI_JavaLang "\%(\<StackWalker\.\)\@' . s:ff.Peek('12', '') . '<=\<StackFrame\>"'
    308   exec 'syn match javaI_JavaLang "\%(\<Thread\.\)\@' . s:ff.Peek('7', '') . '<=\<Builder\>"'
    309   exec 'syn match javaI_JavaLang "\%(\<Thread\.Builder\.\)\@' . s:ff.Peek('15', '') . '<=\<OfPlatform\>"'
    310   exec 'syn match javaI_JavaLang "\%(\<Thread\.Builder\.\)\@' . s:ff.Peek('15', '') . '<=\<OfVirtual\>"'
    311   exec 'syn match javaI_JavaLang "\%(\<ScopedValue\.\)\@' . s:ff.Peek('12', '') . '<=\<CallableOp\>"'
    312   syn cluster javaClasses add=javaI_JavaLang
    313   hi def link javaI_JavaLang javaI_Java
    314 
    315   " Common groups for generated "javaid.vim" syntax items:
    316   hi def link javaR_Java javaR_
    317   hi def link javaC_Java javaC_
    318   hi def link javaE_Java javaE_
    319   hi def link javaX_Java javaX_
    320   hi def link javaI_Java javaI_
    321   hi def link javaX_ javaExceptions
    322   hi def link javaR_ javaExceptions
    323   hi def link javaE_ javaExceptions
    324   hi def link javaC_ javaConstant
    325   hi def link javaI_ javaTypedef
    326 
    327   syn keyword javaLangObject getClass notify notifyAll wait
    328 
    329   " Lower the syntax priority of overridable java.lang.Object method
    330   " names for zero-width matching (define g:java_highlight_signature
    331   " and see their base declarations for java.lang.Object):
    332   syn match javaLangObject "\<clone\>"
    333   syn match javaLangObject "\<equals\>"
    334   syn match javaLangObject "\<finalize\>"
    335   syn match javaLangObject "\<hashCode\>"
    336   syn match javaLangObject "\<toString\>"
    337   hi def link javaLangObject javaConstant
    338 
    339   " As of JDK 25, RuntimePermission is deprecated for removal
    340   "	(JDK-8353641).
    341   "	(Note that SecurityException is still not deprecated.)
    342   " As of JDK 24, SecurityManager is rendered non-functional
    343   "	(JDK-8338625).
    344   " As of JDK 21, Compiler is no more (JDK-8205129).
    345   syn keyword javaLangDeprecated Compiler SecurityManager RuntimePermission
    346 endif
    347 
    348 runtime syntax/javaid.vim
    349 
    350 " Type parameter sections (JLS-17, §4.4, §4.5).
    351 "
    352 " Note that false positives may elsewhere occur whenever an identifier
    353 " is butted against a less-than operator.  Cf. (X<Y) and (X < Y).
    354 if exists("g:java_highlight_generics")
    355   syn keyword javaWildcardBound contained extends super
    356   syn cluster javaTypeParams contains=javaAnnotation,javaWildcardBound,javaType,@javaClasses,javaComment,javaLineComment
    357 
    358   " Match sections of generic methods and constructors and their
    359   " parameterised use.
    360   exec 'syn region javaTypeParamSection transparent matchgroup=javaGenericsCX start=/' . s:ff.Engine('\%#=2', '') . '\%(^\|\s\)\@' . s:ff.Peek('1', '') . '<=<\%(' . s:vv.type_param_list . '>\_s\+\%(\%(' . s:vv.void_or_param_type . '\)\_s\+\)\=\<\K\k*\>\s*(\)\@=/ end=/>/ contains=javaGenerics,@javaTypeParams'
    361   exec 'syn region javaTypeParamSection transparent matchgroup=javaGenericsCX start=/\%(\%(\<new\|::\|\.\)[[:space:]\n]*\)\@' . s:ff.PeekFor('javaTypeParamSection', 80) . '<=<>\@!/ end=/>/ contains=javaGenerics,@javaTypeParams'
    362 
    363   for s:ctx in [{'gsg': 'javaGenerics', 'ghg': 'javaGenericsC1', 'csg': 'javaGenericsX', 'c': ''},
    364       \ {'gsg': 'javaGenericsX', 'ghg': 'javaGenericsC2', 'csg': 'javaGenerics', 'c': ' contained'}]
    365     " Match sections of generic types and their parameterised use.
    366     exec 'syn region ' . s:ctx.gsg . s:ctx.c . ' transparent matchgroup=' . s:ctx.ghg . ' start=/' . s:ff.Engine('\%#=2', '') . '\%(\<\K\k*\>\.\)*\<' . s:ff.UpperCase('[$_[:upper:]]', '[^a-z0-9]') . '\k*\><\%([[:space:]\n]*\%([?@]\|' . s:vv.param_type_head . '\)\)\@=/ end=/>/ contains=' . s:ctx.csg . ',@javaTypeParams'
    367   endfor
    368 
    369   unlet s:ctx
    370   hi def link javaWildcardBound	Question
    371   hi def link javaGenericsC1	Function
    372   hi def link javaGenericsC2	Type
    373   hi def link javaGenericsCX	javaGenericsC2
    374 endif
    375 
    376 if exists("g:java_space_errors")
    377   if !exists("g:java_no_trail_space_error")
    378     syn match javaSpaceError "\s\+$"
    379   endif
    380   if !exists("g:java_no_tab_space_error")
    381     syn match javaSpaceError " \+\t"me=e-1
    382   endif
    383   hi def link javaSpaceError Error
    384 endif
    385 
    386 exec 'syn match javaUserLabel "^\s*\<\K\k*\>\%(\<default\>\)\@' . s:ff.Peek('7', '') . '<!\s*::\@!"he=e-1'
    387 
    388 if s:ff.IsAnyRequestedPreviewFeatureOf([455, 488, 507, 530, 532])
    389   syn region  javaLabelRegion	transparent matchgroup=javaLabel start="\<case\>" matchgroup=NONE end=":\|->" contains=javaBoolean,javaNumber,javaCharacter,javaString,javaConstant,@javaClasses,javaGenerics,javaType,javaLabelDefault,javaLabelVarType,javaLabelWhenClause
    390 else
    391   syn region  javaLabelRegion	transparent matchgroup=javaLabel start="\<case\>" matchgroup=NONE end=":\|->" contains=javaLabelCastType,javaLabelNumber,javaCharacter,javaString,javaConstant,@javaClasses,javaGenerics,javaLabelDefault,javaLabelVarType,javaLabelWhenClause
    392   syn keyword javaLabelCastType	contained char byte short int
    393   syn match   javaLabelNumber	contained "\<0\>[lL]\@!"
    394   syn match   javaLabelNumber	contained "\<\%(0\%([xX]\x\%(_*\x\)*\|_*\o\%(_*\o\)*\|[bB][01]\%(_*[01]\)*\)\|[1-9]\%(_*\d\)*\)\>[lL]\@!"
    395   hi def link javaLabelCastType	javaType
    396   hi def link javaLabelNumber	javaNumber
    397 endif
    398 
    399 syn region  javaLabelRegion	transparent matchgroup=javaLabel start="\<default\>\%(\s*\%(:\|->\)\)\@=" matchgroup=NONE end=":\|->" oneline
    400 " Consider grouped _default_ _case_ labels, i.e.
    401 " case null, default ->
    402 " case null: default:
    403 syn keyword javaLabelDefault	contained default
    404 syn keyword javaLabelVarType	contained var
    405 " Allow for the contingency of the enclosing region not being able to
    406 " _keep_ its _end_, e.g. case ':':.
    407 syn region  javaLabelWhenClause	contained transparent matchgroup=javaLabel start="\<when\>" matchgroup=NONE end=":"me=e-1 end="->"me=e-2 contains=TOP,javaImportDeclBlock,javaExternal,javaLambdaDef
    408 
    409 " Comments
    410 syn keyword javaTodo		contained TODO FIXME XXX
    411 
    412 if exists("g:java_comment_strings")
    413   syn region  javaCommentString	contained start=+"+ end=+"+ end=+$+ end=+\*/+me=s-1,he=s-1 contains=javaSpecial,javaCommentStar,javaSpecialChar,@Spell
    414   syn region  javaCommentString	contained start=+"""[ \t\x0c\r]*$+hs=e+1 end=+"""+he=s-1 contains=javaSpecial,javaCommentStar,javaSpecialChar,@Spell,javaSpecialError,javaTextBlockError
    415   syn region  javaComment2String contained start=+"+ end=+$\|"+ contains=javaSpecial,javaSpecialChar,@Spell
    416   syn match   javaCommentCharacter contained "'\\[^']\{1,6\}'" contains=javaSpecialChar
    417   syn match   javaCommentCharacter contained "'\\''" contains=javaSpecialChar
    418   syn match   javaCommentCharacter contained "'[^\\]'"
    419   syn cluster javaCommentSpecial add=javaCommentString,javaCommentCharacter,javaNumber,javaStrTempl
    420   syn cluster javaCommentSpecial2 add=javaComment2String,javaCommentCharacter,javaNumber,javaStrTempl
    421 endif
    422 
    423 exec 'syn region javaComment matchgroup=javaCommentStart start="/\*" end="\*/" contains=@javaCommentSpecial,javaTodo,javaCommentError,javaSpaceError,@Spell ' . s:ff.QueryFoldArgForSyntaxItems('c')
    424 syn match   javaCommentStar	contained "^\s*\*[^/]"me=e-1
    425 syn match   javaCommentStar	contained "^\s*\*$"
    426 syn match   javaLineComment	"//.*" contains=@javaCommentSpecial2,javaTodo,javaCommentMarkupTag,javaSpaceError,@Spell
    427 syn match   javaCommentMarkupTag contained "@\%(end\|highlight\|link\|replace\|start\)\>" nextgroup=javaCommentMarkupTagAttr,javaSpaceError skipwhite
    428 syn match   javaCommentMarkupTagAttr contained "\<region\>" nextgroup=javaCommentMarkupTagAttr,javaSpaceError skipwhite
    429 exec 'syn region javaCommentMarkupTagAttr contained transparent matchgroup=javaHtmlArg start=/\<\%(re\%(gex\|gion\|placement\)\|substring\|t\%(arget\|ype\)\)\%(\s*=\)\@=/ matchgroup=javaHtmlString end=/\%(=\s*\)\@' . s:ff.PeekFor('javaCommentMarkupTagAttr', 80) . '<=\%("[^"]\+"\|' . "\x27[^\x27]\\+\x27" . '\|\%([.-]\|\k\)\+\)/ nextgroup=javaCommentMarkupTagAttr,javaSpaceError skipwhite oneline'
    430 syn match   javaCommentError contained "/\*"me=e-1 display
    431 
    432 if !exists("g:java_ignore_javadoc") && (s:with_html || s:with_markdown) && g:main_syntax != 'jsp'
    433   " The overridable "html*" and "markdown*" default links must be
    434   " defined _before_ the inclusion of the same default links from
    435   " "html.vim" and "markdown.vim".
    436   if s:with_html || s:with_markdown
    437     hi def link htmlComment		Special
    438     hi def link htmlCommentPart		Special
    439     hi def link htmlArg			Type
    440     hi def link htmlString		String
    441   endif
    442 
    443   if s:with_markdown
    444     hi def link markdownCode		Special
    445     hi def link markdownCodeBlock	Special
    446     hi def link markdownCodeDelimiter	Special
    447     hi def link markdownLinkDelimiter	Comment
    448   endif
    449 
    450   syntax case ignore
    451 
    452   " Note that javaDocSeeTag is valid in HTML and Markdown.
    453   let s:ff.WithMarkdown = s:ff.RightConstant
    454 
    455   " Include HTML syntax coloring for Javadoc comments.
    456   if s:with_html
    457     try
    458       if exists("g:html_syntax_folding") && !exists("g:java_consent_to_html_syntax_folding")
    459 	let s:html_syntax_folding_copy = g:html_syntax_folding
    460 	unlet g:html_syntax_folding
    461       endif
    462 
    463       syntax include @javaHtml syntax/html.vim
    464     finally
    465       unlet! b:current_syntax
    466 
    467       if exists("s:html_syntax_folding_copy")
    468 	let g:html_syntax_folding = s:html_syntax_folding_copy
    469 	unlet s:html_syntax_folding_copy
    470       endif
    471     endtry
    472   endif
    473 
    474   " Include Markdown syntax coloring (v7.2.437) for Javadoc comments.
    475   if s:with_markdown
    476     try
    477       if exists("g:html_syntax_folding") && !exists("g:java_consent_to_html_syntax_folding")
    478 	let s:html_syntax_folding_copy = g:html_syntax_folding
    479 	unlet g:html_syntax_folding
    480       endif
    481 
    482       if !empty(get(g:, 'markdown_fenced_languages', []))
    483 	let s:markdown_fenced_languages_copy = g:markdown_fenced_languages
    484 	unlet g:markdown_fenced_languages
    485       endif
    486 
    487       syntax include @javaMarkdown syntax/markdown.vim
    488 
    489       try
    490 	syn clear markdownId markdownLineStart markdownH1 markdownH2 markdownHeadingRule markdownRule markdownCode markdownCodeBlock markdownIdDeclaration
    491 	let s:ff.WithMarkdown = s:ff.LeftConstant
    492       catch /\<E28:/
    493 	call s:ReportOnce(v:exception)
    494 	let s:no_support = 1
    495 	unlet! g:java_ignore_markdown
    496 	let g:java_ignore_markdown = 28
    497       endtry
    498     catch /\<E48[45]:/
    499       call s:ReportOnce(v:exception)
    500       let s:no_support = 1
    501     finally
    502       unlet! b:current_syntax
    503 
    504       if exists("s:markdown_fenced_languages_copy")
    505 	let g:markdown_fenced_languages = s:markdown_fenced_languages_copy
    506 	unlet s:markdown_fenced_languages_copy
    507       endif
    508 
    509       if exists("s:html_syntax_folding_copy")
    510 	let g:html_syntax_folding = s:html_syntax_folding_copy
    511 	unlet s:html_syntax_folding_copy
    512       endif
    513 
    514       if exists("s:no_support")
    515 	unlet s:no_support
    516 	unlockvar s:with_markdown
    517 	let s:with_markdown = 0
    518 	lockvar s:with_markdown
    519 	hi clear markdownCode
    520 	hi clear markdownCodeBlock
    521 	hi clear markdownCodeDelimiter
    522 	hi clear markdownLinkDelimiter
    523       endif
    524     endtry
    525   endif
    526 
    527   " HTML enables spell checking for all text that is not in a syntax
    528   " item (:syntax spell toplevel); instead, limit spell checking to
    529   " items matchable with syntax groups containing the @Spell cluster.
    530   try
    531     syntax spell default
    532   catch /\<E390:/
    533     call s:ReportOnce(v:exception)
    534   endtry
    535 
    536   if s:with_markdown
    537     exec 'syn region javaMarkdownComment start="///" skip="^\s*///.*$" end="^" keepend contains=javaMarkdownCommentTitle,javaMarkdownShortcutLink,@javaMarkdown,@javaDocTags,javaTodo,@Spell nextgroup=javaMarkdownCommentTitle ' . s:ff.QueryFoldArgForSyntaxItems('d')
    538     syn match javaMarkdownCommentMask	contained "^\s*///"
    539     exec 'syn region javaMarkdownCommentTitle contained matchgroup=javaMarkdownComment start="\%(///.*\r\=\n\s*\)\@' . s:ff.PeekFor('javaMarkdownCommentTitle', 120) . '<!///" matchgroup=javaMarkdownCommentTitle end="\.$" end="\.[ \t\r]\@=" end="\n\%(\s*///\s*$\)\@=" end="\%(^\s*///\s*\)\@' . s:ff.PeekFor('javaMarkdownCommentTitle', 120) . '<=@"me=s-2,he=s-1 contains=javaMarkdownShortcutLink,@javaMarkdown,javaMarkdownCommentMask,javaTodo,@Spell,@javaDocTags'
    540     exec 'syn region javaMarkdownCommentTitle contained matchgroup=javaMarkdownComment start="\%(///.*\r\=\n\s*\)\@' . s:ff.PeekFor('javaMarkdownCommentTitle', 120) . '<!///\s*\%({@return\>\)\@=" matchgroup=javaMarkdownCommentTitle end="}\%(\s*\.*\)*" contains=javaMarkdownShortcutLink,@javaMarkdown,javaMarkdownCommentMask,javaTodo,@Spell,@javaDocTags,javaTitleSkipBlock'
    541     exec 'syn region javaMarkdownCommentTitle contained matchgroup=javaMarkdownComment start="\%(///.*\r\=\n\s*\)\@' . s:ff.PeekFor('javaMarkdownCommentTitle', 120) . '<!///\s*\%({@summary\>\)\@=" matchgroup=javaMarkdownCommentTitle end="}" contains=javaMarkdownShortcutLink,@javaMarkdown,javaMarkdownCommentMask,javaTodo,@Spell,@javaDocTags,javaTitleSkipBlock'
    542 
    543     " REDEFINE THE MARKDOWN ITEMS ANCHORED WITH "^", OBSERVING THE
    544     " DEFINITION ORDER.
    545     syn match markdownLineStart		contained "^\s*///\s*[<@]\@!" contains=@markdownBlock,javaMarkdownCommentTitle,javaMarkdownCommentMask nextgroup=@markdownBlock,htmlSpecialChar
    546     " See https://spec.commonmark.org/0.31.2/#setext-headings.
    547     syn match markdownH1		contained "^\s*/// \{,3}.\+\r\=\n\s*/// \{,3}=\+\s*$" contains=@markdownInline,markdownHeadingRule,markdownAutomaticLink,javaMarkdownCommentMask
    548     syn match markdownH2		contained "^\s*/// \{,3}.\+\r\=\n\s*/// \{,3}-\+\s*$" contains=@markdownInline,markdownHeadingRule,markdownAutomaticLink,javaMarkdownCommentMask
    549     " See https://spec.commonmark.org/0.31.2/#atx-headings.
    550     syn region markdownH1		contained matchgroup=markdownH1Delimiter start=" \{,3}#\s" end="#*\s*$" keepend contains=@markdownInline,markdownAutomaticLink oneline
    551     syn region markdownH2		contained matchgroup=markdownH2Delimiter start=" \{,3}##\s" end="#*\s*$" keepend contains=@markdownInline,markdownAutomaticLink oneline
    552     syn match markdownHeadingRule	contained "^\s*/// \{,3}[=-]\+\s*$" contains=javaMarkdownCommentMask
    553     " See https://spec.commonmark.org/0.31.2/#thematic-breaks.
    554     syn match markdownRule		contained "^\s*/// \{,3}\*\s*\*\%(\s*\*\)\+\s*$" contains=javaMarkdownCommentMask
    555     syn match markdownRule		contained "^\s*/// \{,3}_\s*_\%(\s*_\)\+\s*$" contains=javaMarkdownCommentMask
    556     syn match markdownRule		contained "^\s*/// \{,3}-\s*-\%(\s*-\)\+\s*$" contains=javaMarkdownCommentMask
    557     " See https://spec.commonmark.org/0.31.2/#indented-code-blocks.
    558     syn region markdownCodeBlock	contained start="^\s*///\%( \{4,}\|\t\)" end="^\ze\s*///\%(\s*$\| \{,3}\S\)" keepend contains=javaMarkdownCommentMask
    559     " See https://spec.commonmark.org/0.31.2/#code-spans.
    560     syn region markdownCode		contained matchgroup=markdownCodeDelimiter start="\z(`\+\) \=" end=" \=\z1" keepend contains=markdownLineStart,javaMarkdownCommentMask
    561     " See https://spec.commonmark.org/0.31.2/#fenced-code-blocks.
    562     syn region markdownCodeBlock	contained start="^\s*/// \{,3}\z(```\+\)\%(.\{-}[^`]`\)\@!" end="^\s*/// \{,3}\z1`*" keepend contains=javaMarkdownCommentMask
    563     syn region markdownCodeBlock	contained start="^\s*/// \{,3}\z(\~\~\~\+\)" end="^\s*/// \{,3}\z1\~*" keepend contains=javaMarkdownCommentMask
    564     " See https://spec.commonmark.org/0.31.2/#link-reference-definitions.
    565     syn region markdownIdDeclaration	contained matchgroup=markdownLinkDelimiter start="^\s*/// \{,3\}!\=\[" end="\]:" keepend contains=javaMarkdownCommentMask nextgroup=markdownUrl oneline skipwhite
    566     " See https://spec.commonmark.org/0.31.2/#link-label.
    567     syn region markdownId		contained matchgroup=markdownIdDelimiter start="\[\%([\t ]\]\)\@!" end="\]" contains=javaMarkdownSkipBrackets,javaMarkdownCommentMask
    568     " Note that escaped brackets can be unbalanced.
    569     syn match javaMarkdownSkipBrackets	contained transparent "\\\[\|\\\]"
    570     " See https://spec.commonmark.org/0.31.2/#shortcut-reference-link.
    571     syn region javaMarkdownShortcutLink	contained matchgroup=markdownLinkTextDelimiter start="!\=\[^\@!\%(\_[^][]*\%(\[\_[^][]*\]\_[^][]*\)*]\%([[(]\)\@!\)\@=" end="\]\%([[(]\)\@!" contains=@markdownInline,markdownLineStart,javaMarkdownSkipBrackets,javaMarkdownCommentMask nextgroup=markdownLink,markdownId skipwhite
    572 
    573     for s:name in ['markdownFootnoteDefinition', 'markdownFootnote']
    574       if hlexists(s:name)
    575 	exec 'syn clear ' . s:name
    576       endif
    577     endfor
    578 
    579     unlet s:name
    580 
    581     " COMBAK: Footnotes are recognised by "markdown.vim", but are not
    582     " in CommonMark.  See https://pandoc.org/MANUAL.html#footnotes.
    583 """"syn match markdownFootnoteDefinition contained "^\s*///\s*\[^[^\]]\+\]:" contains=javaMarkdownCommentMask
    584 
    585     hi def link javaMarkdownComment	Comment
    586     hi def link javaMarkdownCommentMask	javaMarkdownComment
    587     hi def link javaMarkdownCommentTitle SpecialComment
    588     hi def link javaMarkdownShortcutLink htmlLink
    589   endif
    590 
    591   if s:with_html
    592     exec 'syn region javaDocComment start="/\*\*" end="\*/" keepend contains=javaCommentTitle,@javaHtml,@javaDocTags,javaTodo,javaCommentError,javaSpaceError,@Spell ' . s:ff.QueryFoldArgForSyntaxItems('d')
    593     exec 'syn region javaCommentTitle contained matchgroup=javaDocComment start="/\*\*" matchgroup=javaCommentTitle end="\.$" end="\.[ \t\r]\@=" end="\%(^\s*\**\s*\)\@' . s:ff.PeekFor('javaCommentTitle', 120) . '<=@"me=s-2,he=s-1 end="\*/"me=s-1,he=s-1 contains=@javaHtml,javaCommentStar,javaTodo,javaCommentError,javaSpaceError,@Spell,@javaDocTags'
    594     syn region javaCommentTitle	contained matchgroup=javaDocComment start="/\*\*\s*\r\=\n\=\s*\**\s*\%({@return\>\)\@=" matchgroup=javaCommentTitle end="}\%(\s*\.*\)*" contains=@javaHtml,javaCommentStar,javaTodo,javaCommentError,javaSpaceError,@Spell,@javaDocTags,javaTitleSkipBlock
    595     syn region javaCommentTitle	contained matchgroup=javaDocComment start="/\*\*\s*\r\=\n\=\s*\**\s*\%({@summary\>\)\@=" matchgroup=javaCommentTitle end="}" contains=@javaHtml,javaCommentStar,javaTodo,javaCommentError,javaSpaceError,@Spell,@javaDocTags,javaTitleSkipBlock
    596     hi def link javaDocComment		Comment
    597     hi def link javaCommentTitle	SpecialComment
    598   endif
    599 
    600   " The members of javaDocTags are sub-grouped according to the Java
    601   " version of their introduction, and sub-group members in turn are
    602   " arranged in alphabetical order, so that future newer members can
    603   " be pre-sorted and appended without disturbing the current member
    604   " placement.
    605   " Since they only have significance in javaCommentTitle, neither
    606   " javaDocSummaryTag nor javaDocReturnTitleTag are defined.
    607   syn cluster javaDocTags	contains=javaDocAuthorTag,javaDocDeprecatedTag,javaDocExceptionTag,javaDocParamTag,javaDocReturnTag,javaDocSeeTag,javaDocVersionTag,javaDocSinceTag,javaDocLinkTag,javaDocSerialTag,javaDocSerialDataTag,javaDocSerialFieldTag,javaDocThrowsTag,javaDocDocRootTag,javaDocInheritDocTag,javaDocLinkplainTag,javaDocValueTag,javaDocCodeTag,javaDocLiteralTag,javaDocHiddenTag,javaDocIndexTag,javaDocProvidesTag,javaDocUsesTag,javaDocSystemPropertyTag,javaDocSnippetTag,javaDocSpecTag
    608 
    609   " Anticipate non-standard inline tags in {@return} and {@summary}.
    610   syn region javaTitleSkipBlock	contained transparent start="{\%(@\%(return\|summary\)\>\)\@!" end="}"
    611   syn match  javaDocDocRootTag	contained "{@docRoot}"
    612   syn match  javaDocInheritDocTag contained "{@inheritDoc}"
    613   syn region javaIndexSkipBlock	contained transparent start="{\%(@index\>\)\@!" end="}" contains=javaIndexSkipBlock,javaDocIndexTag
    614   syn region javaDocIndexTag	contained start="{@index\>" end="}" contains=javaDocIndexTag,javaIndexSkipBlock
    615   syn region javaLinkSkipBlock	contained transparent start="{\%(@link\>\)\@!" end="}" contains=javaLinkSkipBlock,javaDocLinkTag
    616   syn region javaDocLinkTag	contained start="{@link\>" end="}" contains=javaDocLinkTag,javaLinkSkipBlock
    617   syn region javaLinkplainSkipBlock contained transparent start="{\%(@linkplain\>\)\@!" end="}" contains=javaLinkplainSkipBlock,javaDocLinkplainTag
    618   syn region javaDocLinkplainTag contained start="{@linkplain\>" end="}" contains=javaDocLinkplainTag,javaLinkplainSkipBlock
    619   syn region javaLiteralSkipBlock contained transparent start="{\%(@literal\>\)\@!" end="}" contains=javaLiteralSkipBlock,javaDocLiteralTag
    620   syn region javaDocLiteralTag	contained start="{@literal\>" end="}" contains=javaDocLiteralTag,javaLiteralSkipBlock
    621   syn region javaSystemPropertySkipBlock contained transparent start="{\%(@systemProperty\>\)\@!" end="}" contains=javaSystemPropertySkipBlock,javaDocSystemPropertyTag
    622   syn region javaDocSystemPropertyTag contained start="{@systemProperty\>" end="}" contains=javaDocSystemPropertyTag,javaSystemPropertySkipBlock
    623   syn region javaValueSkipBlock	contained transparent start="{\%(@value\>\)\@!" end="}" contains=javaValueSkipBlock,javaDocValueTag
    624   syn region javaDocValueTag	contained start="{@value\>" end="}" contains=javaDocValueTag,javaValueSkipBlock
    625 
    626   syn match  javaDocParam	contained "\s\zs\S\+"
    627   syn match  javaDocExceptionTag contained "@exception\s\+\S\+" contains=javaDocParam
    628   syn match  javaDocParamTag	contained "@param\s\+\S\+" contains=javaDocParam
    629   syn match  javaDocSinceTag	contained "@since\s\+\S\+" contains=javaDocParam
    630   syn match  javaDocThrowsTag	contained "@throws\s\+\S\+" contains=javaDocParam
    631   syn match  javaDocSpecTag	contained "@spec\_s\+\S\+\ze\_s\+\S\+" contains=javaDocParam
    632 
    633   syn match  javaDocAuthorTag	contained "@author\>"
    634   syn match  javaDocDeprecatedTag contained "@deprecated\>"
    635   syn match  javaDocHiddenTag	contained "@hidden\>"
    636   syn match  javaDocReturnTag	contained "@return\>"
    637   syn match  javaDocSerialTag	contained "@serial\>"
    638   syn match  javaDocSerialDataTag contained "@serialData\>"
    639   syn match  javaDocSerialFieldTag contained "@serialField\>"
    640   syn match  javaDocVersionTag	contained "@version\>"
    641 
    642   syn match javaDocSeeTag contained "@see\>\s*" nextgroup=javaDocSeeTag1,javaDocSeeTag2,javaDocSeeTag3,javaDocSeeTag4,javaDocSeeTagStar,javaDocSeeTagSlash skipwhite skipempty
    643 
    644   if s:with_html
    645     syn match  javaDocSeeTagStar contained "^\s*\*\+\%(\s*{\=@\|/\|$\)\@!" nextgroup=javaDocSeeTag1,javaDocSeeTag2,javaDocSeeTag3,javaDocSeeTag4 skipwhite skipempty
    646     hi def link javaDocSeeTagStar javaDocComment
    647   endif
    648 
    649   if s:with_markdown
    650     syn match  javaDocSeeTagSlash contained "^\s*///\%(\s*{\=@\|$\)\@!" nextgroup=javaDocSeeTag1,javaDocSeeTag2,javaDocSeeTag3,javaDocSeeTag4 skipwhite skipempty
    651     hi def link javaDocSeeTagSlash javaMarkdownComment
    652   endif
    653 
    654   syn match  javaDocSeeTag1	contained @"\_[^"]\+"@
    655   syn match  javaDocSeeTag2	contained @<a\s\+\_.\{-}</a>@ contains=@javaHtml extend
    656   exec 'syn match javaDocSeeTag3 contained @[' . s:ff.WithMarkdown('[', '') . '"< \t]\@!\%(\k\|[/.]\)*\%(##\=\k\+\%((\_[^)]*)\)\=\)\=@ nextgroup=javaDocSeeTag3Label skipwhite skipempty'
    657   syn match  javaDocSeeTag3Label contained @\k\%(\k\+\s*\)*$@
    658 
    659   " COMBAK: No support for type javaDocSeeTag2 in Markdown.
    660 ""if s:with_markdown
    661 ""  syn match  javaDocSeeTag4	contained @\[.\+\]\s\=\%(\[.\+\]\|(.\+)\)@ contains=@javaMarkdown extend
    662 ""  hi def link javaDocSeeTag4	Special
    663 ""endif
    664 
    665   syn region javaCodeSkipBlock	contained transparent start="{\%(@code\>\)\@!" end="}" contains=javaCodeSkipBlock,javaDocCodeTag
    666   syn region javaDocCodeTag	contained start="{@code\>" end="}" contains=javaDocCodeTag,javaCodeSkipBlock
    667 
    668   exec 'syn region javaDocSnippetTagAttr contained transparent matchgroup=javaHtmlArg start=/\<\%(class\|file\|id\|lang\|region\)\%(\s*=\)\@=/ matchgroup=javaHtmlString end=/:$/ end=/\%(=\s*\)\@' . s:ff.PeekFor('javaDocSnippetTagAttr', 80) . '<=\%("[^"]\+"\|' . "\x27[^\x27]\\+\x27" . '\|\%([.\\/-]\|\k\)\+\)/ nextgroup=javaDocSnippetTagAttr skipwhite skipnl'
    669   syn region javaSnippetSkipBlock contained transparent start="{\%(@snippet\>\)\@!" end="}" contains=javaSnippetSkipBlock,javaDocSnippetTag,javaCommentMarkupTag
    670   syn region javaDocSnippetTag	contained start="{@snippet\>" end="}" contains=javaDocSnippetTag,javaSnippetSkipBlock,javaDocSnippetTagAttr,javaCommentMarkupTag
    671 
    672   syntax case match
    673   hi def link javaDocParam		Function
    674 
    675   hi def link javaDocAuthorTag		Special
    676   hi def link javaDocCodeTag		Special
    677   hi def link javaDocDeprecatedTag	Special
    678   hi def link javaDocDocRootTag		Special
    679   hi def link javaDocExceptionTag	Special
    680   hi def link javaDocHiddenTag		Special
    681   hi def link javaDocIndexTag		Special
    682   hi def link javaDocInheritDocTag	Special
    683   hi def link javaDocLinkTag		Special
    684   hi def link javaDocLinkplainTag	Special
    685   hi def link javaDocLiteralTag		Special
    686   hi def link javaDocParamTag		Special
    687   hi def link javaDocReturnTag		Special
    688   hi def link javaDocSeeTag		Special
    689   hi def link javaDocSeeTag1		String
    690   hi def link javaDocSeeTag2		Special
    691   hi def link javaDocSeeTag3		Function
    692   hi def link javaDocSerialTag		Special
    693   hi def link javaDocSerialDataTag	Special
    694   hi def link javaDocSerialFieldTag	Special
    695   hi def link javaDocSinceTag		Special
    696   hi def link javaDocSnippetTag		Special
    697   hi def link javaDocSpecTag		Special
    698   hi def link javaDocSystemPropertyTag	Special
    699   hi def link javaDocThrowsTag		Special
    700   hi def link javaDocValueTag		Special
    701   hi def link javaDocVersionTag		Special
    702 endif
    703 
    704 " match the special comment /**/
    705 syn match   javaComment		"/\*\*/"
    706 
    707 " Strings and constants
    708 syn match   javaSpecialError	contained "\\."
    709 syn match   javaSpecialCharError contained "[^']"
    710 " Escape Sequences (JLS-17, §3.10.7):
    711 syn match   javaSpecialChar	contained "\\\%(u\x\x\x\x\|[0-3]\o\o\|\o\o\=\|[bstnfr"'\\]\)"
    712 syn region  javaString		start=+"+ end=+"+ end=+$+ contains=javaSpecialChar,javaSpecialError,@Spell
    713 syn region  javaString		start=+"""[ \t\x0c\r]*$+hs=e+1 end=+"""+he=s-1 contains=javaSpecialChar,javaSpecialError,javaTextBlockError,@Spell
    714 syn match   javaTextBlockError	+"""\s*"""+
    715 
    716 if s:ff.IsAnyRequestedPreviewFeatureOf([430])
    717   syn region javaStrTemplEmbExp	contained matchgroup=javaStrTempl start="\\{" end="}" contains=TOP,javaImportDeclBlock
    718   exec 'syn region javaStrTempl start=+\%(\.[[:space:]\n]*\)\@' . s:ff.PeekFor('javaStrTempl', 80) . '<="+ end=+"+ contains=javaStrTemplEmbExp,javaSpecialChar,javaSpecialError,@Spell'
    719   exec 'syn region javaStrTempl start=+\%(\.[[:space:]\n]*\)\@' . s:ff.PeekFor('javaStrTempl', 80) . '<="""[ \t\x0c\r]*$+hs=e+1 end=+"""+he=s-1 contains=javaStrTemplEmbExp,javaSpecialChar,javaSpecialError,javaTextBlockError,@Spell'
    720   hi def link javaStrTempl	Macro
    721 endif
    722 
    723 syn match   javaCharacter	"'[^']*'" contains=javaSpecialChar,javaSpecialCharError
    724 syn match   javaCharacter	"'\\''" contains=javaSpecialChar
    725 syn match   javaCharacter	"'[^\\]'"
    726 " Integer literals (JLS-17, §3.10.1):
    727 syn keyword javaNumber		0 0l 0L
    728 syn match   javaNumber		"\<\%(0\%([xX]\x\%(_*\x\)*\|_*\o\%(_*\o\)*\|[bB][01]\%(_*[01]\)*\)\|[1-9]\%(_*\d\)*\)[lL]\=\>"
    729 " Decimal floating-point literals (JLS-17, §3.10.2):
    730 " Against "\<\d\+\>\.":
    731 syn match   javaNumber		"\<\d\%(_*\d\)*\."
    732 syn match   javaNumber		"\%(\<\d\%(_*\d\)*\.\%(\d\%(_*\d\)*\)\=\|\.\d\%(_*\d\)*\)\%([eE][-+]\=\d\%(_*\d\)*\)\=[fFdD]\=\>"
    733 syn match   javaNumber		"\<\d\%(_*\d\)*[eE][-+]\=\d\%(_*\d\)*[fFdD]\=\>"
    734 syn match   javaNumber		"\<\d\%(_*\d\)*\%([eE][-+]\=\d\%(_*\d\)*\)\=[fFdD]\>"
    735 " Hexadecimal floating-point literals (JLS-17, §3.10.2):
    736 syn match   javaNumber		"\<0[xX]\%(\x\%(_*\x\)*\.\=\|\%(\x\%(_*\x\)*\)\=\.\x\%(_*\x\)*\)[pP][-+]\=\d\%(_*\d\)*[fFdD]\=\>"
    737 
    738 " Unicode characters
    739 syn match   javaSpecial "\\u\x\x\x\x"
    740 
    741 " Method declarations (JLS-17, §8.4.3, §8.4.4, §9.4).
    742 if exists("g:java_highlight_functions")
    743   syn cluster javaFuncParams contains=javaAnnotation,@javaClasses,javaGenerics,javaType,javaVarArg,javaComment,javaLineComment
    744 
    745   if exists("g:java_highlight_signature")
    746     syn cluster javaFuncParams add=javaParamModifier
    747     hi def link javaFuncDefStart javaFuncDef
    748   else
    749     syn cluster javaFuncParams add=javaScopeDecl,javaConceptKind,javaStorageClass,javaExternal,javaTypeParamSection
    750   endif
    751 
    752   if g:java_highlight_functions =~# '^indent[1-8]\=$'
    753     let s:last = g:java_highlight_functions[-1 :]
    754     let s:indent = s:last != 't' ? repeat("\x20", s:last) : "\t"
    755     " Try to not match other type members, initialiser blocks, enum
    756     " constants (JLS-17, §8.9.1), and constructors (JLS-17, §8.1.7):
    757     " at any _conventional_ indentation, skip over all fields with
    758     " "[^=]*", all records with "\<record\s", and let the "*Skip*"
    759     " definitions take care of constructor declarations and enum
    760     " constants (with no support for @Foo(value = "bar")).  Also,
    761     " reject inlined declarations with "[^{;]" for signature.
    762     exec 'syn region javaFuncDef ' . s:ff.GroupArgs('transparent matchgroup=javaFuncDefStart', '') . ' start="' . s:ff.PeekTo('\%(', '') . '^' . s:indent . '\%(<\%(/\*.\{-}\*/\|[^(){}>]\|\n\)\+>\+\s\+\|\%(\%(@\%(\K\k*\.\)*\K\k*\>\)\s\+\)\+\)\=\%(\<\K\k*\>\.\)*\K\k*\>[^={;]*\%(\<record\)\@' . s:ff.Peek('6', '') . '<!\s' . s:ff.PeekFrom('\)\@' . s:ff.PeekFor('javaFuncDef', 120) . '<=', '') . '\K\k*\s*(" end=")" contains=@javaFuncParams'
    763     " As long as package-private constructors cannot be matched with
    764     " javaFuncDef, do not look with javaConstructorSkipDeclarator for
    765     " them.  (Approximate "javaTypeParamSection" if necessary.)
    766     exec 'syn match javaConstructorSkipDeclarator transparent "^' . s:indent . '\%(\%(@\%(\K\k*\.\)*\K\k*\>\)\s\+\)*p\%(ublic\|rotected\|rivate\)\s\+\%(<\%(/\*.\{-}\*/\|[^(){}>]\|\n\)\+>\+\s\+\)\=\K\k*\s*(\@=" contains=javaAnnotation,javaScopeDecl,javaTypeParamSection,javaClassDecl,javaTypedef,javaType,@javaClasses,javaGenerics,javaComment,javaLineComment'
    767     " With a zero-width span for signature applicable on demand to
    768     " javaFuncDef, make related adjustments:
    769     " (1) Claim all enum constants of a line as a unit.
    770     exec 'syn match javaEnumSkipConstant contained transparent /^' . s:indent . '\%(\%(\%(@\%(\K\k*\.\)*\K\k*\>\)\s\+\)*\K\k*\s*\%((.*)\)\=\s*[,;({]\s*\)\+/ contains=@javaEnumConstants'
    771     " (2) Define javaTopEnum{Block,Declaration} for top level enums
    772     " and tell apart their constants from method declarations.
    773     syn region javaTopEnumBlock contained transparent matchgroup=javaTopEnumBlockStart start="{" end="}" contains=@javaTop,javaEnumSkipConstant
    774     exec 'syn match javaTopEnumDeclaration transparent /\%(^\%(\%(@\%(\K\k*\.\)*\K\k*\>\)\s\+\)*\%(p\%(ublic\|rotected\|rivate\)\s\+\)\=\%(strictfp\s\+\)\=\<enum\_s\+\)\@' . s:ff.PeekFor('javaTopEnumDeclaration', 80) . '<=\K\k*\%(\_s\+implements\_s.\+\)\=\_s*{\@=/ nextgroup=javaTopEnumBlock skipwhite skipempty'
    775     " (3) Define a base variant of javaParenT without using @javaTop
    776     " in order to not include javaFuncDef.
    777     syn region javaParenE transparent matchgroup=javaParen start="(" end=")" contains=@javaEnumConstants,javaInParen
    778     syn region javaParenE transparent matchgroup=javaParen start="\[" end="\]" contains=@javaEnumConstants
    779     syn cluster javaEnumConstants contains=TOP,javaTopEnumDeclaration,javaImportDeclBlock,javaFuncDef,javaParenT
    780     unlet s:indent s:last
    781   else
    782     " This is the "style" variant (:help ft-java-syntax).
    783 
    784     " Match arbitrarily indented camelCasedName method declarations.
    785     " Match: [@ɐ] [abstract] [<α, β>] Τʬ[<γ>][[][]] μʭʭ(/* ... */);
    786     exec 'syn region javaFuncDef ' . s:ff.GroupArgs('transparent matchgroup=javaFuncDefStart', '') . ' start=/' . s:ff.Engine('\%#=2', '') . s:ff.PeekTo('\%(', '') . '^\s\+\%(\%(@\%(\K\k*\.\)*\K\k*\>\)\s\+\)*\%(p\%(ublic\|rotected\|rivate\)\s\+\)\=\%(\%(abstract\|default\)\s\+\|\%(\%(final\|\%(native\|strictfp\)\|s\%(tatic\|ynchronized\)\)\s\+\)*\)\=\%(<' . s:vv.type_param_list . '>\s\+\)\=\%(' . s:vv.void_or_param_type . '\)\s\+' . s:ff.PeekFrom('\)\@' . s:ff.PeekFor('javaFuncDef', 120) . '<=', '') . '\<' . s:ff.LowerCase('[$_[:lower:]]', '[^A-Z0-9]') . '\k*\>\s*(/ end=/)/ skip=/\/\*.\{-}\*\/\|\/\/.*$/ contains=@javaFuncParams'
    787   endif
    788 endif
    789 
    790 if exists("g:java_highlight_debug")
    791   " Strings and constants
    792   syn match   javaDebugSpecial		contained "\\\%(u\x\x\x\x\|[0-3]\o\o\|\o\o\=\|[bstnfr"'\\]\)"
    793   syn region  javaDebugString		contained start=+"+ end=+"+ contains=javaDebugSpecial
    794   syn region  javaDebugString		contained start=+"""[ \t\x0c\r]*$+hs=e+1 end=+"""+he=s-1 contains=javaDebugSpecial,javaDebugTextBlockError
    795 
    796   if s:ff.IsAnyRequestedPreviewFeatureOf([430])
    797     " The highlight groups of java{StrTempl,Debug{,Paren,StrTempl}}\,
    798     " share one colour by default. Do not conflate unrelated parens.
    799     syn region javaDebugStrTemplEmbExp	contained matchgroup=javaDebugStrTempl start="\\{" end="}" contains=javaComment,javaLineComment,javaDebug\%(Paren\)\@!.*
    800     exec 'syn region javaDebugStrTempl contained start=+\%(\.[[:space:]\n]*\)\@' . s:ff.PeekFor('javaDebugStrTempl', 80) . '<="+ end=+"+ contains=javaDebugStrTemplEmbExp,javaDebugSpecial'
    801     exec 'syn region javaDebugStrTempl contained start=+\%(\.[[:space:]\n]*\)\@' . s:ff.PeekFor('javaDebugStrTempl', 80) . '<="""[ \t\x0c\r]*$+hs=e+1 end=+"""+he=s-1 contains=javaDebugStrTemplEmbExp,javaDebugSpecial,javaDebugTextBlockError'
    802     hi def link javaDebugStrTempl	Macro
    803   endif
    804 
    805   syn match   javaDebugTextBlockError	contained +"""\s*"""+
    806   syn match   javaDebugCharacter	contained "'[^\\]'"
    807   syn match   javaDebugSpecialCharacter contained "'\\.'"
    808   syn match   javaDebugSpecialCharacter contained "'\\''"
    809   syn keyword javaDebugNumber		contained 0 0l 0L
    810   syn match   javaDebugNumber		contained "\<\d\%(_*\d\)*\."
    811   syn match   javaDebugNumber		contained "\<\%(0\%([xX]\x\%(_*\x\)*\|_*\o\%(_*\o\)*\|[bB][01]\%(_*[01]\)*\)\|[1-9]\%(_*\d\)*\)[lL]\=\>"
    812   syn match   javaDebugNumber		contained "\%(\<\d\%(_*\d\)*\.\%(\d\%(_*\d\)*\)\=\|\.\d\%(_*\d\)*\)\%([eE][-+]\=\d\%(_*\d\)*\)\=[fFdD]\=\>"
    813   syn match   javaDebugNumber		contained "\<\d\%(_*\d\)*[eE][-+]\=\d\%(_*\d\)*[fFdD]\=\>"
    814   syn match   javaDebugNumber		contained "\<\d\%(_*\d\)*\%([eE][-+]\=\d\%(_*\d\)*\)\=[fFdD]\>"
    815   syn match   javaDebugNumber		contained "\<0[xX]\%(\x\%(_*\x\)*\.\=\|\%(\x\%(_*\x\)*\)\=\.\x\%(_*\x\)*\)[pP][-+]\=\d\%(_*\d\)*[fFdD]\=\>"
    816   syn keyword javaDebugBoolean		contained true false
    817   syn keyword javaDebugType		contained null this super
    818   syn region  javaDebugParen		contained start=+(+ end=+)+ contains=javaDebug.*,javaDebugParen
    819 
    820   " To make this work, define the highlighting for these groups.
    821   syn match javaDebug "\<System\.\%(out\|err\)\.print\%(ln\)\=\s*("me=e-1 contains=javaDebug.* nextgroup=javaDebugParen
    822 " FIXME: What API does "p" belong to?
    823 " syn match javaDebug "\<p\s*("me=e-1 contains=javaDebug.* nextgroup=javaDebugParen
    824   syn match javaDebug "\<\K\k*\.printStackTrace\s*("me=e-1 contains=javaDebug.* nextgroup=javaDebugParen
    825 " FIXME: What API do "trace*" belong to?
    826 " syn match javaDebug "\<trace[SL]\=\s*("me=e-1 contains=javaDebug.* nextgroup=javaDebugParen
    827 
    828   hi def link javaDebug			Debug
    829   hi def link javaDebugString		DebugString
    830   hi def link javaDebugTextBlockError	Error
    831   hi def link javaDebugType		DebugType
    832   hi def link javaDebugBoolean		DebugBoolean
    833   hi def link javaDebugNumber		Debug
    834   hi def link javaDebugSpecial		DebugSpecial
    835   hi def link javaDebugSpecialCharacter	DebugSpecial
    836   hi def link javaDebugCharacter	DebugString
    837   hi def link javaDebugParen		Debug
    838 
    839   hi def link DebugString		String
    840   hi def link DebugSpecial		Special
    841   hi def link DebugBoolean		Boolean
    842   hi def link DebugType			Type
    843 endif
    844 
    845 " Complement javaBlock and javaInParen for highlighting.
    846 syn region javaBlockOther transparent matchgroup=javaBlockOtherStart start="{" end="}"
    847 
    848 " Try not to fold top-level-type bodies under assumption that there is
    849 " but one such body.
    850 exec 'syn region javaBlock transparent matchgroup=javaBlockStart start="\%(^\|^\S[^:]\+\)\@' . s:ff.PeekFor('javaBlock', 120) . '<!{" end="}" ' . s:ff.QueryFoldArgForSyntaxItems('b')
    851 
    852 " See "D.2.1 Anonymous Classes" at
    853 " https://web.archive.org/web/20010821025330/java.sun.com/docs/books/jls/first_edition/html/1.1Update.html#12959.
    854 if exists("g:java_mark_braces_in_parens_as_errors")
    855   syn match javaInParen contained "[{}]"
    856   hi def link javaInParen javaError
    857 endif
    858 
    859 " catch errors caused by wrong parenthesis
    860 syn region  javaParenT	transparent matchgroup=javaParen start="(" end=")" contains=@javaTop,javaInParen,javaParenT1
    861 syn region  javaParenT1 contained transparent matchgroup=javaParen1 start="(" end=")" contains=@javaTop,javaInParen,javaParenT2
    862 syn region  javaParenT2 contained transparent matchgroup=javaParen2 start="(" end=")" contains=@javaTop,javaInParen,javaParenT
    863 syn match   javaParenError ")"
    864 " catch errors caused by wrong square parenthesis
    865 syn region  javaParenT	transparent matchgroup=javaParen start="\[" end="\]" contains=@javaTop,javaParenT1
    866 syn region  javaParenT1 contained transparent matchgroup=javaParen1 start="\[" end="\]" contains=@javaTop,javaParenT2
    867 syn region  javaParenT2 contained transparent matchgroup=javaParen2 start="\[" end="\]" contains=@javaTop,javaParenT
    868 syn match   javaParenError "\]"
    869 
    870 " Lambda expressions (JLS-17, §15.27) and method reference expressions
    871 " (JLS-17, §15.13).
    872 if exists("g:java_highlight_functions")
    873   syn match javaMethodRef ":::\@!"
    874 
    875   if exists("g:java_highlight_signature")
    876     let s:ff.LambdaDef = s:ff.LeftConstant
    877   else
    878     let s:ff.LambdaDef = s:ff.RightConstant
    879   endif
    880 
    881   " Make ()-matching definitions after the parenthesis error catcher.
    882   "
    883   " Note that here and elsewhere a single-line token is used for \z,
    884   " with other tokens repeated as necessary, to overcome the lack of
    885   " support for multi-line matching with \z.
    886   "
    887   " Match: ([@A [@B ...] final] var a[, var b, ...]) ->
    888   "	| ([@A [@B ...] final] T[<α>][[][]] a[, T b, ...]) ->
    889   " Expressions interspersed with comments are not recognised.
    890   exec 'syn ' . s:ff.LambdaDef('region javaLambdaDef transparent matchgroup=javaLambdaDefStart start=/', 'match javaLambdaDef "') . '\k\@' . s:ff.Peek('4', '') . '<!(' . s:ff.LambdaDef('\%(', '') . '[[:space:]\n]*\%(\%(@\%(\K\k*\.\)*\K\k*\>\%((\_.\{-1,})\)\{-,1}[[:space:]\n]\+\)*\%(final[[:space:]\n]\+\)\=\%(\<\K\k*\>\.\)*\<\K\k*\>\%(<\%([^(){}]\|\n\)\+[[:space:]-]\@' . s:ff.Peek('1', '') . '<!>\)\=\%(\%(\%(\[\]\)\+\|\.\.\.\)\)\=[[:space:]\n]\+\<\K\k*\>\%(\[\]\)*\%(,[[:space:]\n]*\)\=\)\+)[[:space:]\n]*' . s:ff.LambdaDef('\z(->\)\)\@=/ end=/)[[:space:]\n]*\z1/', '->"') . ' contains=javaAnnotation,javaParamModifier,javaLambdaVarType,javaType,@javaClasses,javaGenerics,javaVarArg'
    891   " Match: () ->
    892   "	| (a[, b, ...]) ->
    893   exec 'syn ' . s:ff.LambdaDef('region javaLambdaDef transparent matchgroup=javaLambdaDefStart start=/', 'match javaLambdaDef "') . '\k\@' . s:ff.Peek('4', '') . '<!(' . s:ff.LambdaDef('\%(', '') . '[[:space:]\n]*\%(\<\K\k*\>\%(,[[:space:]\n]*\)\=\)*)[[:space:]\n]*' . s:ff.LambdaDef('\z(->\)\)\@=/ end=/)[[:space:]\n]*\z1/', '->"')
    894   " Match: a ->
    895   exec 'syn ' . s:ff.LambdaDef('region javaLambdaDef transparent start=/', 'match javaLambdaDef "') . '\<\K\k*\>\%(\<default\>\)\@' . s:ff.Peek('7', '') . '<!' . s:ff.LambdaDef('\%([[:space:]\n]*\z(->\)\)\@=/ matchgroup=javaLambdaDefStart end=/\z1/', '[[:space:]\n]*->"')
    896 
    897   syn keyword javaParamModifier contained final
    898   syn keyword javaLambdaVarType contained var
    899   hi def link javaParamModifier		javaConceptKind
    900   hi def link javaLambdaVarType		javaOperator
    901   hi def link javaLambdaDef		javaFuncDef
    902   hi def link javaLambdaDefStart	javaFuncDef
    903   hi def link javaMethodRef		javaFuncDef
    904   hi def link javaFuncDef		Function
    905 endif
    906 
    907 " The @javaTop cluster comprises non-contained Java syntax groups.
    908 " Note that the syntax file "aidl.vim" relies on its availability.
    909 syn cluster javaTop contains=TOP,javaTopEnumDeclaration
    910 
    911 if !exists("g:java_minlines")
    912   let g:java_minlines = 10
    913 endif
    914 
    915 " Note that variations of a /*/ balanced comment, e.g., /*/*/, /*//*/,
    916 " /* /*/, /*  /*/, etc., may have their rightmost /*/ part accepted
    917 " as a comment start by ':syntax sync ccomment'; consider alternatives
    918 " to make synchronisation start further towards file's beginning by
    919 " bumping up g:java_minlines or issuing ':syntax sync fromstart' or
    920 " preferring &foldmethod set to 'syntax'.
    921 exec "syn sync ccomment javaComment minlines=" . g:java_minlines
    922 
    923 " The default highlighting.
    924 hi def link javaVarArg			Function
    925 hi def link javaBranch			Conditional
    926 hi def link javaConditional		Conditional
    927 hi def link javaRepeat			Repeat
    928 hi def link javaExceptions		Exception
    929 hi def link javaAssert			Statement
    930 hi def link javaStorageClass		StorageClass
    931 hi def link javaMethodDecl		javaStorageClass
    932 hi def link javaClassDecl		javaStorageClass
    933 hi def link javaScopeDecl		javaStorageClass
    934 hi def link javaConceptKind		javaStorageClass
    935 
    936 hi def link javaBoolean			Boolean
    937 hi def link javaSpecial			Special
    938 hi def link javaSpecialError		Error
    939 hi def link javaSpecialCharError	Error
    940 hi def link javaString			String
    941 hi def link javaCharacter		Character
    942 hi def link javaSpecialChar		SpecialChar
    943 hi def link javaNumber			Number
    944 hi def link javaError			Error
    945 hi def link javaError2			javaError
    946 hi def link javaTextBlockError		Error
    947 hi def link javaParenError		javaError
    948 hi def link javaStatement		Statement
    949 hi def link javaOperator		Operator
    950 hi def link javaConstant		Constant
    951 hi def link javaTypedef			Typedef
    952 hi def link javaTodo			Todo
    953 hi def link javaAnnotation		PreProc
    954 hi def link javaAnnotationStart		javaAnnotation
    955 hi def link javaType			Type
    956 hi def link javaExternal		Include
    957 hi def link javaModuleImport		Statement
    958 
    959 hi def link javaUserLabel		Label
    960 hi def link javaUserLabelRef		javaUserLabel
    961 hi def link javaLabel			Label
    962 hi def link javaLabelDefault		javaLabel
    963 hi def link javaLabelVarType		javaOperator
    964 
    965 hi def link javaComment			Comment
    966 hi def link javaCommentStar		javaComment
    967 hi def link javaLineComment		Comment
    968 hi def link javaCommentMarkupTagAttr	javaHtmlArg
    969 hi def link javaCommentString		javaString
    970 hi def link javaComment2String		javaString
    971 hi def link javaCommentCharacter	javaCharacter
    972 hi def link javaCommentError		javaError
    973 hi def link javaCommentStart		javaComment
    974 
    975 hi def link javaHtmlArg			Type
    976 hi def link javaHtmlString		String
    977 
    978 let b:current_syntax = "java"
    979 
    980 if g:main_syntax == 'java'
    981   unlet g:main_syntax
    982 endif
    983 
    984 if exists("s:clear_java_ignore_html")
    985   unlet! s:clear_java_ignore_html g:java_ignore_html
    986 endif
    987 
    988 if exists("s:clear_java_ignore_markdown")
    989   unlet! s:clear_java_ignore_markdown g:java_ignore_markdown
    990 endif
    991 
    992 let b:spell_options = "contained"
    993 let &cpo = s:cpo_save
    994 unlet s:cpo_save s:ff s:vv s:with_html s:with_markdown
    995 
    996 " See ":help vim9-mix".
    997 if !has("vim9script")
    998   finish
    999 endif
   1000 
   1001 if exists("g:java_foldtext_show_first_or_second_line")
   1002   def! s:LazyPrefix(prefix: string, dashes: string, count: number): string
   1003     return empty(prefix)
   1004       ? printf('+-%s%3d lines: ', dashes, count)
   1005       : prefix
   1006   enddef
   1007 
   1008   def! s:JavaSyntaxFoldTextExpr(): string
   1009     # Piggyback on NGETTEXT.
   1010     const summary: string = foldtext()
   1011     return getline(v:foldstart) !~ '/\*\+\s*$'
   1012       ? summary
   1013       : LazyPrefix(matchstr(summary, '^+-\+\s*\d\+\s.\{-1,}:\s'),
   1014 			v:folddashes,
   1015 			(v:foldend - v:foldstart + 1)) ..
   1016 	  getline(v:foldstart + 1)
   1017   enddef
   1018 
   1019   setlocal foldtext=s:JavaSyntaxFoldTextExpr()
   1020   delfunction! g:JavaSyntaxFoldTextExpr
   1021 endif
   1022 " vim: fdm=syntax sw=2 ts=8 noet sta