vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

eiffel.vim (3317B)


      1 " Vim indent file
      2 " Language:	Eiffel
      3 " Maintainer:	Jocelyn Fiat <jfiat@eiffel.com>
      4 " Previous-Maintainer:	David Clarke <gadicath@dishevelled.net>
      5 " Contributions from: Takuya Fujiwara
      6 " Contributions from: Thilo Six
      7 " $Date: 2017/03/08 06:00:00 $
      8 " $Revision: 1.4 $
      9 " URL: https://github.com/eiffelhub/vim-eiffel
     10 
     11 " Only load this indent file when no other was loaded.
     12 if exists("b:did_indent")
     13   finish
     14 endif
     15 let b:did_indent = 1
     16 
     17 setlocal indentexpr=GetEiffelIndent()
     18 setlocal nolisp
     19 setlocal nosmartindent
     20 setlocal nocindent
     21 setlocal autoindent
     22 setlocal comments=:--
     23 setlocal indentkeys+==end,=else,=ensure,=require,=check,=loop,=until
     24 setlocal indentkeys+==creation,=feature,=inherit,=class,=is,=redefine,=rename,=variant
     25 setlocal indentkeys+==invariant,=do,=local,=export
     26 
     27 let b:undo_indent = "setl smartindent< indentkeys< indentexpr< autoindent< comments< "
     28 
     29 " Define some stuff
     30 " keywords grouped by indenting
     31 let s:trust_user_indent = '\(+\)\(\s*\(--\).*\)\=$'
     32 let s:relative_indent = '^\s*\(deferred\|class\|feature\|creation\|inherit\|loop\|from\|across\|until\|if\|else\|elseif\|ensure\|require\|check\|do\|local\|invariant\|variant\|rename\|redefine\|do\|export\)\>'
     33 let s:outdent = '^\s*\(else\|invariant\|variant\|do\|require\|until\|loop\|local\)\>'
     34 let s:no_indent = '^\s*\(class\|feature\|creation\|inherit\)\>'
     35 let s:single_dent = '^[^-]\+[[:alnum:]]\+ is\(\s*\(--\).*\)\=$'
     36 let s:inheritance_dent = '\s*\(redefine\|rename\|export\)\>'
     37 
     38 
     39 " Only define the function once.
     40 if exists("*GetEiffelIndent")
     41   finish
     42 endif
     43 
     44 let s:keepcpo= &cpo
     45 set cpo&vim
     46 
     47 function GetEiffelIndent()
     48 
     49   " Eiffel Class indenting
     50   "
     51   " Find a non-blank line above the current line.
     52   let lnum = prevnonblank(v:lnum - 1)
     53 
     54   " At the start of the file use zero indent.
     55   if lnum == 0
     56     return 0
     57   endif
     58 
     59   " trust the user's indenting
     60   if getline(lnum) =~ s:trust_user_indent
     61     return -1
     62   endif
     63 
     64   " Add a 'shiftwidth' after lines that start with an indent word
     65   let ind = indent(lnum)
     66   if getline(lnum) =~ s:relative_indent
     67     let ind = ind + shiftwidth()
     68   endif
     69 
     70   " Indent to single indent
     71   if getline(v:lnum) =~ s:single_dent && getline(v:lnum) !~ s:relative_indent
     72 	   \ && getline(v:lnum) !~ '\s*\<\(and\|or\|implies\)\>'
     73      let ind = shiftwidth()
     74   endif
     75 
     76   " Indent to double indent
     77   if getline(v:lnum) =~ s:inheritance_dent
     78      let ind = 2 * shiftwidth()
     79   endif
     80 
     81   " Indent line after the first line of the function definition
     82   if getline(lnum) =~ s:single_dent
     83      let ind = ind + shiftwidth()
     84   endif
     85 
     86   " The following should always be at the start of a line, no indenting
     87   if getline(v:lnum) =~ s:no_indent
     88      let ind = 0
     89   endif
     90 
     91   " Subtract a 'shiftwidth', if this isn't the first thing after the 'is'
     92   " or first thing after the 'do'
     93   if getline(v:lnum) =~ s:outdent && getline(v:lnum - 1) !~ s:single_dent
     94 	\ && getline(v:lnum - 1) !~ '^\s*do\>'
     95     let ind = ind - shiftwidth()
     96   endif
     97 
     98   " Subtract a shiftwidth for end statements
     99   if getline(v:lnum) =~ '^\s*end\>'
    100     let ind = ind - shiftwidth()
    101   endif
    102 
    103   " set indent of zero end statements that are at an indent of 3, this should
    104   " only ever be the class's end.
    105   if getline(v:lnum) =~ '^\s*end\>' && ind == shiftwidth()
    106     let ind = 0
    107   endif
    108 
    109   return ind
    110 endfunction
    111 
    112 let &cpo = s:keepcpo
    113 unlet s:keepcpo
    114 
    115 " vim:sw=2