vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

lua.vim (4823B)


      1 " Vim filetype plugin file.
      2 
      3 " Language:		Lua
      4 " Maintainer:		Doug Kearns <dougkearns@gmail.com>
      5 " Previous Maintainer:	Max Ischenko <mfi@ukr.net>
      6 " Contributor:		Dorai Sitaram <ds26@gte.com>
      7 "			C.D. MacEachern <craig.daniel.maceachern@gmail.com>
      8 "			Tyler Miller <tmillr@proton.me>
      9 "			Phạm Bình An <phambinhanctb2004@gmail.com>
     10 "			@konfekt
     11 " Last Change:		2026 Jun 20
     12 
     13 if exists("b:did_ftplugin")
     14   finish
     15 endif
     16 let b:did_ftplugin = 1
     17 
     18 " keep in sync with syntax/lua.vim
     19 if !exists("lua_version")
     20   " Default is lua 5.3
     21   let lua_version = 5
     22   let lua_subversion = 3
     23 elseif !exists("lua_subversion")
     24   " lua_version exists, but lua_subversion doesn't. In this case set it to 0
     25   let lua_subversion = 0
     26 endif
     27 
     28 let s:cpo_save = &cpo
     29 set cpo&vim
     30 
     31 setlocal comments=:---,:--
     32 setlocal commentstring=--\ %s
     33 setlocal formatoptions-=t formatoptions+=croql
     34 setlocal path-=. " Lua doesn't support importing module in path related to current file like JS
     35 
     36 let &l:define = '\<function\|\<local\%(\s\+function\)\='
     37 
     38 let &l:include = '\<\%(\%(do\|load\)file\|require\)\s*('
     39 setlocal includeexpr=s:LuaInclude(v:fname)
     40 setlocal suffixesadd=.lua
     41 
     42 let b:undo_ftplugin = "setl cms< com< def< fo< inc< inex< sua< pa<"
     43 
     44 if exists("loaded_matchit") && !exists("b:match_words")
     45   let b:match_ignorecase = 0
     46   let b:match_words =
     47 	\ '\<\%(do\|function\|if\)\>:' ..
     48 	\ '\<\%(return\|else\|elseif\)\>:' ..
     49 	\ '\<end\>,' ..
     50 	\ '\<repeat\>:\<until\>,' ..
     51 	\ '--\[\(=*\)\[:\%(--\)\=]\1]'
     52   let b:undo_ftplugin ..= " | unlet! b:match_words b:match_ignorecase"
     53 endif
     54 
     55 if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
     56   let b:browsefilter = "Lua Source Files (*.lua)\t*.lua\n"
     57   if has("win32")
     58     let b:browsefilter ..= "All Files (*.*)\t*\n"
     59   else
     60     let b:browsefilter ..= "All Files (*)\t*\n"
     61   endif
     62   let b:undo_ftplugin ..= " | unlet! b:browsefilter"
     63 endif
     64 
     65 if has("folding") && get(g:, "lua_folding", 0)
     66   setlocal foldmethod=expr
     67   setlocal foldexpr=s:LuaFold()
     68   let b:lua_lasttick = -1
     69   let b:undo_ftplugin ..= " | setl foldexpr< foldmethod< | unlet! b:lua_lasttick b:lua_foldlists"
     70 endif
     71 
     72 " The rest of the file needs to be :sourced only once per Vim session
     73 if exists("s:loaded_lua") || &cp
     74   let &cpo = s:cpo_save
     75   unlet s:cpo_save
     76   finish
     77 endif
     78 let s:loaded_lua = 1
     79 
     80 function s:LuaInclude(fname) abort
     81   let lua_ver = str2float(printf("%d.%02d", g:lua_version, g:lua_subversion))
     82   let fname = tr(a:fname, '.', '/')
     83   let paths = lua_ver >= 5.03 ? [fname .. ".lua", fname .. "/init.lua"] : [fname .. ".lua"]
     84   for path in paths
     85     if filereadable(path)
     86       return path
     87     endif
     88   endfor
     89   return fname
     90 endfunction
     91 
     92 let s:patterns = [
     93       \ ['do', 'end'],
     94       \ ['if\s+.+\s+then', 'end'],
     95       \ ['repeat', 'until\s+.+'],
     96       \ ['for\s+.+\s+do', 'end'],
     97       \ ['while\s+.+\s+do', 'end'],
     98       \ ['function.+', 'end'],
     99       \ ['return\s+function.+', 'end'],
    100       \ ['local\s+function\s+.+', 'end'],
    101       \ ]
    102 
    103 function s:LuaFold() abort
    104   if b:lua_lasttick == b:changedtick
    105     return b:lua_foldlists[v:lnum - 1]
    106   endif
    107   let b:lua_lasttick = b:changedtick
    108 
    109   let b:lua_foldlists = []
    110   let foldlist = []
    111   let buf = getline(1, "$")
    112   for line in buf
    113     for t in s:patterns
    114       let open = 0
    115       let end = 0
    116       let tagopen  = '\v^\s*' .. t[0] ..'\s*$'
    117       let tagend = '\v^\s*' .. t[1] ..'\s*$'
    118       if line =~# tagopen
    119 	call add(foldlist, t)
    120 	let open = 1
    121 	break
    122       elseif line =~# tagend
    123 	if len(foldlist) > 0 && line =~# foldlist[-1][1]
    124 	  call remove(foldlist, -1)
    125 	  let end = 1
    126 	else
    127 	  let foldlist = []
    128 	endif
    129 	break
    130       endif
    131     endfor
    132     let prefix = ""
    133     if open == 1 | let prefix = ">" | endif
    134     if end == 1 | let prefix = "<" | endif
    135     let b:lua_foldlists += [prefix..(len(foldlist) + end)]
    136   endfor
    137 
    138   return b:lua_foldlists[v:lnum - 1]
    139 endfunction
    140 
    141 if !has('vim9script')
    142   let &cpo = s:cpo_save
    143   unlet s:cpo_save
    144 
    145   finish
    146 endif
    147 
    148 delfunction! s:LuaFold
    149 def s:LuaFold(): string
    150   if b:lua_lasttick == b:changedtick
    151     return b:lua_foldlists[v:lnum - 1]
    152   endif
    153   b:lua_lasttick = b:changedtick
    154 
    155   b:lua_foldlists = []
    156   var foldlist = []
    157   var buf = getline(1, "$")
    158   for line in buf
    159     var open = 0
    160     var end = 0
    161     for t in patterns
    162       var tagopen  = '\v^\s*' .. t[0] .. '\s*$'
    163       var tagend = '\v^\s*' .. t[1] .. '\s*$'
    164       if line =~# tagopen
    165 	add(foldlist, t)
    166 	open = 1
    167 	break
    168       elseif line =~# tagend
    169 	if len(foldlist) > 0 && line =~# foldlist[-1][1]
    170 	  end = 1
    171 	  remove(foldlist, -1)
    172 	else
    173 	  foldlist = []
    174 	endif
    175 	break
    176       endif
    177     endfor
    178     var prefix = ""
    179     if open == 1 | prefix = ">" | endif
    180     if end == 1 | prefix = "<" | endif
    181     b:lua_foldlists += [prefix .. (len(foldlist) + end)]
    182   endfor
    183   return b:lua_foldlists[v:lnum - 1]
    184 enddef
    185 
    186 let &cpo = s:cpo_save
    187 unlet s:cpo_save
    188 
    189 " vim: nowrap sw=2 sts=2 ts=8 noet: