vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

matchparen.vim (7732B)


      1 " Vim plugin for showing matching parens
      2 " Maintainer:	The Vim Project <https://github.com/vim/vim>
      3 " Last Change:	2025 Apr 08
      4 " Former Maintainer:	Bram Moolenaar <Bram@vim.org>
      5 
      6 " Exit quickly when:
      7 " - this plugin was already loaded (or disabled)
      8 " - when 'compatible' is set
      9 " - Vim has no support for :defer
     10 if exists("g:loaded_matchparen") || &cp || exists(":defer") != 2
     11   finish
     12 endif
     13 let g:loaded_matchparen = 1
     14 
     15 if !exists("g:matchparen_timeout")
     16   let g:matchparen_timeout = 300
     17 endif
     18 if !exists("g:matchparen_insert_timeout")
     19   let g:matchparen_insert_timeout = 60
     20 endif
     21 if !exists("g:matchparen_disable_cursor_hl")
     22   let g:matchparen_disable_cursor_hl = 0
     23 endif
     24 
     25 augroup matchparen
     26   " Replace all matchparen autocommands
     27   autocmd! CursorMoved,CursorMovedI,WinEnter,WinScrolled * call s:Highlight_Matching_Pair()
     28   autocmd! BufWinEnter * autocmd SafeState * ++once call s:Highlight_Matching_Pair()
     29   autocmd! WinLeave,BufLeave * call s:Remove_Matches()
     30   autocmd! TextChanged,TextChangedI * call s:Highlight_Matching_Pair()
     31   autocmd! TextChangedP * call s:Remove_Matches()
     32 augroup END
     33 
     34 " Skip the rest if it was already done.
     35 if exists("*s:Highlight_Matching_Pair")
     36   finish
     37 endif
     38 
     39 let s:cpo_save = &cpo
     40 set cpo-=C
     41 
     42 " The function that is invoked (very often) to define a ":match" highlighting
     43 " for any matching paren.
     44 func s:Highlight_Matching_Pair()
     45   if !exists("w:matchparen_ids")
     46     let w:matchparen_ids = []
     47   endif
     48   " Remove any previous match.
     49   call s:Remove_Matches()
     50 
     51   " Avoid that we remove the popup menu.
     52   " Return when there are no colors (looks like the cursor jumps).
     53   if pumvisible() || (&t_Co < 8 && !has("gui_running"))
     54     return
     55   endif
     56 
     57   " Get the character under the cursor and check if it's in 'matchpairs'.
     58   let c_lnum = line('.')
     59   let c_col = col('.')
     60   let before = 0
     61 
     62   let text = getline(c_lnum)
     63   let c_before = text->strpart(0, c_col - 1)->slice(-1)
     64   let c = text->strpart(c_col - 1)->slice(0, 1)
     65   let plist = split(&matchpairs, '.\zs[:,]')
     66   let i = index(plist, c)
     67   if i < 0
     68     " not found, in Insert mode try character before the cursor
     69     if c_col > 1 && (mode() == 'i' || mode() == 'R')
     70       let before = strlen(c_before)
     71       let c = c_before
     72       let i = index(plist, c)
     73     endif
     74     if i < 0
     75       " not found, nothing to do
     76       return
     77     endif
     78   endif
     79 
     80   " Figure out the arguments for searchpairpos().
     81   if i % 2 == 0
     82     let s_flags = 'nW'
     83     let c2 = plist[i + 1]
     84   else
     85     let s_flags = 'nbW'
     86     let c2 = c
     87     let c = plist[i - 1]
     88   endif
     89   if c == '['
     90     let c = '\['
     91     let c2 = '\]'
     92   endif
     93 
     94   " Find the match.  When it was just before the cursor move it there for a
     95   " moment.
     96   if before > 0
     97     let save_cursor = getcurpos()
     98     call cursor(c_lnum, c_col - before)
     99     defer setpos('.', save_cursor)
    100   endif
    101 
    102   if !has("syntax") || !exists("g:syntax_on")
    103     let s_skip = "0"
    104   else
    105     " do not attempt to match when the syntax item where the cursor is
    106     " indicates there does not exist a matching parenthesis, e.g. for shells
    107     " case statement: "case $var in foobar)"
    108     "
    109     " add the check behind a filetype check, so it only needs to be
    110     " evaluated for certain filetypes
    111     if ['sh']->index(&filetype) >= 0 &&
    112         \ synstack(".", col("."))->indexof({_, id -> synIDattr(id, "name")
    113         \ =~? "shSnglCase"}) >= 0
    114       return
    115     endif
    116     " Build an expression that detects whether the current cursor position is
    117     " in certain syntax types (string, comment, etc.), for use as
    118     " searchpairpos()'s skip argument.
    119     " We match "escape" for special items, such as lispEscapeSpecial, and
    120     " match "symbol" for lispBarSymbol.
    121     let s_skip = 'synstack(".", col("."))'
    122         \ . '->indexof({_, id -> synIDattr(id, "name") =~? '
    123         \ . '"string\\|character\\|singlequote\\|escape\\|symbol\\|comment"}) >= 0'
    124     " If executing the expression determines that the cursor is currently in
    125     " one of the syntax types, then we want searchpairpos() to find the pair
    126     " within those syntax types (i.e., not skip).  Otherwise, the cursor is
    127     " outside of the syntax types and s_skip should keep its value so we skip
    128     " any matching pair inside the syntax types.
    129     " Catch if this throws E363: pattern uses more memory than 'maxmempattern'.
    130     try
    131       execute 'if ' . s_skip . ' | let s_skip = "0" | endif'
    132     catch /^Vim\%((\a\+)\)\=:E363/
    133       " We won't find anything, so skip searching, should keep Vim responsive.
    134       return
    135     endtry
    136   endif
    137 
    138   " Limit the search to lines visible in the window.
    139   let stoplinebottom = line('w$')
    140   let stoplinetop = line('w0')
    141   if i % 2 == 0
    142     let stopline = stoplinebottom
    143   else
    144     let stopline = stoplinetop
    145   endif
    146 
    147   " Limit the search time to 300 msec to avoid a hang on very long lines.
    148   " This fails when a timeout is not supported.
    149   if mode() == 'i' || mode() == 'R'
    150     let timeout = exists("b:matchparen_insert_timeout") ? b:matchparen_insert_timeout : g:matchparen_insert_timeout
    151   else
    152     let timeout = exists("b:matchparen_timeout") ? b:matchparen_timeout : g:matchparen_timeout
    153   endif
    154   try
    155     let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline, timeout)
    156   catch /E118/
    157     " Can't use the timeout, restrict the stopline a bit more to avoid taking
    158     " a long time on closed folds and long lines.
    159     " The "viewable" variables give a range in which we can scroll while
    160     " keeping the cursor at the same position.
    161     " adjustedScrolloff accounts for very large numbers of scrolloff.
    162     let adjustedScrolloff = min([&scrolloff, (line('w$') - line('w0')) / 2])
    163     let bottom_viewable = min([line('$'), c_lnum + &lines - adjustedScrolloff - 2])
    164     let top_viewable = max([1, c_lnum-&lines+adjustedScrolloff + 2])
    165     " one of these stoplines will be adjusted below, but the current values are
    166     " minimal boundaries within the current window
    167     if i % 2 == 0
    168       if has("byte_offset") && has("syntax_items") && &smc > 0
    169 	let stopbyte = min([line2byte("$"), line2byte(".") + col(".") + &smc * 2])
    170 	let stopline = min([bottom_viewable, byte2line(stopbyte)])
    171       else
    172 	let stopline = min([bottom_viewable, c_lnum + 100])
    173       endif
    174       let stoplinebottom = stopline
    175     else
    176       if has("byte_offset") && has("syntax_items") && &smc > 0
    177 	let stopbyte = max([1, line2byte(".") + col(".") - &smc * 2])
    178 	let stopline = max([top_viewable, byte2line(stopbyte)])
    179       else
    180 	let stopline = max([top_viewable, c_lnum - 100])
    181       endif
    182       let stoplinetop = stopline
    183     endif
    184     let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline)
    185   endtry
    186 
    187   " If a match is found setup match highlighting.
    188   if m_lnum > 0 && m_lnum >= stoplinetop && m_lnum <= stoplinebottom
    189     if !g:matchparen_disable_cursor_hl
    190       call add(w:matchparen_ids, matchaddpos('MatchParen', [[c_lnum, c_col - before], [m_lnum, m_col]], 10))
    191     else
    192       call add(w:matchparen_ids, matchaddpos('MatchParen', [[m_lnum, m_col]], 10))
    193     endif
    194     let w:paren_hl_on = 1
    195   endif
    196 endfunction
    197 
    198 func s:Remove_Matches()
    199   if exists('w:paren_hl_on') && w:paren_hl_on
    200     while !empty(w:matchparen_ids)
    201       silent! call remove(w:matchparen_ids, 0)->matchdelete()
    202     endwhile
    203     let w:paren_hl_on = 0
    204   endif
    205 endfunc
    206 
    207 " Define commands that will disable and enable the plugin.
    208 command DoMatchParen call s:DoMatchParen()
    209 command NoMatchParen call s:NoMatchParen()
    210 
    211 func s:NoMatchParen()
    212   let w = winnr()
    213   noau windo call s:Remove_Matches()
    214   unlet! g:loaded_matchparen
    215   exe "noau ". w . "wincmd w"
    216   au! matchparen
    217 endfunc
    218 
    219 func s:DoMatchParen()
    220   runtime plugin/matchparen.vim
    221   let w = winnr()
    222   silent windo doau CursorMoved
    223   exe "noau ". w . "wincmd w"
    224 endfunc
    225 
    226 let &cpo = s:cpo_save
    227 unlet s:cpo_save