vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

html.vim (19942B)


      1 " Vim syntax file
      2 " Language:		HTML
      3 " Maintainer:		Doug Kearns <dougkearns@gmail.com>
      4 " Previous Maintainers: Jorge Maldonado Ventura <jorgesumle@freakspot.net>
      5 "			Claudio Fleiner <claudio@fleiner.com>
      6 " Last Change:		2026 Sep 12
      7 
      8 " See :help html.vim for some comments and a description of the options
      9 
     10 " quit when a syntax file was already loaded
     11 if !exists("main_syntax")
     12   if exists("b:current_syntax")
     13     finish
     14   endif
     15   let main_syntax = 'html'
     16 endif
     17 
     18 let s:cpo_save = &cpo
     19 set cpo&vim
     20 
     21 syntax spell toplevel
     22 
     23 syn include @htmlXml syntax/xml.vim
     24 unlet b:current_syntax
     25 
     26 syn case ignore
     27 
     28 " mark illegal characters
     29 syn match htmlError "[<>&]"
     30 
     31 " tags
     32 syn region  htmlString	 contained start=+"+ end=+"+ contains=htmlSpecialChar,javaScriptExpression,@htmlPreproc
     33 syn region  htmlString	 contained start=+'+ end=+'+ contains=htmlSpecialChar,javaScriptExpression,@htmlPreproc
     34 syn match   htmlValue	 contained "=[\t ]*[^'" \t>][^ \t>]*"hs=s+1   contains=javaScriptExpression,@htmlPreproc
     35 syn region  htmlEndTag		   start=+</+	   end=+>+ contains=htmlTagN,htmlTagError
     36 syn region  htmlTag		   start=+<[^/]+   end=+>+ fold contains=htmlTagN,htmlString,htmlArg,htmlValue,htmlTagError,htmlEvent,htmlCssDefinition,@htmlPreproc,@htmlArgCluster
     37 syn match   htmlTagN	 contained +<\s*[-a-zA-Z0-9]\++hs=s+1 contains=htmlTagName,htmlSpecialTagName,@htmlTagNameCluster
     38 syn match   htmlTagN	 contained +</\s*[-a-zA-Z0-9]\++hs=s+2 contains=htmlTagName,htmlSpecialTagName,@htmlTagNameCluster
     39 syn match   htmlTagError contained "[^>]<"ms=s+1
     40 
     41 " tag names
     42 syn keyword htmlTagName contained address applet area a base basefont
     43 syn keyword htmlTagName contained big blockquote br caption center
     44 syn keyword htmlTagName contained cite code dd dfn dir div dl dt font
     45 syn keyword htmlTagName contained form hr html img
     46 syn keyword htmlTagName contained input isindex kbd li link map menu
     47 syn keyword htmlTagName contained meta ol option param pre p samp span
     48 syn keyword htmlTagName contained select small strike sub sup
     49 syn keyword htmlTagName contained table td textarea th tr tt ul var xmp
     50 syn keyword htmlTagName contained b i u em strong head body title h1 h2 h3 h4 h5 h6
     51 
     52 " new html 4.0 tags
     53 syn keyword htmlTagName contained abbr acronym bdo button col colgroup
     54 syn keyword htmlTagName contained del fieldset iframe ins label legend
     55 syn keyword htmlTagName contained object optgroup q s tbody tfoot thead
     56 
     57 " new html 5 tags
     58 syn keyword htmlTagName contained article aside audio bdi canvas data
     59 syn keyword htmlTagName contained datalist details dialog embed figcaption
     60 syn keyword htmlTagName contained figure footer header hgroup keygen main
     61 syn keyword htmlTagName contained mark menuitem meter nav output picture
     62 syn keyword htmlTagName contained progress rb rp rt rtc ruby search section
     63 syn keyword htmlTagName contained slot source summary template time track
     64 syn keyword htmlTagName contained video wbr
     65 
     66 " svg and math tags
     67 syn keyword htmlMathTagName contained math
     68 syn keyword htmlSvgTagName  contained svg
     69 
     70 syn region  htmlMath start="<math>" end="</math>" contains=@htmlXml transparent keepend
     71 syn region  htmlSvg  start="<svg>"  end="</svg>"  contains=@htmlXml transparent keepend
     72 
     73 syn cluster xmlTagHook	add=htmlMathTagName,htmlSvgTagName
     74 
     75 " legal arg names
     76 syn keyword htmlArg contained action
     77 syn keyword htmlArg contained align alink alt archive background bgcolor
     78 syn keyword htmlArg contained border bordercolor cellpadding
     79 syn keyword htmlArg contained cellspacing checked class clear code codebase color
     80 syn keyword htmlArg contained cols colspan content coords enctype face
     81 syn keyword htmlArg contained gutter height href hspace id
     82 syn keyword htmlArg contained link lowsrc marginheight
     83 syn keyword htmlArg contained marginwidth maxlength method name prompt
     84 syn keyword htmlArg contained rel rev role rows rowspan scrolling selected shape
     85 syn keyword htmlArg contained size src start target text title type url
     86 syn keyword htmlArg contained usemap ismap valign value vlink vspace width wrap
     87 syn match   htmlArg contained "\<http-equiv="me=e-1
     88 
     89 " ARIA attributes {{{1
     90 let s:aria =<< trim END
     91   activedescendant
     92   atomic
     93   autocomplete
     94   braillelabel
     95   brailleroledescription
     96   busy
     97   checked
     98   colcount
     99   colindex
    100   colindextext
    101   colspan
    102   controls
    103   current
    104   describedby
    105   description
    106   details
    107   disabled
    108   errormessage
    109   expanded
    110   flowto
    111   haspopup
    112   hidden
    113   invalid
    114   keyshortcuts
    115   label
    116   labelledby
    117   level
    118   live
    119   modal
    120   multiline
    121   multiselectable
    122   orientation
    123   owns
    124   placeholder
    125   posinset
    126   pressed
    127   readonly
    128   relevant
    129   required
    130   roledescription
    131   rowcount
    132   rowindex
    133   rowindextext
    134   rowspan
    135   selected
    136   setsize
    137   sort
    138   valuemax
    139   valuemin
    140   valuenow
    141   valuetext
    142 END
    143 let s:aria_deprecated =<< trim END
    144   dropeffect
    145   grabbed
    146 END
    147 
    148 call extend(s:aria, s:aria_deprecated)
    149 exe 'syn match htmlArg contained "\%#=1\<aria-\%(' .. s:aria->join('\|') .. '\)\>"'
    150 unlet s:aria s:aria_deprecated
    151 " }}}
    152 
    153 " Netscape extensions
    154 syn keyword htmlTagName contained frame noframes frameset nobr blink
    155 syn keyword htmlTagName contained layer ilayer nolayer spacer
    156 syn keyword htmlArg	contained frameborder noresize pagex pagey above below
    157 syn keyword htmlArg	contained left top visibility clip id noshade
    158 syn match   htmlArg	contained "\<z-index\>"
    159 
    160 " Microsoft extensions
    161 syn keyword htmlTagName contained marquee
    162 
    163 " html 4.0 arg names
    164 syn match   htmlArg contained "\<accept-charset\>"
    165 syn keyword htmlArg contained abbr accept accesskey axis char charoff charset
    166 syn keyword htmlArg contained cite classid codetype compact data datetime
    167 syn keyword htmlArg contained declare defer dir disabled for frame
    168 syn keyword htmlArg contained headers hreflang label lang language longdesc
    169 syn keyword htmlArg contained multiple nohref nowrap object profile readonly
    170 syn keyword htmlArg contained rules scheme scope span standby style
    171 syn keyword htmlArg contained summary tabindex valuetype version
    172 
    173 " html 5 arg names
    174 syn keyword htmlArg contained allow autocapitalize as blocking decoding
    175 syn keyword htmlArg contained enterkeyhint imagesizes imagesrcset inert
    176 syn keyword htmlArg contained integrity is itemid itemprop itemref itemscope
    177 syn keyword htmlArg contained itemtype loading nomodule ping playsinline
    178 syn keyword htmlArg contained referrerpolicy slot allowfullscreen async
    179 syn keyword htmlArg contained autocomplete autofocus autoplay challenge
    180 syn keyword htmlArg contained contenteditable contextmenu controls crossorigin
    181 syn keyword htmlArg contained default dirname download draggable dropzone form
    182 syn keyword htmlArg contained formaction formenctype formmethod formnovalidate
    183 syn keyword htmlArg contained formtarget hidden high icon inputmode keytype
    184 syn keyword htmlArg contained kind list loop low max min minlength muted nonce
    185 syn keyword htmlArg contained novalidate open optimum pattern placeholder
    186 syn keyword htmlArg contained poster preload radiogroup required reversed
    187 syn keyword htmlArg contained sandbox spellcheck sizes srcset srcdoc srclang
    188 syn keyword htmlArg contained step title translate typemustmatch
    189 syn match   htmlArg contained "\<data-\h\%(\w\|[-.]\)*\%(\_s*=\)\@="
    190 
    191 " special characters
    192 syn match htmlSpecialChar "&#\=[0-9A-Za-z]\{1,32};"
    193 
    194 " Comments (the real ones or the old netscape ones)
    195 if exists("html_wrong_comments")
    196   syn region htmlComment	start=+<!--+	end=+--\s*>+	contains=@Spell
    197 else
    198   " The HTML 5.2 syntax 8.2.4.41: bogus comment is parser error; browser skips until next &gt
    199   syn region htmlComment	start=+<!+	end=+>+		contains=htmlCommentError keepend
    200   " Idem 8.2.4.42,51: Comment starts with <!-- and ends with -->
    201   " Idem 8.2.4.43,44: Except <!--> and <!---> are parser errors
    202   " Idem 8.2.4.52: dash-dash-bang (--!>) is error ignored by parser, also closes comment
    203   syn region htmlComment matchgroup=htmlComment start=+<!--\%(-\?>\)\@!+	end=+--!\?>+	contains=htmlCommentNested,@htmlPreProc,@Spell keepend
    204   " Idem 8.2.4.49: nested comment is parser error, except <!--> is all right
    205   syn match htmlCommentNested contained "<!-->\@!"
    206   syn match htmlCommentError  contained "[^><!]"
    207 endif
    208 syn region htmlDoctype	start=+<!DOCTYPE+	end=+>+ keepend
    209 
    210 " server-parsed commands
    211 syn region htmlPreProc start=+<!--#+ end=+-->+ contains=htmlPreStmt,htmlPreError,htmlPreAttr
    212 syn match htmlPreStmt contained "<!--#\%(config\|echo\|exec\|fsize\|flastmod\|include\|printenv\|set\|if\|elif\|else\|endif\|geoguide\)\>"
    213 syn match htmlPreError contained "<!--#\S*"ms=s+4
    214 syn match htmlPreAttr contained "\w\+=[^"]\S\+" contains=htmlPreProcAttrError,htmlPreProcAttrName
    215 syn region htmlPreAttr contained start=+\w\+="+ skip=+\\\\\|\\"+ end=+"+ contains=htmlPreProcAttrName keepend
    216 syn match htmlPreProcAttrError contained "\w\+="he=e-1
    217 syn match htmlPreProcAttrName contained "\%(expr\|errmsg\|sizefmt\|timefmt\|var\|cgi\|cmd\|file\|virtual\|value\)="he=e-1
    218 
    219 if !exists("html_no_rendering")
    220   " rendering
    221   syn cluster htmlTop contains=@Spell,htmlTag,htmlEndTag,htmlSpecialChar,htmlPreProc,htmlComment,htmlLink,javaScript,htmlVbScript,@htmlPreproc
    222 
    223   syn region htmlStrike start="<del\>" end="</del\_s*>"me=s-1 contains=@htmlTop
    224   syn region htmlStrike start="<s\>" end="</s\_s*>"me=s-1 contains=@htmlTop
    225   syn region htmlStrike start="<strike\>" end="</strike\_s*>"me=s-1 contains=@htmlTop
    226 
    227   syn region htmlBold start="<b\>" end="</b\_s*>"me=s-1 contains=@htmlTop,htmlBoldUnderline,htmlBoldItalic
    228   syn region htmlBold start="<strong\>" end="</strong\_s*>"me=s-1 contains=@htmlTop,htmlBoldUnderline,htmlBoldItalic
    229   syn region htmlBoldUnderline contained start="<u\>" end="</u\_s*>"me=s-1 contains=@htmlTop,htmlBoldUnderlineItalic
    230   syn region htmlBoldItalic contained start="<i\>" end="</i\_s*>"me=s-1 contains=@htmlTop,htmlBoldItalicUnderline
    231   syn region htmlBoldItalic contained start="<em\>" end="</em\_s*>"me=s-1 contains=@htmlTop,htmlBoldItalicUnderline
    232   syn region htmlBoldUnderlineItalic contained start="<i\>" end="</i\_s*>"me=s-1 contains=@htmlTop
    233   syn region htmlBoldUnderlineItalic contained start="<em\>" end="</em\_s*>"me=s-1 contains=@htmlTop
    234   syn region htmlBoldItalicUnderline contained start="<u\>" end="</u\_s*>"me=s-1 contains=@htmlTop,htmlBoldUnderlineItalic
    235 
    236   syn region htmlUnderline start="<u\>" end="</u\_s*>"me=s-1 contains=@htmlTop,htmlUnderlineBold,htmlUnderlineItalic
    237   syn region htmlUnderlineBold contained start="<b\>" end="</b\_s*>"me=s-1 contains=@htmlTop,htmlUnderlineBoldItalic
    238   syn region htmlUnderlineBold contained start="<strong\>" end="</strong\_s*>"me=s-1 contains=@htmlTop,htmlUnderlineBoldItalic
    239   syn region htmlUnderlineItalic contained start="<i\>" end="</i\_s*>"me=s-1 contains=@htmlTop,htmlUnderlineItalicBold
    240   syn region htmlUnderlineItalic contained start="<em\>" end="</em\_s*>"me=s-1 contains=@htmlTop,htmlUnderlineItalicBold
    241   syn region htmlUnderlineItalicBold contained start="<b\>" end="</b\_s*>"me=s-1 contains=@htmlTop
    242   syn region htmlUnderlineItalicBold contained start="<strong\>" end="</strong\_s*>"me=s-1 contains=@htmlTop
    243   syn region htmlUnderlineBoldItalic contained start="<i\>" end="</i\_s*>"me=s-1 contains=@htmlTop
    244   syn region htmlUnderlineBoldItalic contained start="<em\>" end="</em\_s*>"me=s-1 contains=@htmlTop
    245 
    246   syn region htmlItalic start="<i\>" end="</i\_s*>"me=s-1 contains=@htmlTop,htmlItalicBold,htmlItalicUnderline
    247   syn region htmlItalic start="<em\>" end="</em\_s*>"me=s-1 contains=@htmlTop
    248   syn region htmlItalicBold contained start="<b\>" end="</b\_s*>"me=s-1 contains=@htmlTop,htmlItalicBoldUnderline
    249   syn region htmlItalicBold contained start="<strong\>" end="</strong\_s*>"me=s-1 contains=@htmlTop,htmlItalicBoldUnderline
    250   syn region htmlItalicBoldUnderline contained start="<u\>" end="</u\_s*>"me=s-1 contains=@htmlTop
    251   syn region htmlItalicUnderline contained start="<u\>" end="</u\_s*>"me=s-1 contains=@htmlTop,htmlItalicUnderlineBold
    252   syn region htmlItalicUnderlineBold contained start="<b\>" end="</b\_s*>"me=s-1 contains=@htmlTop
    253   syn region htmlItalicUnderlineBold contained start="<strong\>" end="</strong\_s*>"me=s-1 contains=@htmlTop
    254 
    255   syn match htmlLeadingSpace "^\s\+" contained
    256   syn region htmlLink start="<a\>\_[^>]*\<href\>" end="</a\_s*>"me=s-1 contains=@Spell,htmlTag,htmlEndTag,htmlSpecialChar,htmlPreProc,htmlComment,htmlLeadingSpace,javaScript,htmlVbScript,@htmlPreproc
    257   syn region htmlH1 start="<h1\>" end="</h1\_s*>"me=s-1 contains=@htmlTop
    258   syn region htmlH2 start="<h2\>" end="</h2\_s*>"me=s-1 contains=@htmlTop
    259   syn region htmlH3 start="<h3\>" end="</h3\_s*>"me=s-1 contains=@htmlTop
    260   syn region htmlH4 start="<h4\>" end="</h4\_s*>"me=s-1 contains=@htmlTop
    261   syn region htmlH5 start="<h5\>" end="</h5\_s*>"me=s-1 contains=@htmlTop
    262   syn region htmlH6 start="<h6\>" end="</h6\_s*>"me=s-1 contains=@htmlTop
    263   syn region htmlHead start="<head\>" end="</head\_s*>"me=s-1 end="<body\>"me=s-1 end="<h[1-6]\>"me=s-1 contains=htmlTag,htmlEndTag,htmlSpecialChar,htmlPreProc,htmlComment,htmlLink,htmlTitle,javaScript,htmlVbScript,cssStyle,@htmlPreproc
    264   syn region htmlTitle start="<title\>" end="</title\_s*>"me=s-1 contains=htmlTag,htmlEndTag,htmlSpecialChar,htmlPreProc,htmlComment,javaScript,htmlVbScript,@htmlPreproc
    265 endif
    266 
    267 syn keyword htmlTagName		contained noscript
    268 syn keyword htmlSpecialTagName	contained script style
    269 if main_syntax != 'java' || exists("java_javascript")
    270   " JAVA SCRIPT
    271   syn include @htmlJavaScript syntax/javascript.vim
    272   unlet b:current_syntax
    273   syn region  javaScript start=+<script\>\_[^>]*>+ keepend end=+</script\_[^>]*>+me=s-1 contains=@htmlJavaScript,htmlCssStyleComment,htmlScriptTag,@htmlPreproc
    274   syn region  htmlScriptTag	contained start=+<script+ end=+>+ fold contains=htmlTagN,htmlString,htmlArg,htmlValue,htmlTagError,htmlEvent
    275   hi def link htmlScriptTag htmlTag
    276 
    277   " html events (i.e. arguments that include javascript commands)
    278   if exists("html_extended_events")
    279     syn region htmlEvent	contained start=+\<on\a\+\s*=[\t ]*'+ end=+'+ contains=htmlEventSQ
    280     syn region htmlEvent	contained start=+\<on\a\+\s*=[\t ]*"+ end=+"+ contains=htmlEventDQ
    281   else
    282     syn region htmlEvent	contained start=+\<on\a\+\s*=[\t ]*'+ end=+'+ keepend contains=htmlEventSQ
    283     syn region htmlEvent	contained start=+\<on\a\+\s*=[\t ]*"+ end=+"+ keepend contains=htmlEventDQ
    284   endif
    285   syn region htmlEventSQ	contained start=+'+ms=s+1 end=+'+me=s-1 contains=@htmlJavaScript
    286   syn region htmlEventDQ	contained start=+"+ms=s+1 end=+"+me=s-1 contains=@htmlJavaScript
    287   hi def link htmlEventSQ htmlEvent
    288   hi def link htmlEventDQ htmlEvent
    289 
    290   " a javascript expression is used as an arg value
    291   syn region  javaScriptExpression contained start=+&{+ keepend end=+};+ contains=@htmlJavaScript,@htmlPreproc
    292 endif
    293 
    294 if main_syntax != 'java' || exists("java_vb")
    295   " VB SCRIPT
    296   syn include @htmlVbScript syntax/vb.vim
    297   unlet b:current_syntax
    298   syn region  htmlVbScript start=+<script \_[^>]*language *=\_[^>]*vbscript\_[^>]*>+ keepend end=+</script\_[^>]*>+me=s-1 contains=@htmlVbScript,htmlCssStyleComment,htmlScriptTag,@htmlPreproc
    299 endif
    300 
    301 syn cluster htmlJavaScript	add=@htmlPreproc
    302 
    303 if main_syntax != 'java' || exists("java_css")
    304   " embedded style sheets
    305   syn keyword htmlArg		contained media
    306   syn include @htmlCss syntax/css.vim
    307   unlet b:current_syntax
    308   syn region cssStyle start=+<style+ keepend end=+</style>+ contains=@htmlCss,htmlTag,htmlEndTag,htmlCssStyleComment,@htmlPreproc
    309   syn match htmlCssStyleComment contained "\%(<!--\|-->\)"
    310   syn region htmlCssDefinition matchgroup=htmlArg start='style="' keepend matchgroup=htmlString end='"' contains=css.*Attr,css.*Prop,cssComment,cssLength,cssColor,cssURL,cssImportant,cssError,cssString,@htmlPreproc
    311   hi def link htmlStyleArg htmlString
    312 endif
    313 
    314 if main_syntax == "html"
    315   syn sync clear
    316   syn sync match htmlHighlightSkip "^.*['\"].*$"
    317   syn sync match htmlHighlight grouphere  htmlComment  "<!--"
    318   syn sync match htmlHighlight groupthere NONE         "--!\=\s*>"
    319   syn sync match htmlHighlight groupthere NONE         "</script\>"
    320   syn sync match htmlHighlight groupthere javaScript   "<script\>"
    321   syn sync match htmlHighlight groupthere htmlVbScript "<script \_[^>]*language *=\_[^>]*vbscript"
    322   syn sync match htmlHighlight groupthere NONE         "</style\>"
    323   syn sync match htmlHighlight groupthere cssStyle     "<style\>"
    324   exe "syn sync minlines=" .. get(g:, 'html_minlines', 250)
    325   exe "syn sync maxlines=" .. get(g:, 'html_maxlines', 500)
    326 endif
    327 
    328 " Folding
    329 " (Originally written by Ingo Karkat and Marcus Zanona; see
    330 " https://vi.stackexchange.com/questions/2306/html-syntax-folding-in-vim .)
    331 if get(g:, "html_syntax_folding", 0)
    332   syn region htmlFold start="<\z(\<\%(area\|base\|br\|col\|command\|embed\|hr\|img\|input\|keygen\|link\|meta\|param\|source\|track\|wbr\>\)\@![a-z-]\+\>\)\%(\_s*\_[^/]\?>\|\_s\_[^>]*\_[^>/]>\)" end="</\z1\_s*>" fold transparent keepend extend containedin=htmlHead,htmlH\d
    333   " fold comments (the real ones and the old Netscape ones)
    334   if exists("html_wrong_comments")
    335     syn region htmlComment start=+<!--+ end=+--\s*>\%(\n\s*<!--\)\@!+ contains=@Spell fold
    336   endif
    337 endif
    338 
    339 " The default highlighting.
    340 hi def link htmlTag			Function
    341 hi def link htmlEndTag			Identifier
    342 hi def link htmlArg			Type
    343 hi def link htmlTagName			htmlStatement
    344 hi def link htmlSpecialTagName		Exception
    345 hi def link htmlMathTagName		htmlTagName
    346 hi def link htmlSvgTagName		htmlTagName
    347 hi def link htmlValue			String
    348 hi def link htmlSpecialChar		Special
    349 
    350 if !exists("html_no_rendering")
    351   hi def link htmlH1			  Title
    352   hi def link htmlH2			  htmlH1
    353   hi def link htmlH3			  htmlH2
    354   hi def link htmlH4			  htmlH3
    355   hi def link htmlH5			  htmlH4
    356   hi def link htmlH6			  htmlH5
    357   hi def link htmlHead			  PreProc
    358   hi def link htmlTitle			  Title
    359   hi def link htmlBoldItalicUnderline	  htmlBoldUnderlineItalic
    360   hi def link htmlUnderlineBold		  htmlBoldUnderline
    361   hi def link htmlUnderlineItalicBold	  htmlBoldUnderlineItalic
    362   hi def link htmlUnderlineBoldItalic	  htmlBoldUnderlineItalic
    363   hi def link htmlItalicUnderline	  htmlUnderlineItalic
    364   hi def link htmlItalicBold		  htmlBoldItalic
    365   hi def link htmlItalicBoldUnderline	  htmlBoldUnderlineItalic
    366   hi def link htmlItalicUnderlineBold	  htmlBoldUnderlineItalic
    367   hi def link htmlLink			  Underlined
    368   hi def link htmlLeadingSpace		  None
    369   if !exists("html_my_rendering")
    370     hi def htmlBold		   term=bold cterm=bold gui=bold
    371     hi def htmlBoldUnderline	   term=bold,underline cterm=bold,underline gui=bold,underline
    372     hi def htmlBoldItalic	   term=bold,italic cterm=bold,italic gui=bold,italic
    373     hi def htmlBoldUnderlineItalic term=bold,italic,underline cterm=bold,italic,underline gui=bold,italic,underline
    374     hi def htmlUnderline	   term=underline cterm=underline gui=underline
    375     hi def htmlUnderlineItalic	   term=italic,underline cterm=italic,underline gui=italic,underline
    376     hi def htmlItalic		   term=italic cterm=italic gui=italic
    377     if v:version > 800 || v:version == 800 && has("patch1038")
    378       hi def htmlStrike	term=strikethrough cterm=strikethrough gui=strikethrough
    379     else
    380       hi def htmlStrike	term=underline cterm=underline gui=underline
    381     endif
    382   endif
    383 endif
    384 
    385 hi def link htmlPreStmt		   PreProc
    386 hi def link htmlPreError	   Error
    387 hi def link htmlPreProc		   PreProc
    388 hi def link htmlPreAttr		   String
    389 hi def link htmlPreProcAttrName    PreProc
    390 hi def link htmlPreProcAttrError   Error
    391 hi def link htmlString		   String
    392 hi def link htmlStatement	   Statement
    393 hi def link htmlComment		   Comment
    394 hi def link htmlDoctype		   htmlComment
    395 hi def link htmlCommentNested	   htmlError
    396 hi def link htmlCommentError	   htmlError
    397 hi def link htmlTagError	   htmlError
    398 hi def link htmlEvent		   javaScript
    399 hi def link htmlError		   Error
    400 
    401 hi def link javaScript		   Special
    402 hi def link javaScriptExpression   javaScript
    403 hi def link htmlCssStyleComment    Comment
    404 hi def link htmlCssDefinition	   Special
    405 
    406 let b:current_syntax = "html"
    407 
    408 if main_syntax == 'html'
    409   unlet main_syntax
    410 endif
    411 
    412 let &cpo = s:cpo_save
    413 unlet s:cpo_save
    414 
    415 " vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: