vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

gen_syntax_vim.vim (27746B)


      1 " Vim syntax file generator
      2 " Language:		 Vim script
      3 " Maintainer:	 Hirohito Higashi (h_east)
      4 " Last Change: 2026 Aug 02
      5 
      6 let s:keepcpo= &cpo
      7 set cpo&vim
      8 
      9 language C
     10 let s:log_write_dir = getcwd() . '/'
     11 
     12 function s:parse_vim_option(opt, missing_opt, term_out_code)
     13 	try
     14 		let file_name = $VIM_SRCDIR . '/optiondefs.h'
     15 		let item = {}
     16 
     17 		new
     18 		exec 'read ' . file_name
     19 		norm! gg
     20 		exec '/^.*\s*options\[\]\s*=\s*$/+1;/^\s*#\s*define\s*p_term(/-1yank a'
     21 		exec '/^#define\s\+p_term(/+1;/^};$/-1yank b'
     22 		%delete _
     23 
     24 		put a
     25 		" workaround for 'shortname'
     26 		g/^#\s*ifdef\s*SHORT_FNAME\>/j
     27 		g/^#/d
     28 		g/^\s*{\s*"\w\+"\%(\s*,\s*[^,]*\)\{2}[^,]$/j
     29 		g/^\s*{\s*"\w\+"\s*,.*$/j
     30 		g!/^\s*{\s*"\w\+"\s*,.*$/d
     31 
     32 		for line in getline(1, line('$'))
     33 			let list = matchlist(line, '^\s*{\s*"\(\w\+\)"\s*,\s*\%("\(\w\+\)"\|NULL\)\s*,\s*\%([^,]*\(P_BOOL\)[^,]*\|[^,]*\)\s*,\s*\([^,]*NULL\)\?.*')
     34 			if list[1] == 'completefuzzycollect'
     35 				continue
     36 			endif
     37 			let item.name = list[1]
     38 			let item.short_name = list[2]
     39 			let item.is_bool = empty(list[3]) ? 0 : 1
     40 			if empty(list[4])
     41 				call add(a:opt, copy(item))
     42 			else
     43 				call add(a:missing_opt, copy(item))
     44 			endif
     45 		endfor
     46 		if empty(a:opt)
     47 			throw 'opt is empty'
     48 		endif
     49 		if empty(a:missing_opt)
     50 			throw 'missing_opt is empty'
     51 		endif
     52 
     53 		%delete _
     54 		put b
     55 		g!/^\s*p_term(\s*"\w\+"\s*,.*$/d
     56 
     57 		for line in getline(1, line('$'))
     58 			let list = matchlist(line, '^\s*p_term(\s*"\(\w\+\)"\s*,')
     59 			let item.name = list[1]
     60 			call add(a:term_out_code, copy(item))
     61 		endfor
     62 		quit!
     63 		if empty(a:term_out_code)
     64 			throw 'term_out_code is empty'
     65 		endif
     66 	catch /.*/
     67 		call s:err_gen('')
     68 		throw 'exit'
     69 	endtry
     70 endfunc
     71 
     72 function s:append_syn_vimopt(lnum, str_info, opt_list, prefix, bool_only)
     73 	let ret_lnum = a:lnum
     74 	let str = a:str_info.start
     75 
     76 	for o in a:opt_list
     77 		if !a:bool_only || o.is_bool
     78 			if !empty(o.short_name)
     79 				let str .= ' ' . a:prefix . o.short_name
     80 			endif
     81 			let str .= ' ' . a:prefix . o.name
     82 			if len(str) > s:line_break_len
     83 				if !empty(a:str_info.end)
     84 					let str .= ' ' . a:str_info.end
     85 				endif
     86 				call append(ret_lnum, str)
     87 				let str = a:str_info.start
     88 				let ret_lnum += 1
     89 			endif
     90 		endif
     91 	endfor
     92 	if str !=# a:str_info.start
     93 		if !empty(a:str_info.end)
     94 			let str .= ' ' . a:str_info.end
     95 		endif
     96 		call append(ret_lnum, str)
     97 		let ret_lnum += 1
     98 	endif
     99 	return ret_lnum
    100 endfunc
    101 
    102 " ------------------------------------------------------------------------------
    103 function s:parse_vim_command(cmd)
    104 	try
    105 		let file_name = $VIM_SRCDIR . '/ex_cmds.h'
    106 		let item = {}
    107 
    108 		new
    109 		exec 'read ' . file_name
    110 		norm! gg
    111 		exec '/^}\?\s*cmdnames\[\]\s*=\s*$/+1;/^};/-1yank'
    112 		%delete _
    113 		put
    114 		/EXCMD(CMD_block,/s/\s\+\/\/.*//
    115 		g/EXCMD(CMD_/,/),/j
    116 		g!/^EXCMD(/d
    117 
    118 
    119 		let lcmd = {}
    120 		for key in range(char2nr('a'), char2nr('z'))
    121 			let lcmd[nr2char(key)] = []
    122 		endfor
    123 		let lcmd['~'] = []
    124 
    125 		for line in getline(1, line('$'))
    126 			let list = matchlist(line, '^EXCMD(\w\+\s*,\s*"\(\a\w*\)"\s*,')
    127 			if !empty(list)
    128 				" Small ascii character or other.
    129 				let key = (list[1][:0] =~# '\l') ? list[1][:0] : '~'
    130 				let item.name = list[1]
    131 				let item.flags = {}
    132 				let item.flags.range = match(line, 'EX_RANGE') >= 0
    133 				call add(lcmd[key], copy(item))
    134 			endif
    135 		endfor
    136 		quit!
    137 
    138 		for key in sort(keys(lcmd))
    139 			for my in range(len(lcmd[key]))
    140 				let omit_idx = 0
    141 				if my > 0
    142 					let omit_idx = (key =~# '\l') ? 1 : 0
    143 					for idx in range(1, strlen(lcmd[key][my].name))
    144 						let matched = 0
    145 						for pre in range(my - 1, 0, -1)
    146 							" Avoiding conflicts shortened command and special commands
    147 							" - weird abbreviations for delete. (See :help :d)
    148 							" - k{char} is used as mark. (See :help :k)
    149 							" - :s commsnds repeat. (See :help :substitute-repeat)
    150 							if lcmd[key][my].name[:idx] ==# lcmd[key][pre].name[:idx] ||
    151 							\	(key ==# 'd' &&
    152 							\		lcmd[key][my].name[:idx] =~# '^d\%[elete][lp]$')
    153 							\	|| (key ==# 'k' &&
    154 							\		lcmd[key][my].name[:idx] =~# '^k[a-zA-Z]$')
    155 							\	|| (key ==# 's' &&
    156 							\		lcmd[key][my].name[:idx] =~# '^s\%(c\%([^sr][^ip]\=\)\=$\|g\|i[^mlg]\=$\|I\|r[^e]\=$\)')
    157 								let matched = 1
    158 								let omit_idx = idx + 1
    159 								break
    160 							endif
    161 						endfor
    162 						if !matched
    163 							break
    164 						endif
    165 					endfor
    166 				endif
    167 
    168 				let item = lcmd[key][my]
    169 				let item.type = s:get_vim_command_type(item.name)
    170 				if omit_idx + 1 < strlen(item.name)
    171 					let item.omit_idx = omit_idx
    172 					let item.syn_str = item.name[:omit_idx] . '[' . 
    173 					\		item.name[omit_idx + 1:] . ']'
    174 					let item.syn_pat = item.name[:omit_idx] . '\%[' .
    175 					\		item.name[omit_idx + 1:] . ']'
    176 				else
    177 					let item.omit_idx = -1
    178 					let item.syn_str = item.name
    179 					let item.syn_pat = item.name
    180 				endif
    181 				call add(a:cmd, copy(item))
    182 			endfor
    183 		endfor
    184 
    185 		let no_shorten_in_vim9 =<< trim EOL
    186 			final
    187 			def
    188 			enddef
    189 			class
    190 			endclass
    191 			enum
    192 			endenum
    193 			interface
    194 			endinterface
    195 			abstract
    196 			public
    197 			static
    198 			this
    199 			var
    200 			type
    201 		EOL
    202 
    203 		call map(a:cmd, {_, v ->
    204 			\ index(no_shorten_in_vim9, v.name) != -1 ?
    205 			\		extend(copy(v), {'omit_idx': -1, 'syn_str': v.name}) :
    206 			"\ ":fina" means ":finally" in legacy script, for backwards compatibility.
    207 			"\ (From Vim source code find_ex_command() in ex_docmd.c)
    208 			\ v.name ==# 'finally' ?
    209 			\		extend(copy(v), {'omit_idx': 3, 'syn_str': 'fina[lly]'}) :
    210 			"\ :ho must not be recognized as :horizontal.
    211 			\ v.name ==# 'horizontal' ?
    212 			\		extend(copy(v), {'omit_idx': 2, 'syn_str': 'hor[izontal]'}) :
    213 			\ v
    214 			\ })
    215 
    216 		if empty(a:cmd)
    217 			throw 'cmd is empty'
    218 		endif
    219 	catch /.*/
    220 		call s:err_gen('')
    221 		throw 'exit'
    222 	endtry
    223 endfunc
    224 
    225 function s:memoize_cmd_modifiers()
    226 	let modifiers = []
    227 	function _() closure
    228 		if empty(modifiers)
    229 			try
    230 				let file_name = $VIM_SRCDIR .. '/ex_docmd.c'
    231 
    232 				new
    233 				exec 'read ' .. file_name
    234 				norm! gg
    235 				exec ':/^static cmdmod_info_T cmdmod_info_tab\[] = {/+1;/^};/-1yank'
    236 				%delete _
    237 
    238 				put
    239 				1delete _
    240 
    241 				let list = []
    242 				for line in getline(1, line('$'))
    243 					let list = matchlist(line, '^\s*{"\(\w\+\)".*')
    244 					" :browse and :confirm handled separately as lower priority matches
    245 					" because they have same-named builtin functions
    246 					if index(['browse', 'confirm'], list[1]) == -1
    247 						call add(modifiers, copy(list[1]))
    248 					endif
    249 				endfor
    250 
    251 				quit!
    252 
    253 				if empty(modifiers)
    254 					throw 'cmd modifiers list is empty'
    255 				endif
    256 
    257 			catch /.*/
    258 				call s:err_gen('')
    259 				throw 'exit'
    260 			endtry
    261 		endif
    262 		return modifiers
    263 	endfunction
    264 	return function("_")
    265 endfunction
    266 let s:get_cmd_modifiers = s:memoize_cmd_modifiers()
    267 
    268 function s:get_vim_command_type(cmd_name)
    269 	" Return value:
    270 	"   0: normal
    271 	"   1: (Reserved)
    272 	"   2: abbrev
    273 	"   3: menu
    274 	"   4: map
    275 	"   5: mapclear
    276 	"   6: unmap
    277 	"   7: abclear
    278 	"   8: modifiers
    279 	"   9: cd
    280 	"   99: (Exclude registration of "syn keyword")
    281 	let ab_prefix   = '^[ci]\?'
    282 	let menu_prefix = '^\%([acinostvx]\?\|tl\)'
    283 	let map_prefix  = '^[acilnostvx]\?'
    284 	let exclude_list =<< trim EOL
    285 		2match
    286 		3match
    287 		Next
    288 		Print
    289 		X
    290 		abstract
    291 		argdo
    292 		append
    293 		augroup
    294 		autocmd
    295 		behave
    296 		breakadd
    297 		breakdel
    298 		breaklist
    299 		browse
    300 		bufdo
    301 		buffer
    302 		call
    303 		catch
    304 		cdo
    305 		cfdo
    306 		change
    307 		chdir
    308 		class
    309 		command
    310 		confirm
    311 		const
    312 		copy
    313 		debug
    314 		debuggreedy
    315 		def
    316 		defer
    317 		delcommand
    318 		delete
    319 		delfunction
    320 		doautoall
    321 		doautocmd
    322 		echo
    323 		echoconsole
    324 		echoerr
    325 		echohl
    326 		echomsg
    327 		echon
    328 		echowindow
    329 		else
    330 		elseif
    331 		endclass
    332 		enddef
    333 		endenum
    334 		endfunction
    335 		endif
    336 		endinterface
    337 		enum
    338 		eval
    339 		execute
    340 		export
    341 		filetype
    342 		filter
    343 		final
    344 		folddoclosed
    345 		folddoopen
    346 		for
    347 		function
    348 		global
    349 		grep
    350 		grepadd
    351 		help
    352 		helpgrep
    353 		highlight
    354 		history
    355 		if
    356 		import
    357 		insert
    358 		interface
    359 		join
    360 		k
    361 		language
    362 		let
    363 		ldo
    364 		lfdo
    365 		lgrep
    366 		lgrepadd
    367 		lhelpgrep
    368 		lmake
    369 		loadkeymap
    370 		lockvar
    371 		lua
    372 		luado
    373 		luafile
    374 		lvimgrep
    375 		lvimgrepadd
    376 		make
    377 		map
    378 		mapclear
    379 		mark
    380 		match
    381 		menutranslate
    382 		mzfile
    383 		mzscheme
    384 		noremap
    385 		normal
    386 		number
    387 		packadd
    388 		perl
    389 		perldo
    390 		popup
    391 		profdel
    392 		profile
    393 		promptfind
    394 		promptrepl
    395 		public
    396 		py3
    397 		py3do
    398 		py3file
    399 		pydo
    400 		pyfile
    401 		python
    402 		python3
    403 		pythonx
    404 		pyx
    405 		pyxdo
    406 		pyxfile
    407 		redir
    408 		return
    409 		ruby
    410 		rubydo
    411 		rubyfile
    412 		runtime
    413 		set
    414 		setglobal
    415 		setlocal
    416 		sleep
    417 		smagic
    418 		snomagic
    419 		sort
    420 		split
    421 		static
    422 		substitute
    423 		swapname
    424 		syntax
    425 		syntime
    426 		t
    427 		tabdo
    428 		tcl
    429 		tcldo
    430 		tclfile
    431 		terminal
    432 		this
    433 		throw
    434 		type
    435 		uniq
    436 		unlet
    437 		unlockvar
    438 		unmap
    439 		var
    440 		vglobal
    441 		vim9script
    442 		vimgrep
    443 		vimgrepadd
    444 		while
    445 		wincmd
    446 		windo
    447 		write
    448 		z
    449 	EOL
    450 
    451 	if index(exclude_list, a:cmd_name) != -1
    452 		let ret = 99
    453 	elseif a:cmd_name =~# '^\%(\%(un\)\?abbreviate\|noreabbrev\|\l\%(nore\|un\)\?abbrev\)$'
    454 		let ret = 2
    455 	elseif a:cmd_name =~# ab_prefix . 'abclear$'
    456 		let ret = 7
    457 	elseif a:cmd_name =~# menu_prefix . '\%(nore\|un\)\?menu$'
    458 		let ret = 3
    459 	elseif a:cmd_name =~# map_prefix . '\%(nore\)\?map$'
    460 		let ret = 4
    461 	elseif a:cmd_name =~# map_prefix . 'mapclear$'
    462 		let ret = 5
    463 	elseif a:cmd_name =~# map_prefix . 'unmap$'
    464 		let ret = 6
    465 	elseif index(s:get_cmd_modifiers(), a:cmd_name) != -1
    466 		let ret = 8
    467 	" :chdir handled specially for command/function distinction
    468 	elseif a:cmd_name =~# '^\%([lt]\?cd\|[lt]chdir\)$'
    469 		let ret = 9
    470 	else
    471 		let ret = 0
    472 	endif
    473 	return ret
    474 endfunc
    475 
    476 function s:append_syn_vimcmd(lnum, str_info, cmd_list, type)
    477 	let ret_lnum = a:lnum
    478 	let str = a:str_info.start
    479 
    480 	for o in a:cmd_list
    481 		if o.type == a:type
    482 			let str .= ' ' . o.syn_str
    483 			if len(str) > s:line_break_len
    484 				if !empty(a:str_info.end)
    485 					let str .= ' ' . a:str_info.end
    486 				endif
    487 				call append(ret_lnum, str)
    488 				let str = a:str_info.start
    489 				let ret_lnum += 1
    490 			endif
    491 		endif
    492 	endfor
    493 	if str !=# a:str_info.start
    494 		if !empty(a:str_info.end)
    495 			let str .= ' ' . a:str_info.end
    496 		endif
    497 		call append(ret_lnum, str)
    498 		let ret_lnum += 1
    499 	endif
    500 	return s:append_syn_vimcmd_after_range(ret_lnum, a:str_info, a:cmd_list, a:type)
    501 endfunc
    502 
    503 " append post-range :syn-match variants
    504 function s:append_syn_vimcmd_after_range(lnum, str_info, cmd_list, type)
    505 	let cmd_list = filter(
    506 				\ copy(a:cmd_list),
    507 				\ { _, v -> v.flags.range && v.type == a:type })
    508 	let str_start = substitute(
    509 				\ a:str_info.start,
    510 				\ 'syn keyword vim\(\w\+\)\(.*\)',
    511 				\ 'syn match vim\1_\2',
    512 				\ '')
    513 	let str_end = a:str_info.end
    514 	let ret_lnum = a:lnum
    515 
    516 	let by_head = {}
    517 	for cmd in cmd_list
    518 		let head = cmd.name[0]
    519 		if !has_key(by_head, head)
    520 			let by_head[head] = []
    521 		endif
    522 		call add(by_head[head], cmd)
    523 	endfor
    524 
    525 	for head in sort(keys(by_head))
    526 		let str = str_start . ' "' . head
    527 		let tails = by_head[head]->map({ _, v -> v.syn_pat[1:] })
    528 		if len(tails) == 1
    529 			let str .= tails[0]
    530 		elseif len(tails) > 1
    531 			let str .= '\%(' . tails->join('\|') . '\)'
    532 		endif
    533 		let str .= '\>"'
    534 		if !empty(str_end)
    535 			let str .= ' ' . str_end
    536 		endif
    537 		call append(ret_lnum, str)
    538 		let ret_lnum += 1
    539 	endfor
    540 	return ret_lnum
    541 endfunc
    542 
    543 " ------------------------------------------------------------------------------
    544 function s:parse_vim_event(li)
    545 	try
    546 		let file_name = $VIM_SRCDIR . '/autocmd.c'
    547 		let item = {}
    548 
    549 		new
    550 		exec 'read ' . file_name
    551 		norm! gg
    552 		exec '/^static keyvalue_T event_tab\[NUM_EVENTS] = {$/+1;/^};$/-1yank'
    553 		%delete _
    554 
    555 		put
    556 		g!/^\s*KEYVALUE_ENTRY(/d
    557 
    558 		for line in getline(1, line('$'))
    559 			let list = matchlist(line, '^\s*KEYVALUE_ENTRY(-\?EVENT_\w\+,\s*"\(\w\+\)"')
    560 			let item.name = list[1]
    561 			call add(a:li, copy(item))
    562 		endfor
    563 
    564 		" "User" requires a user defined argument event.
    565 		" (Separately specified in vim.vim.base).
    566 		call filter(a:li, {idx, val -> val.name !=# 'User'})
    567 
    568 		quit!
    569 
    570 		if empty(a:li)
    571 			throw 'event is empty'
    572 		endif
    573 	catch /.*/
    574 		call s:err_gen('')
    575 		throw 'exit'
    576 	endtry
    577 endfunc
    578 
    579 " ------------------------------------------------------------------------------
    580 function s:parse_vim_function(li)
    581 	try
    582 		let file_name = $VIM_SRCDIR . '/evalfunc.c'
    583 		let item = {}
    584 
    585 		new
    586 		exec 'read ' . file_name
    587 		norm! gg
    588 		exec '/^static\s\+const\s\+funcentry_T\s\+global_functions\[\]\s*=\s*$/+1;/^};/-1yank'
    589 		%delete _
    590 
    591 		put
    592 		g!/^\s*{\s*"\w\+"\s*,.*$/d
    593 		g/^\s*{\s*"test"\s*,.*$/d
    594 		g@//\s*obsolete@d
    595 		g@/\*\s*obsolete\s*\*/@d
    596 
    597 		for line in getline(1, line('$'))
    598 			let list = matchlist(line, '^\s*{\s*"\(\w\+\)"\s*,')
    599 			let item.name = list[1]
    600 			call add(a:li, copy(item))
    601 		endfor
    602 
    603 		quit!
    604 
    605 		if empty(a:li)
    606 			throw 'function is empty'
    607 		endif
    608 	catch /.*/
    609 		call s:err_gen('')
    610 		throw 'exit'
    611 	endtry
    612 endfunc
    613 
    614 " ------------------------------------------------------------------------------
    615 function s:parse_vim_group(li)
    616 	try
    617 		let file_name = $VIM_SRCDIR . '/../runtime/syntax/syncolor.vim'
    618 		let item = {}
    619 
    620 		new
    621 		exec 'read ' . file_name
    622 		g!/^\s*Syn\%(Color\|Link\)/d
    623 		%s/^\s*Syn\%(Color\|Link\)\s\+\(\w\+\).*/\1/
    624 
    625 		for group in getline(1, line('$'))->sort()->uniq()
    626 			let item.name = group
    627 			call add(a:li, copy(item))
    628 		endfor
    629 
    630 		quit!
    631 
    632 		if empty(a:li)
    633 			throw 'group is empty'
    634 		endif
    635 	catch /.*/
    636 		call s:err_gen('')
    637 		throw 'exit'
    638 	endtry
    639 endfunc
    640 
    641 " ------------------------------------------------------------------------------
    642 function s:parse_vim_hlgroup(li)
    643 	try
    644 		let file_name = $VIM_SRCDIR . '/highlight.c'
    645 		let item = {}
    646 
    647 		new
    648 		exec 'read ' . file_name
    649 		call cursor(1, 1)
    650 		exec '/^static\s\+char\s\+\*(highlight_init_both\[\])\s*=\%(\s*{\)\?$/+1;/^\s*};/-1yank a'
    651 		exec '/^static\s\+char\s\+\*(highlight_init_light\[\])\s*=\%(\s*{\)\?$/+1;/^\s*};/-1yank b'
    652 		exec '/^set_normal_colors(\%(void\)\?)$/+1;/^}$/-1yank d'
    653 		%delete _
    654 		put a
    655 		for line in getline(1, line('$'))
    656 			let list = matchlist(line, '^\s*\%(CENT(\)\?"\%(default\s\+link\s\+\)\?\(\a\+\).*",.*')
    657 			if !empty(list)
    658 				let item.name = list[1]
    659 				let item.type = 'both'
    660 				call add(a:li, copy(item))
    661 			endif
    662 		endfor
    663 
    664 		%delete _
    665 		put b
    666 		for line in getline(1, line('$'))
    667 			let list = matchlist(line, '^\s*\%(CENT(\)\?"\%(default\s\+link\s\+\)\?\(\a\+\).*",.*')
    668 			if !empty(list)
    669 				let item.name = list[1]
    670 				let item.type = 'light'
    671 				call add(a:li, copy(item))
    672 			endif
    673 		endfor
    674 
    675 		%delete _
    676 		put d
    677 		for line in getline(1, line('$'))
    678 			let list = matchlist(line, '^\s*if\s*(set_group_colors(.*"\(\a\+\)",')
    679 			if !empty(list) && list[1] !=# 'Normal'
    680 				let item.name = list[1]
    681 				let item.type = 'gui'
    682 				call add(a:li, copy(item))
    683 			endif
    684 		endfor
    685 
    686 		let item.name = 'CursorIM'
    687 		let item.type = 'gui'
    688 		call add(a:li, copy(item))
    689 
    690 		" The following highlight groups cannot be extracted from highlight.c
    691 		" (TODO: extract from HIGHLIGHT_INIT ?)
    692 		for group in ['ComplMatchIns', 'LineNrAbove', 'LineNrBelow', 'MsgArea', 'Terminal']
    693 			let item.name = group
    694 			let item.type = 'both'
    695 			call add(a:li, copy(item))
    696 		endfor
    697 
    698 		for n in range(1, 9)
    699 			let item.name = 'User' .. n
    700 			let item.type = 'both'
    701 			call add(a:li, copy(item))
    702 		endfor
    703 
    704 		" "Conceal" is a :syn option and cannot be used as keyword, so remove it.
    705 		" (Separately specified as 'syn match' in vim.vim.base).
    706 		call filter(a:li, {idx, val -> val.name !=# 'Conceal'})
    707 
    708 		quit!
    709 
    710 		if empty(a:li)
    711 			throw 'hlgroup is empty'
    712 		endif
    713 	catch /.*/
    714 		call s:err_gen('')
    715 		throw 'exit'
    716 	endtry
    717 endfunc
    718 
    719 " ------------------------------------------------------------------------------
    720 function s:parse_vim_complete_name(li)
    721 	try
    722 		let file_name = $VIM_SRCDIR . '/usercmd.c'
    723 		let item = {}
    724 
    725 		new
    726 		exec 'read ' . file_name
    727 		norm! gg
    728 		exec '/^static keyvalue_T command_complete_tab\[] =$/+1;/^};$/-1yank'
    729 		%delete _
    730 
    731 		put
    732 		g!/^\s*KEYVALUE_ENTRY(/d
    733 		g/"custom\(list\)\?"/d
    734 
    735 		for line in getline(1, line('$'))
    736 			let list = matchlist(line, '^\s*KEYVALUE_ENTRY(EXPAND_\w\+,\s*"\(\w\+\)"')
    737 			let item.name = list[1]
    738 			call add(a:li, copy(item))
    739 		endfor
    740 
    741 		quit!
    742 
    743 		if empty(a:li)
    744 			throw 'complete_name is empty'
    745 		endif
    746 	catch /.*/
    747 		call s:err_gen('')
    748 		throw 'exit'
    749 	endtry
    750 endfunc
    751 
    752 " ------------------------------------------------------------------------------
    753 function s:parse_vim_addr_name(li)
    754 	try
    755 		let file_name = $VIM_SRCDIR . '/usercmd.c'
    756 		let item = {}
    757 
    758 		new
    759 		exec 'read ' . file_name
    760 		norm! gg
    761 		exec '/^static addrtype_T addr_type_complete_tab\[] =$/+1;/^};$/-1yank'
    762 		%delete _
    763 
    764 		put
    765 		g!/^\s*ADDRTYPE_ENTRY(/d
    766 
    767 		for line in getline(1, line('$'))
    768 			let list = matchlist(line, '^\s*ADDRTYPE_ENTRY(ADDR_\w\+,\s*"\(\w\+\)",\s*"\(.*\)"')
    769 			let item.name = list[1]
    770 			call add(a:li, copy(item))
    771 			let item.name = list[2]
    772 			call add(a:li, copy(item))
    773 		endfor
    774 
    775 		" '?' is not in 'iskeyword' and cannot be used as keyword, so remove it.
    776 		" (Separately specified as 'syn match' in vim.vim.base).
    777 		call filter(a:li, {idx, val -> val.name !=# '?'})
    778 
    779 		quit!
    780 
    781 		if empty(a:li)
    782 			throw 'addr_name is empty'
    783 		endif
    784 	catch /.*/
    785 		call s:err_gen('')
    786 		throw 'exit'
    787 	endtry
    788 endfunc
    789 
    790 " ------------------------------------------------------------------------------
    791 function s:parse_vim_var(li)
    792 	try
    793 		let file_name = $VIM_SRCDIR . '/evalvars.c'
    794 		let item = {}
    795 
    796 		new
    797 		exec 'read ' . file_name
    798 		norm! gg
    799 		exec '/^} vimvars\[VV_LEN] =\n{$/+1;/^};$/-1yank'
    800 		%delete _
    801 
    802 		put
    803 		g!/^\s*{VV_NAME(/d
    804 
    805 		for line in getline(1, line('$'))
    806 			let list = matchlist(line, '^\s*{VV_NAME("\(\w\+\)"')
    807 			let item.name = list[1]
    808 			call add(a:li, copy(item))
    809 		endfor
    810 
    811 		quit!
    812 
    813 		if empty(a:li)
    814 			throw 'var is empty'
    815 		endif
    816 	catch /.*/
    817 		call s:err_gen('')
    818 		throw 'exit'
    819 	endtry
    820 endfunc
    821 
    822 " ------------------------------------------------------------------------------
    823 function s:append_syn_any(lnum, str_info, li)
    824 	let ret_lnum = a:lnum
    825 	let str = a:str_info.start
    826 
    827 	for o in a:li
    828 		let str .= ' ' . o.name
    829 		if len(str) > s:line_break_len
    830 			if !empty(a:str_info.end)
    831 				let str .= ' ' . a:str_info.end
    832 			endif
    833 			call append(ret_lnum, str)
    834 			let str = a:str_info.start
    835 			let ret_lnum += 1
    836 		endif
    837 	endfor
    838 	if str !=# a:str_info.start
    839 		if !empty(a:str_info.end)
    840 			let str .= ' ' . a:str_info.end
    841 		endif
    842 		call append(ret_lnum, str)
    843 		let ret_lnum += 1
    844 	endif
    845 	return ret_lnum
    846 endfunc
    847 
    848 " ------------------------------------------------------------------------------
    849 function s:update_syntax_vim_file(vim_info)
    850 	try
    851 		function! s:search_and_check(kword, base_fname, str_info)
    852 			let a:str_info.start = ''
    853 			let a:str_info.end = ''
    854 
    855 			let pattern = '^" GEN_SYN_VIM: ' . a:kword . '\s*,'
    856 			let lnum = search(pattern)
    857 			if lnum == 0
    858 				throw 'Search pattern ''' . pattern . ''' not found in ' .
    859 				\		a:base_fname
    860 			endif
    861 			let li = matchlist(getline(lnum), pattern . '\s*START_STR\s*=\s*''\(.\{-}\)''\s*,\s*END_STR\s*=\s*''\(.\{-}\)''')
    862 			if empty(li)
    863 				throw 'Bad str_info line:' . getline(lnum)
    864 			endif
    865 			let a:str_info.start = li[1]
    866 			let a:str_info.end = li[2]
    867 			return lnum
    868 		endfunc
    869 
    870 		let target_fname = 'vim.vim.rc'
    871 		let base_fname = 'vim.vim.base'
    872 		let str_info = {}
    873 		let str_info.start = ''
    874 		let str_info.end = ''
    875 
    876 		new
    877 		exec 'edit ' . target_fname
    878 		%d _
    879 		exec 'read ' . base_fname
    880 		1delete _
    881 		call cursor(1, 1)
    882 
    883 		" vimCommand
    884 		let li = a:vim_info.cmd
    885 		" vimCommand - normal
    886 		let lnum = s:search_and_check('vimCommand normal', base_fname, str_info)
    887 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 0)
    888 
    889 		" vimOption
    890 		let kword = 'vimOption'
    891 		let li = a:vim_info.opt
    892 		" vimOption - normal
    893 		let lnum = s:search_and_check(kword . ' normal', base_fname, str_info)
    894 		let lnum = s:append_syn_vimopt(lnum, str_info, li, '', 0)
    895 		" vimOption - turn-off
    896 		let lnum = s:search_and_check(kword . ' turn-off', base_fname, str_info)
    897 		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'no', 1)
    898 		" vimOption - invertible
    899 		let lnum = s:search_and_check(kword . ' invertible', base_fname, str_info)
    900 		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'inv', 1)
    901 		" vimOption - term output code
    902 		let li = a:vim_info.term_out_code
    903 		let lnum = s:search_and_check(kword . ' term output code', base_fname, str_info)
    904 		let lnum = s:append_syn_any(lnum, str_info, li)
    905 
    906 		" vimOption - normal variable
    907 		let li = a:vim_info.opt
    908 		let lnum = s:search_and_check(kword . ' normal variable', base_fname, str_info)
    909 		let lnum = s:append_syn_vimopt(lnum, str_info, li, '', 0)
    910 		" vimOption - term output code variable
    911 		let li = a:vim_info.term_out_code
    912 		let lnum = s:search_and_check(kword . ' term output code variable', base_fname, str_info)
    913 		let lnum = s:append_syn_any(lnum, str_info, li)
    914 
    915 		" Missing vimOption
    916 		let li = a:vim_info.missing_opt
    917 		let lnum = s:search_and_check('Missing vimOption', base_fname, str_info)
    918 		let lnum = s:append_syn_vimopt(lnum, str_info, li, '', 0)
    919 		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'no', 1)
    920 		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'inv', 1)
    921 
    922 		" vimAutoEvent
    923 		let li = a:vim_info.event
    924 		let lnum = s:search_and_check('vimAutoEvent', base_fname, str_info)
    925 		let lnum = s:append_syn_any(lnum, str_info, li)
    926 
    927 		" vimGroup
    928 		let li = a:vim_info.group
    929 		let lnum = s:search_and_check('vimGroup', base_fname, str_info)
    930 		let lnum = s:append_syn_any(lnum, str_info, li)
    931 
    932 		" vimHLGroup
    933 		let li = a:vim_info.hlgroup
    934 		let lnum = s:search_and_check('vimHLGroup', base_fname, str_info)
    935 		let lnum = s:append_syn_any(lnum, str_info, li)
    936 
    937 		" vimFuncName
    938 		let li = a:vim_info.func
    939 		let lnum = s:search_and_check('vimFuncName', base_fname, str_info)
    940 		let lnum = s:append_syn_any(lnum, str_info, li)
    941 
    942 		" vimVarName
    943 		let li = a:vim_info.var
    944 		let lnum = s:search_and_check('vimVarName', base_fname, str_info)
    945 		let lnum = s:append_syn_any(lnum, str_info, li)
    946 
    947 		" vimUserAttrComplete
    948 		let li = a:vim_info.compl_name
    949 		let lnum = s:search_and_check('vimUserCmdAttrComplete', base_fname, str_info)
    950 		let lnum = s:append_syn_any(lnum, str_info, li)
    951 
    952 		" vimUserAttrbAddr
    953 		let li = a:vim_info.addr_name
    954 		let lnum = s:search_and_check('vimUserCmdAttrAddr', base_fname, str_info)
    955 		let lnum = s:append_syn_any(lnum, str_info, li)
    956 
    957 		" vimCommand - abbrev
    958 		let kword = 'vimCommand'
    959 		let li = a:vim_info.cmd
    960 		let lnum = s:search_and_check(kword . ' abbrev', base_fname, str_info)
    961 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 2)
    962 		let lnum = s:search_and_check(kword . ' abclear', base_fname, str_info)
    963 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 7)
    964 		" vimCommand - map
    965 		let lnum = s:search_and_check(kword . ' map', base_fname, str_info)
    966 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 4)
    967 		let lnum = s:search_and_check(kword . ' mapclear', base_fname, str_info)
    968 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 5)
    969 		let lnum = s:search_and_check(kword . ' unmap', base_fname, str_info)
    970 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 6)
    971 		" vimCommand - menu
    972 		let lnum = s:search_and_check(kword . ' menu', base_fname, str_info)
    973 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 3)
    974 		" vimCommand - modifier
    975 		let lnum = s:search_and_check(kword . ' modifier', base_fname, str_info)
    976 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 8)
    977 		" vimCommand - cd
    978 		let lnum = s:search_and_check(kword . ' cd', base_fname, str_info)
    979 		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 9)
    980 
    981 		update
    982 		quit!
    983 
    984 	catch /.*/
    985 		call s:err_gen('')
    986 		throw 'exit'
    987 	endtry
    988 endfunc
    989 
    990 " ------------------------------------------------------------------------------
    991 function s:check_help_doc(vim_info)
    992 	try
    993 		new
    994 		let cwd_save = getcwd()
    995 		cd ../../../runtime/doc
    996 
    997 		let exclude_cmd =<< trim END
    998 			deletel
    999 			deletep
   1000 			a
   1001 			i
   1002 		END
   1003 
   1004 		let nocheck_shorten_excmd_list =<< trim END
   1005 			bufdo
   1006 			cfdo
   1007 			cstag
   1008 			debug
   1009 			defer
   1010 			eval
   1011 			intro
   1012 			lfdo
   1013 			luado
   1014 			luafile
   1015 			ownsyntax
   1016 			py3do
   1017 			pydo
   1018 			pyxdo
   1019 			pyxfile
   1020 			rundo
   1021 			smile
   1022 			syntime
   1023 			windo
   1024 			wundo
   1025 		END
   1026 
   1027 		" Check the Ex-command is listed in index.txt
   1028 		split index.txt
   1029 		for vimcmd in a:vim_info.cmd
   1030 			if index(exclude_cmd, vimcmd.name) != -1
   1031 				continue
   1032 			endif
   1033 			norm! gg
   1034 			let find_ptn = '^|:' . vimcmd.name . '|\s\+'
   1035 			let lnum = search(find_ptn, 'eW')
   1036 			if lnum == 0
   1037 				call s:err_sanity($'Ex-cmd ":{vimcmd.name}" is not found in index.txt.')
   1038 			elseif search(find_ptn, 'eW') > 0
   1039 				call s:err_sanity($'Ex-cmd ":{vimcmd.name}" is duplicated in index.txt.')
   1040 			else
   1041 				let doc_syn_str = substitute(getline(lnum), find_ptn . ':\(\S\+\)\s\+.*', '\1', '')
   1042 				if doc_syn_str !=# vimcmd.syn_str
   1043 					call s:err_sanity($'Ex-cmd "{vimcmd.name}" short name differ in index.txt. expect: "{vimcmd.syn_str}", but: "{doc_syn_str}"')
   1044 				endif
   1045 			endif
   1046 		endfor
   1047 		quit!
   1048 
   1049 		" Check the existence of the help tag for Ex-command.
   1050 		set wildignore=version*.txt,todo.txt,usr_*.txt
   1051 		for vimcmd in a:vim_info.cmd
   1052 			if index(exclude_cmd, vimcmd.name) != -1
   1053 				continue
   1054 			endif
   1055 			let find_ptn = '\s\*:' . vimcmd.name . '\*\_s'
   1056 			exec "silent! vimgrep /" . find_ptn . "/gj *.txt"
   1057 			let qfl = getqflist()
   1058 			if empty(qfl)
   1059 				call s:err_sanity($'Help tag for Ex-cmd ":{vimcmd.name}" not found.')
   1060 			elseif len(qfl) > 1
   1061 				call s:err_sanity($'Help tag for Ex-cmd ":{vimcmd.name}" is duplicated.')
   1062 			elseif index(nocheck_shorten_excmd_list, vimcmd.name) ==# -1
   1063 				" Check the existence of the shorten Ex-command notation.
   1064 				cc
   1065 				norm! 2k
   1066 				let end_lnum = qfl[0].lnum + 10
   1067 				let find_ptn = '^:.*\<' . vimcmd.syn_str->escape('[]')
   1068 				let lnum = search(find_ptn, 'W', end_lnum)
   1069 				if lnum == 0
   1070 					if vimcmd.omit_idx != -1
   1071 						" Check the existence of the shorten help tag for Ex-command.
   1072 						cc
   1073 						norm! k
   1074 						let end_lnum = qfl[0].lnum + 10
   1075 						let find_ptn = '\s\*:' . vimcmd.name[:vimcmd.omit_idx] . '\*\_s'
   1076 						let lnum = search(find_ptn, 'W', end_lnum)
   1077 					else
   1078 						let lnum = 1
   1079 					endif
   1080 					if lnum == 0
   1081 						call s:err_sanity($'Shorten help tag "{vimcmd.name[:vimcmd.omit_idx]}" for Ex-cmd "{vimcmd.name}" not found.')
   1082 					endif
   1083 				endif
   1084 			endif
   1085 		endfor
   1086 	catch /.*/
   1087 		call s:err_gen('')
   1088 		throw 'exit'
   1089 	finally
   1090 		call s:err_gen('Ex-cmd documentation consistency check completed.')
   1091 		exec 'cd ' . cwd_save
   1092 		set wildignore&
   1093 	endtry
   1094 endfunc
   1095 
   1096 " ------------------------------------------------------------------------------
   1097 function s:err_gen(arg)
   1098 	call s:write_error(a:arg, s:log_write_dir .. 'generator.err')
   1099 endfunc
   1100 
   1101 function s:err_sanity(arg)
   1102 	call s:write_error(a:arg, s:log_write_dir .. 'sanity_check.err')
   1103 endfunc
   1104 
   1105 function s:write_error(arg, fname)
   1106 	let li = []
   1107 	if !empty(v:throwpoint)
   1108 		call add(li, v:throwpoint)
   1109 	endif
   1110 	if !empty(v:exception)
   1111 		call add(li, v:exception)
   1112 	endif
   1113 	if type(a:arg) == type([])
   1114 		call extend(li, a:arg)
   1115 	elseif type(a:arg) == type("")
   1116 		if !empty(a:arg)
   1117 			call add(li, a:arg)
   1118 		endif
   1119 	endif
   1120 	if !empty(li)
   1121 		call writefile(li, a:fname, 'a')
   1122 	else
   1123 		call writefile(['UNKNOWN'], a:fname, 'a')
   1124 	endif
   1125 endfunc
   1126 
   1127 " ------------------------------------------------------------------------------
   1128 try
   1129 	let s:line_break_len = 768
   1130 	let s:vim_info = {}
   1131 	let s:vim_info.opt = []
   1132 	let s:vim_info.missing_opt = []
   1133 	let s:vim_info.term_out_code = []
   1134 	let s:vim_info.cmd = []
   1135 	let s:vim_info.event = []
   1136 	let s:vim_info.func = []
   1137 	let s:vim_info.group = []
   1138 	let s:vim_info.hlgroup = []
   1139 	let s:vim_info.compl_name = []
   1140 	let s:vim_info.addr_name = []
   1141 	let s:vim_info.var = []
   1142 
   1143 	set lazyredraw
   1144 	if !$CHECK_HELP_DOC
   1145 		silent call s:parse_vim_option(s:vim_info.opt, s:vim_info.missing_opt,
   1146 		\						s:vim_info.term_out_code)
   1147 		silent call s:parse_vim_command(s:vim_info.cmd)
   1148 		silent call s:parse_vim_event(s:vim_info.event)
   1149 		silent call s:parse_vim_function(s:vim_info.func)
   1150 		silent call s:parse_vim_group(s:vim_info.group)
   1151 		silent call s:parse_vim_hlgroup(s:vim_info.hlgroup)
   1152 		silent call s:parse_vim_complete_name(s:vim_info.compl_name)
   1153 		silent call s:parse_vim_addr_name(s:vim_info.addr_name)
   1154 		silent call s:parse_vim_var(s:vim_info.var)
   1155 
   1156 		call s:update_syntax_vim_file(s:vim_info)
   1157 	else
   1158 		silent call s:parse_vim_command(s:vim_info.cmd)
   1159 		silent call s:check_help_doc(s:vim_info)
   1160 	endif
   1161 	set nolazyredraw
   1162 
   1163 finally
   1164 	quitall!
   1165 endtry
   1166 
   1167 " ---------------------------------------------------------------------
   1168 let &cpo = s:keepcpo
   1169 unlet s:keepcpo
   1170 " vim:ts=2 sw=2