vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

gdscript.vim (1968B)


      1 vim9script
      2 
      3 # Vim filetype plugin file
      4 # Language: gdscript (Godot game engine scripting language)
      5 # Maintainer: Maxim Kim <habamax@gmail.com>
      6 # Website: https://github.com/habamax/vim-gdscript
      7 # Last Change: 2024 Jul 14
      8 #              2026 Jun 27 by Vim Project (normalize recommended style guard)
      9 
     10 if exists("b:did_ftplugin") | finish | endif
     11 
     12 b:did_ftplugin = 1
     13 b:undo_ftplugin = 'setlocal cinkeys<'
     14       \ .. '| setlocal indentkeys<'
     15       \ .. '| setlocal commentstring<'
     16       \ .. '| setlocal suffixesadd<'
     17       \ .. '| setlocal foldexpr<'
     18       \ .. '| setlocal foldignore<'
     19 
     20 setlocal cinkeys-=0#
     21 setlocal indentkeys-=0#
     22 setlocal suffixesadd=.gd
     23 setlocal commentstring=#\ %s
     24 setlocal foldignore=
     25 setlocal foldexpr=GDScriptFoldLevel()
     26 
     27 if get(g:, 'gdscript_recommended_style', get(g:, 'filetype_recommended_style', 1))
     28     setlocal noexpandtab tabstop=4 softtabstop=0 shiftwidth=0
     29     b:undo_ftplugin ..= ' | setlocal expandtab< tabstop< softtabstop< shiftwidth<'
     30 endif
     31 
     32 
     33 def GDScriptFoldLevel(): string
     34     var line = getline(v:lnum)
     35     if line =~? '^\s*$'
     36         return "-1"
     37     endif
     38 
     39     var sw = shiftwidth()
     40     var indent = indent(v:lnum) / sw
     41     var indent_next = indent(nextnonblank(v:lnum + 1)) / sw
     42 
     43     if indent_next > indent && line =~ ':\s*$'
     44         return $">{indent_next}"
     45     else
     46         return $"{indent}"
     47     endif
     48 enddef
     49 
     50 
     51 if !exists("g:no_plugin_maps")
     52     # Next/Previous section
     53     def NextSection(back: bool, cnt: number)
     54         for n in range(cnt)
     55             search('^\s*func\s', back ? 'bW' : 'W')
     56         endfor
     57     enddef
     58 
     59     nnoremap <silent><buffer> ]] <scriptcmd>NextSection(false, v:count1)<CR>
     60     nnoremap <silent><buffer> [[ <scriptcmd>NextSection(true, v:count1)<CR>
     61     xmap <buffer><expr> ]] $'<C-\><C-N>{v:count1}]]m>gv'
     62     xmap <buffer><expr> [[ $'<C-\><C-N>{v:count1}[[m>gv'
     63     b:undo_ftplugin ..=
     64           \    " | silent exe 'unmap <buffer> [['"
     65           \ .. " | silent exe 'unmap <buffer> ]]'"
     66 endif