vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

mswin.vim (4127B)


      1 " Set options and add mapping such that Vim behaves a lot like MS-Windows
      2 "
      3 " Maintainer:	The Vim Project <https://github.com/vim/vim>
      4 " Last Change:	2024 Mar 13
      5 " Former Maintainer:	Bram Moolenaar <Bram@vim.org>
      6 
      7 " Bail out if this isn't wanted.
      8 if exists("g:skip_loading_mswin") && g:skip_loading_mswin
      9   finish
     10 endif
     11 
     12 " set the 'cpoptions' to its Vim default
     13 if 1	" only do this when compiled with expression evaluation
     14   let s:save_cpo = &cpoptions
     15 endif
     16 set cpo&vim
     17 
     18 " set 'selection', 'selectmode', 'mousemodel' and 'keymodel' for MS-Windows
     19 behave mswin
     20 
     21 " backspace and cursor keys wrap to previous/next line
     22 set backspace=indent,eol,start whichwrap+=<,>,[,]
     23 
     24 " backspace in Visual mode deletes selection
     25 vnoremap <BS> d
     26 
     27 " the better solution would be to use has("clipboard_working"),
     28 " but that may not be available yet while starting up, so let's just check if
     29 " clipboard support has been compiled in and assume it will be working :/
     30 if has("clipboard")
     31     " CTRL-X and SHIFT-Del are Cut
     32     vnoremap <C-X> "+x
     33     vnoremap <S-Del> "+x
     34 
     35     " CTRL-C and CTRL-Insert are Copy
     36     vnoremap <C-C> "+y
     37     vnoremap <C-Insert> "+y
     38 
     39     " CTRL-V and SHIFT-Insert are Paste
     40     map <C-V>		"+gP
     41     map <S-Insert>		"+gP
     42 
     43     cmap <C-V>		<C-R>+
     44     cmap <S-Insert>		<C-R>+
     45 else
     46 		" Use the unnamed register when clipboard support not available
     47 
     48     " CTRL-X and SHIFT-Del are Cut
     49     vnoremap <C-X>   x
     50     vnoremap <S-Del> x
     51 
     52     " CTRL-C and CTRL-Insert are Copy
     53     vnoremap <C-C>      y
     54     vnoremap <C-Insert> y
     55 
     56     " CTRL-V and SHIFT-Insert are Paste
     57     noremap <C-V>      gP
     58     noremap <S-Insert> gP
     59 
     60     inoremap <C-V>      <C-R>"
     61     inoremap <S-Insert> <C-R>"
     62 endif
     63 
     64 " Pasting blockwise and linewise selections is not possible in Insert and
     65 " Visual mode without the +virtualedit feature.  They are pasted as if they
     66 " were characterwise instead.
     67 " Uses the paste.vim autoload script.
     68 " Use CTRL-G u to have CTRL-Z only undo the paste.
     69 
     70 if has("clipboard")
     71     exe 'inoremap <script> <C-V> <C-G>u' . paste#paste_cmd['i']
     72     exe 'vnoremap <script> <C-V> ' . paste#paste_cmd['v']
     73 endif
     74 
     75 imap <S-Insert>		<C-V>
     76 vmap <S-Insert>		<C-V>
     77 
     78 " Use CTRL-Q to do what CTRL-V used to do
     79 noremap <C-Q>		<C-V>
     80 
     81 " Use CTRL-S for saving, also in Insert mode (<C-O> doesn't work well when
     82 " using completions).
     83 noremap <C-S>		:update<CR>
     84 vnoremap <C-S>		<C-C>:update<CR>
     85 inoremap <C-S>		<Esc>:update<CR>gi
     86 
     87 " For CTRL-V to work autoselect must be off.
     88 " On Unix we have two selections, autoselect can be used.
     89 if !has("unix")
     90   set guioptions-=a
     91 endif
     92 
     93 " CTRL-Z is Undo; not in cmdline though
     94 noremap <C-Z> u
     95 inoremap <C-Z> <C-O>u
     96 
     97 " CTRL-Y is Redo (although not repeat); not in cmdline though
     98 noremap <C-Y> <C-R>
     99 inoremap <C-Y> <C-O><C-R>
    100 
    101 " Alt-Space is System menu
    102 if has("gui")
    103   noremap <M-Space> :simalt ~<CR>
    104   inoremap <M-Space> <C-O>:simalt ~<CR>
    105   cnoremap <M-Space> <C-C>:simalt ~<CR>
    106 endif
    107 
    108 " CTRL-A is Select all
    109 noremap <C-A> gggH<C-O>G
    110 inoremap <C-A> <C-O>gg<C-O>gH<C-O>G
    111 cnoremap <C-A> <C-C>gggH<C-O>G
    112 onoremap <C-A> <C-C>gggH<C-O>G
    113 snoremap <C-A> <C-C>gggH<C-O>G
    114 xnoremap <C-A> <C-C>ggVG
    115 
    116 " CTRL-Tab is Next window
    117 noremap <C-Tab> <C-W>w
    118 inoremap <C-Tab> <C-O><C-W>w
    119 cnoremap <C-Tab> <C-C><C-W>w
    120 onoremap <C-Tab> <C-C><C-W>w
    121 
    122 " CTRL-F4 is Close window
    123 noremap <C-F4> <C-W>c
    124 inoremap <C-F4> <C-O><C-W>c
    125 cnoremap <C-F4> <C-C><C-W>c
    126 onoremap <C-F4> <C-C><C-W>c
    127 
    128 if has("gui")
    129   " CTRL-F is the search dialog
    130   noremap  <expr> <C-F> has("gui_running") ? ":promptfind\<CR>" : "/"
    131   inoremap <expr> <C-F> has("gui_running") ? "\<C-\>\<C-O>:promptfind\<CR>" : "\<C-\>\<C-O>/"
    132   cnoremap <expr> <C-F> has("gui_running") ? "\<C-\>\<C-C>:promptfind\<CR>" : "\<C-\>\<C-O>/"
    133 
    134   " CTRL-H is the replace dialog,
    135   " but in console, it might be backspace, so don't map it there
    136   nnoremap <expr> <C-H> has("gui_running") ? ":promptrepl\<CR>" : "\<C-H>"
    137   inoremap <expr> <C-H> has("gui_running") ? "\<C-\>\<C-O>:promptrepl\<CR>" : "\<C-H>"
    138   cnoremap <expr> <C-H> has("gui_running") ? "\<C-\>\<C-C>:promptrepl\<CR>" : "\<C-H>"
    139 endif
    140 
    141 " restore 'cpoptions'
    142 set cpo&
    143 if 1
    144   let &cpoptions = s:save_cpo
    145   unlet s:save_cpo
    146 endif