vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

cpp.vim (7887B)


      1 " Vim syntax file
      2 " Language:		C++
      3 " Maintainer:		This runtime file is looking for a new maintainer.
      4 " Previous Maintainers:	vim-jp (https://github.com/vim-jp/vim-cpp)
      5 "			Ken Shan <ccshan@post.harvard.edu>
      6 " Last Change:		2026 Sep 16
      7 
      8 " quit when a syntax file was already loaded
      9 if exists("b:current_syntax")
     10   finish
     11 endif
     12 
     13 " inform C syntax that the file was included from cpp.vim
     14 let b:filetype_in_cpp_family = 1
     15 
     16 " Read the C syntax to start with
     17 runtime! syntax/c.vim
     18 unlet b:current_syntax
     19 unlet b:filetype_in_cpp_family
     20 
     21 " C++ extensions
     22 syn keyword cppStatement	new delete this friend using
     23 syn keyword cppAccess		public protected private
     24 syn keyword cppModifier		inline virtual explicit export
     25 syn keyword cppType		bool wchar_t
     26 syn keyword cppExceptions	throw try catch
     27 syn keyword cppOperator		operator typeid
     28 syn keyword cppOperator		and bitor or xor compl bitand and_eq or_eq xor_eq not not_eq
     29 syn match cppCast		"\<\%(const\|static\|dynamic\|reinterpret\)_cast\s*<"me=e-1
     30 syn match cppCast		"\<\%(const\|static\|dynamic\|reinterpret\)_cast\s*$"
     31 syn keyword cppStorageClass	mutable
     32 syn keyword cppStructure	class typename template namespace
     33 syn keyword cppBoolean		true false
     34 syn keyword cppConstant		__cplusplus
     35 
     36 " C++ 11 extensions
     37 if !exists("cpp_no_cpp11")
     38   syn keyword cppModifier	override final
     39   syn keyword cppType		nullptr_t auto
     40   syn keyword cppExceptions	noexcept
     41   syn keyword cppStorageClass	constexpr decltype thread_local
     42   syn keyword cppConstant	nullptr
     43   syn keyword cppConstant	ATOMIC_FLAG_INIT ATOMIC_VAR_INIT
     44   syn keyword cppConstant	ATOMIC_BOOL_LOCK_FREE ATOMIC_CHAR_LOCK_FREE
     45   syn keyword cppConstant	ATOMIC_CHAR16_T_LOCK_FREE ATOMIC_CHAR32_T_LOCK_FREE
     46   syn keyword cppConstant	ATOMIC_WCHAR_T_LOCK_FREE ATOMIC_SHORT_LOCK_FREE
     47   syn keyword cppConstant	ATOMIC_INT_LOCK_FREE ATOMIC_LONG_LOCK_FREE
     48   syn keyword cppConstant	ATOMIC_LLONG_LOCK_FREE ATOMIC_POINTER_LOCK_FREE
     49   syn region cppRawString	matchgroup=cppRawStringDelimiter start=+\%(u8\|[uLU]\)\=R"\z([[:alnum:]_{}[\]#<>%:;.?*\+\-/\^&|~!=,"']\{,16}\)(+ end=+)\z1"\%(sv\|s\|_[_a-zA-Z][_a-zA-Z0-9]*\)\=+ contains=@Spell
     50   syn match cppCast		"\<\%(const\|static\|dynamic\)_pointer_cast\s*<"me=e-1
     51   syn match cppCast		"\<\%(const\|static\|dynamic\)_pointer_cast\s*$"
     52 endif
     53 
     54 " C++ 14 extensions
     55 if !exists("cpp_no_cpp14")
     56   syn match cppNumbers		display transparent "\<\d\|\.\d" contains=cppNumber,cppFloat
     57   syn match cppNumber		display contained "\<0\%([Uu]\=\%([Ll]\|LL\|ll\)\|\%([Ll]\|LL\|ll\)\=[Uu]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     58   syn match cppNumber		display contained "\<[1-9]\d*\%('\d\+\)*\%([Uu]\=\%([Ll]\|LL\|ll\)\|\%([Ll]\|LL\|ll\)\=[Uu]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     59   syn match cppNumber		display contained "\<0\o*\%('\o\+\)*\%([Uu]\=\%([Ll]\|LL\|ll\)\|\%([Ll]\|LL\|ll\)\=[Uu]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     60   syn match cppNumber		display contained "\<0[Bb][01]\+\%('[01]\+\)*\%([Uu]\=\%([Ll]\|LL\|ll\)\|\%([Ll]\|LL\|ll\)\=[Uu]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     61   syn match cppNumber		display contained "\<0[Xx]\x\+\%('\x\+\)*\%([Uu]\=\%([Ll]\|LL\|ll\)\|\%([Ll]\|LL\|ll\)\=[Uu]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     62   syn match cppFloat		display contained "\<\d\+\%('\d\+\)*\.\%(\d\+\%('\d\+\)*\)\=\%([Ee][-+]\=\d\+\)\=\%([FfLl]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     63   syn match cppFloat		display contained "\.\d\+\%('\d\+\)*\%([Ee][-+]\=\d\+\)\=\%([FfLl]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     64   syn match cppFloat		display contained "\<\d\+[Ee][-+]\=\d\+\%([FfLl]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     65   syn region cppString		start=+\%(L\|u\|u8\|U\)\="+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"\%(sv\|s\|_\i*\)\=+ end='$' contains=cSpecial,cFormat,@Spell
     66 endif
     67 
     68 " C++ 17 extensions
     69 if !exists("cpp_no_cpp17")
     70   syn match cppCast		"\<reinterpret_pointer_cast\s*<"me=e-1
     71   syn match cppCast		"\<reinterpret_pointer_cast\s*$"
     72   syn match cppFloat		display contained "\<0[Xx]\%(\x\+\%('\x\+\)*\)\=\.\x\+\%('\x\+\)*[Pp][-+]\=\d\+\%('\d\+\)*\%([FfLl]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     73   syn match cppFloat		display contained "\<0[Xx]\x\+\%('\x\+\)*\.\=[Pp][-+]\=\d\+\%('\d\+\)*\%([FfLl]\|i[fl]\=\|h\|min\|s\|ms\|us\|ns\|_\i*\)\=\>"
     74 
     75   " TODO: push this up to c.vim if/when supported in C23
     76   syn match cppCharacter	"u8'[^\\]'"
     77   syn match cppCharacter	"u8'[^']*'" contains=cSpecial
     78   if exists("c_gnu")
     79     syn match cppSpecialError	  "u8'\\[^'\"?\\abefnrtv]'"
     80     syn match cppSpecialCharacter "u8'\\['\"?\\abefnrtv]'"
     81   else
     82     syn match cppSpecialError	  "u8'\\[^'\"?\\abfnrtv]'"
     83     syn match cppSpecialCharacter "u8'\\['\"?\\abfnrtv]'"
     84   endif
     85   syn match cppSpecialCharacter display "u8'\\\o\{1,3}'"
     86   syn match cppSpecialCharacter display "u8'\\x\x\+'"
     87 
     88 endif
     89 
     90 " C++ 20 extensions
     91 if !exists("cpp_no_cpp20")
     92   syn match cppNumber		display contained "\<0\%(y\|d\)\>"
     93   syn match cppNumber		display contained "\<[1-9]\d*\%('\d\+\)*\%(y\|d\)\>"
     94   syn match cppNumber		display contained "\<0\o\+\%(y\|d\)\>"
     95   syn match cppNumber		display contained "\<0[Bb][01]\+\%('[01]\+\)*\%(y\|d\)\>"
     96   syn match cppNumber		display contained "\<0[Xx]\x\+\%('\x\+\)*\%(y\|d\)\>"
     97   syn keyword cppStatement	co_await co_return co_yield requires
     98   syn keyword cppStorageClass	consteval constinit
     99   syn keyword cppStructure	concept
    100   syn keyword cppType		char8_t
    101   syn keyword cppModule		import module export
    102 endif
    103 
    104 " C++ 23 extensions
    105 if !exists("cpp_no_cpp23")
    106   syn match cppNumber		display contained "\<0\%([Zz][Uu]\=\|[Uu][Zz]\)\>"
    107   syn match cppNumber		display contained "\<[1-9]\d*\%('\d\+\)*\%([Zz][Uu]\=\|[Uu][Zz]\)\>"
    108   syn match cppNumber		display contained "\<0\o*\%('\o\+\)*\%([Zz][Uu]\=\|[Uu][Zz]\)\>"
    109   syn match cppNumber		display contained "\<0[Bb][01]\+\%('[01]\+\)*\%([Zz][Uu]\=\|[Uu][Zz]\)\>"
    110   syn match cppNumber		display contained "\<0[Xx]\x\+\%('\x\+\)*\%([Zz][Uu]\=\|[Uu][Zz]\)\>"
    111   syn match cppFloat		display contained "\<\d\+\%('\d\+\)*\.\%(\d\+\%('\d\+\)*\)\=\%([Ee][-+]\=\d\+\%('\d\+\)*\)\=\%([Ff]\%(16\|32\|64\|128\)\|\%(BF\|bf\)16\)\>"
    112   syn match cppFloat		display contained "\.\d\+\%('\d\+\)*\%([Ee][-+]\=\d\+\%('\d\+\)*\)\=\%([Ff]\%(16\|32\|64\|128\)\|\%(BF\|bf\)16\)\=\>"
    113   syn match cppFloat		display contained "\<0[Xx]\%(\x\+\%('\x\+\)*\)\=\.\x\+\%('\x\+\)*[Pp][-+]\=\d\+\%('\d\+\)*\%([Ff]\%(16\|32\|64\|128\)\|\%(BF\|bf\)16\)\=\>"
    114   syn match cppFloat		display contained "\<0[Xx]\x\+\%('\x\+\)*\.\=[Pp][-+]\=\d\+\%('\d\+\)*\%([Ff]\%(16\|32\|64\|128\)\|\%(BF\|bf\)16\)\=\>"
    115   syn keyword cppType		float16_t float32_t float64_t float128_t bfloat16_t
    116 endif
    117 
    118 " C++ 26 extensions
    119 if !exists("cpp_no_cpp26")
    120   " attribute [[ ... ]] with optional value expr, eg [[=foo{1}]]
    121   syn region cppAttribute	matchgroup=cppAttributeBracket start="\w\@1<!\[\[" end="\]\]" contains=TOP,@Spell
    122   syn match cppReflect		"\^\^"
    123   syn match cppSpliceBracket	"\[:\|:\]"
    124   syn keyword cppStatement	contract_assert
    125 endif
    126 
    127 " The minimum and maximum operators in GNU C++
    128 syn match cppMinMax "[<>]?"
    129 
    130 " Default highlighting
    131 hi def link cppAccess			cppStatement
    132 hi def link cppCast			cppStatement
    133 hi def link cppExceptions		Exception
    134 hi def link cppOperator			Operator
    135 hi def link cppStatement		Statement
    136 hi def link cppModifier			Type
    137 hi def link cppType			Type
    138 hi def link cppStorageClass		StorageClass
    139 hi def link cppStructure		Structure
    140 hi def link cppBoolean			Boolean
    141 hi def link cppCharacter		cCharacter
    142 hi def link cppSpecialCharacter		cSpecialCharacter
    143 hi def link cppSpecialError		cSpecialError
    144 hi def link cppConstant			Constant
    145 hi def link cppRawStringDelimiter	Delimiter
    146 hi def link cppRawString		String
    147 hi def link cppString			String
    148 hi def link cppNumber			Number
    149 hi def link cppFloat			Number
    150 hi def link cppModule			Include
    151 hi def link cppAttributeBracket		Special
    152 hi def link cppReflect			Operator
    153 hi def link cppSpliceBracket		Special
    154 
    155 let b:current_syntax = "cpp"
    156 
    157 " vim: ts=8