vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

sign.txt (27653B)


      1 *sign.txt*	For Vim version 9.2.  Last change: 2026 Aug 23
      2 
      3 
      4 		  VIM REFERENCE MANUAL	  by Gordon Prieur
      5 					  and Bram Moolenaar
      6 
      7 
      8 Sign Support Features				*sign-support*
      9 
     10 1. Introduction				|sign-intro|
     11 2. Commands				|sign-commands|
     12 3. Functions				|sign-functions-details|
     13 
     14 {only available when compiled with the |+signs| feature}
     15 
     16 ==============================================================================
     17 1. Introduction					*sign-intro* *signs*
     18 
     19 When a debugger or other IDE tool is driving an editor it needs to be able
     20 to give specific highlights which quickly tell the user useful information
     21 about the file.  One example of this would be a debugger which had an icon
     22 in the left-hand column denoting a breakpoint.  Another example might be an
     23 arrow representing the Program Counter (PC).  The sign features allow both
     24 placement of a sign, or icon, in the left-hand side of the window and
     25 definition of a highlight which will be applied to that line.  Displaying the
     26 sign as an image is most likely only feasible in gvim (although Sun
     27 Microsystem's dtterm does support this it's the only terminal emulator I know
     28 of which does).  A text sign and the highlight should be feasible in any color
     29 terminal emulator.
     30 
     31 Signs and highlights are not useful just for debuggers.  Sun's Visual
     32 WorkShop uses signs and highlights to mark build errors and SourceBrowser
     33 hits.  Additionally, the debugger supports 8 to 10 different signs and
     34 highlight colors, see |NetBeans|.
     35 
     36 There are two steps in using signs:
     37 
     38 1. Define the sign.  This specifies the image, text and highlighting.  For
     39    example, you can define a "break" sign with an image of a stop roadsign and
     40    text "!!".
     41 
     42 2. Place the sign.  This specifies the file and line number where the sign is
     43    displayed.  A defined sign can be placed several times in different lines
     44    and files.
     45 
     46 							*sign-column*
     47 When signs are defined for a file, Vim will automatically add a column of two
     48 characters to display them in.  When the last sign is unplaced the column
     49 disappears again.  This behavior can be changed with the 'signcolumn' option.
     50 
     51 The color of the column is set with the SignColumn highlight group
     52 |hl-SignColumn|.  Example to set the color: >
     53 
     54 	:highlight SignColumn guibg=darkgrey
     55 <
     56 If 'cursorline' is enabled, then the CursorLineSign highlight group is used
     57 |hl-CursorLineSign|.
     58 							*sign-identifier*
     59 Each placed sign is identified by a number called the sign identifier.  This
     60 identifier is used to jump to the sign or to remove the sign.  The identifier
     61 is assigned when placing the sign using the |:sign-place| command or the
     62 |sign_place()| function.  Each sign identifier should be a unique number.  If
     63 multiple placed signs use the same identifier, then jumping to or removing a
     64 sign becomes unpredictable.  To avoid overlapping identifiers, sign groups can
     65 be used.  The |sign_place()| function can be called with a zero sign identifier
     66 to allocate the next available identifier.
     67 
     68 							*sign-group*
     69 Each placed sign can be assigned to either the global group or a named group.
     70 When placing a sign, if a group name is not supplied, or an empty string is
     71 used, then the sign is placed in the global group.  Otherwise the sign is
     72 placed in the named group.  The sign identifier is unique within a group.  The
     73 sign group allows Vim plugins to use unique signs without interfering with
     74 other plugins using signs.
     75 
     76 To place a sign in a popup window the group name must start with "PopUp".
     77 Other signs will not show in a popup window.  The group name "PopUpMenu" is
     78 used by popup windows where 'cursorline' is set.
     79 
     80 							*sign-priority*
     81 Each placed sign is assigned a priority value.  When multiple signs are placed
     82 on the same line, the attributes of the sign with the highest priority is used
     83 independently of the sign group.  The default priority for a sign is 10, this
     84 value can be changed for different signs by specifying a different value at
     85 definition time.  The priority is assigned at the time of placing a sign.
     86 
     87 When two signs with the same priority are present, and one has an icon or text
     88 in the signcolumn while the other has line highlighting, then both are
     89 displayed.
     90 
     91 When the line on which the sign is placed is deleted, the sign is moved to the
     92 next line (or the last line of the buffer, if there is no next line).  When
     93 the delete is undone the sign does not move back.
     94 
     95 When a sign with line highlighting and 'cursorline' highlighting are both
     96 present, if the priority is 100 or more then the sign highlighting takes
     97 precedence, otherwise the 'cursorline' highlighting.
     98 
     99 ==============================================================================
    100 2. Commands					*sign-commands* *:sig* *:sign*
    101 
    102 Here is an example that places a sign "piet", displayed with the text ">>", in
    103 line 23 of the current file: >
    104 	:sign define piet text=>> texthl=Search
    105 	:exe ":sign place 2 line=23 name=piet file=" .. expand("%:p")
    106 
    107 And here is the command to delete it again: >
    108 	:sign unplace 2
    109 
    110 Note that the ":sign" command cannot be followed by another command or a
    111 comment.  If you do need that, use the |:execute| command.
    112 
    113 
    114 DEFINING A SIGN.			*:sign-define* *E255* *E160* *E612*
    115 
    116 See |sign_define()| for the equivalent Vim script function.
    117 
    118 :sig[n] define {name} {argument}...
    119 		Define a new sign or set attributes for an existing sign.
    120 		The {name} can either be a number (all digits) or a name
    121 		starting with a non-digit.  Leading zeros are ignored, thus
    122 		"0012", "012" and "12" are considered the same name.
    123 		About 120 different signs can be defined.
    124 
    125 		Accepted arguments:
    126 
    127 	icon={bitmap}
    128 		Define the file name where the bitmap can be found.  Should be
    129 		a full path.  The bitmap should fit in the place of two
    130 		characters.  This is not checked.  If the bitmap is too big it
    131 		will cause redraw problems.  Only GTK 2 can scale the bitmap
    132 		to fit the space available.
    133 			toolkit		supports ~
    134 			GTK 1		pixmap (.xpm)
    135 			GTK 2		many
    136 			Motif		pixmap (.xpm)
    137 			Win32		.bmp, .ico, .cur
    138 					pixmap (.xpm) |+xpm_w32|
    139 	priority={prio}
    140 		Default priority for the sign, see |sign-priority|.
    141 
    142 	linehl={group}
    143 		Highlighting group used for the whole line the sign is placed
    144 		in.  Most useful is defining a background color.
    145 
    146 	numhl={group}
    147 		Highlighting group used for the line number on the line where
    148 		the sign is placed.  Overrides |hl-LineNr|, |hl-LineNrAbove|,
    149 		|hl-LineNrBelow|, and |hl-CursorLineNr|.
    150 
    151 	text={text}						*E239*
    152 		Define the text that is displayed when there is no icon or the
    153 		GUI is not being used.  Only printable characters are allowed
    154 		and they must occupy one or two display cells.
    155 
    156 	texthl={group}
    157 		Highlighting group used for the text item.
    158 
    159 	culhl={group}
    160 		Highlighting group used for the text item when the cursor is
    161 		on the same line as the sign and 'cursorline' is enabled.
    162 
    163 	Example: >
    164 		:sign define MySign text=>> texthl=Search linehl=DiffText
    165 <
    166 
    167 DELETING A SIGN						*:sign-undefine* *E155*
    168 
    169 See |sign_undefine()| for the equivalent Vim script function.
    170 
    171 :sig[n] undefine {name}
    172 		Deletes a previously defined sign.  If signs with this {name}
    173 		are still placed this will cause trouble.
    174 
    175 		Example: >
    176 			:sign undefine MySign
    177 <
    178 
    179 LISTING SIGNS						*:sign-list* *E156*
    180 
    181 See |sign_getdefined()| for the equivalent Vim script function.
    182 
    183 :sig[n] list	Lists all defined signs and their attributes.
    184 
    185 :sig[n] list {name}
    186 		Lists one defined sign and its attributes.
    187 
    188 
    189 PLACING SIGNS						*:sign-place* *E158*
    190 
    191 See |sign_place()| for the equivalent Vim script function.
    192 
    193 :sig[n] place {id} line={lnum} name={name} file={fname}
    194 		Place sign defined as {name} at line {lnum} in file {fname}.
    195 							*:sign-fname*
    196 		The file {fname} must already be loaded in a buffer.  The
    197 		exact file name must be used, wildcards, $ENV and ~ are not
    198 		expanded, white space must not be escaped.  Trailing white
    199 		space is ignored.
    200 
    201 		The sign is remembered under {id}, this can be used for
    202 		further manipulation.  {id} must be a number.
    203 		It's up to the user to make sure the {id} is used only once in
    204 		each file (if it's used several times unplacing will also have
    205 		to be done several times and making changes may not work as
    206 		expected).
    207 
    208 		The following optional sign attributes can be specified before
    209 		"file=":
    210 			group={group}	Place sign in sign group {group}
    211 			priority={prio}	Assign priority {prio} to sign
    212 
    213 		By default, the sign is placed in the global sign group.
    214 
    215 		By default, the sign is assigned a default priority of 10,
    216 		unless specified otherwise by the sign definition.  To assign
    217 		a different priority value, use "priority={prio}" to specify a
    218 		value.  The priority is used to determine the sign that is
    219 		displayed when multiple signs are placed on the same line.
    220 
    221 		Examples: >
    222 			:sign place 5 line=3 name=sign1 file=a.py
    223 			:sign place 6 group=g2 line=2 name=sign2 file=x.py
    224 			:sign place 9 group=g2 priority=50 line=5
    225 							\ name=sign1 file=a.py
    226 <
    227 :sig[n] place {id} line={lnum} name={name} [buffer={nr}]
    228 		Same, but use buffer {nr}.  If the buffer argument is not
    229 		given, place the sign in the current buffer.
    230 
    231 		Example: >
    232 			:sign place 10 line=99 name=sign3
    233 			:sign place 10 line=99 name=sign3 buffer=3
    234 <
    235 							*E885*
    236 :sig[n] place {id} name={name} file={fname}
    237 		Change the placed sign {id} in file {fname} to use the defined
    238 		sign {name}.  See remark above about {fname} |:sign-fname|.
    239 		This can be used to change the displayed sign without moving
    240 		it (e.g., when the debugger has stopped at a breakpoint).
    241 
    242 		The optional "group={group}" attribute can be used before
    243 		"file=" to select a sign in a particular group.  The optional
    244 		"priority={prio}" attribute can be used to change the priority
    245 		of an existing sign.
    246 
    247 		Example: >
    248 			:sign place 23 name=sign1 file=/path/to/edit.py
    249 <
    250 :sig[n] place {id} name={name} [buffer={nr}]
    251 		Same, but use buffer {nr}.  If the buffer argument is not
    252 		given, use the current buffer.
    253 
    254 		Example: >
    255 			:sign place 23 name=sign1
    256 			:sign place 23 name=sign1 buffer=7
    257 <
    258 
    259 REMOVING SIGNS						*:sign-unplace* *E159*
    260 
    261 See |sign_unplace()| for the equivalent Vim script function.
    262 
    263 :sig[n] unplace {id} file={fname}
    264 		Remove the previously placed sign {id} from file {fname}.
    265 		See remark above about {fname} |:sign-fname|.
    266 
    267 :sig[n] unplace {id} group={group} file={fname}
    268 		Same but remove the sign {id} in sign group {group}.
    269 
    270 :sig[n] unplace {id} group=* file={fname}
    271 		Same but remove the sign {id} from all the sign groups.
    272 
    273 :sig[n] unplace * file={fname}
    274 		Remove all placed signs in file {fname}.
    275 
    276 :sig[n] unplace * group={group} file={fname}
    277 		Remove all placed signs in group {group} from file {fname}.
    278 
    279 :sig[n] unplace * group=* file={fname}
    280 		Remove all placed signs in all the groups from file {fname}.
    281 
    282 :sig[n] unplace {id} buffer={nr}
    283 		Remove the previously placed sign {id} from buffer {nr}.
    284 
    285 :sig[n] unplace {id} group={group} buffer={nr}
    286 		Remove the previously placed sign {id} in group {group} from
    287 		buffer {nr}.
    288 
    289 :sig[n] unplace {id} group=* buffer={nr}
    290 		Remove the previously placed sign {id} in all the groups from
    291 		buffer {nr}.
    292 
    293 :sig[n] unplace * buffer={nr}
    294 		Remove all placed signs in buffer {nr}.
    295 
    296 :sig[n] unplace * group={group} buffer={nr}
    297 		Remove all placed signs in group {group} from buffer {nr}.
    298 
    299 :sig[n] unplace * group=* buffer={nr}
    300 		Remove all placed signs in all the groups from buffer {nr}.
    301 
    302 :sig[n] unplace {id}
    303 		Remove the previously placed sign {id} from all files it
    304 		appears in.
    305 
    306 :sig[n] unplace {id} group={group}
    307 		Remove the previously placed sign {id} in group {group} from
    308 		all files it appears in.
    309 
    310 :sig[n] unplace {id} group=*
    311 		Remove the previously placed sign {id} in all the groups from
    312 		all the files it appears in.
    313 
    314 :sig[n] unplace *
    315 		Remove all placed signs in the global group from all the
    316 		files.
    317 
    318 :sig[n] unplace * group={group}
    319 		Remove all placed signs in group {group} from all the files.
    320 
    321 :sig[n] unplace * group=*
    322 		Remove all placed signs in all the groups from all the files.
    323 
    324 :sig[n] unplace
    325 		Remove a placed sign at the cursor position.  If multiple
    326 		signs are placed in the line, then only one is removed.
    327 
    328 :sig[n] unplace group={group}
    329 		Remove a placed sign in group {group} at the cursor
    330 		position.
    331 
    332 :sig[n] unplace group=*
    333 		Remove a placed sign in any group at the cursor position.
    334 
    335 
    336 LISTING PLACED SIGNS					*:sign-place-list*
    337 
    338 See |sign_getplaced()| for the equivalent Vim script function.
    339 
    340 :sig[n] place file={fname}
    341 		List signs placed in file {fname}.
    342 		See remark above about {fname} |:sign-fname|.
    343 
    344 :sig[n] place group={group} file={fname}
    345 		List signs in group {group} placed in file {fname}.
    346 
    347 :sig[n] place group=* file={fname}
    348 		List signs in all the groups placed in file {fname}.
    349 
    350 :sig[n] place buffer={nr}
    351 		List signs placed in buffer {nr}.
    352 
    353 :sig[n] place group={group} buffer={nr}
    354 		List signs in group {group} placed in buffer {nr}.
    355 
    356 :sig[n] place group=* buffer={nr}
    357 		List signs in all the groups placed in buffer {nr}.
    358 
    359 :sig[n] place	List placed signs in the global group in all files.
    360 
    361 :sig[n] place group={group}
    362 		List placed signs with sign group {group} in all files.
    363 
    364 :sig[n] place group=*
    365 		List placed signs in all sign groups in all files.
    366 
    367 
    368 JUMPING TO A SIGN					*:sign-jump* *E157*
    369 
    370 See |sign_jump()| for the equivalent Vim script function.
    371 
    372 :sig[n] jump {id} file={fname}
    373 		Open the file {fname} or jump to the window that contains
    374 		{fname} and position the cursor at sign {id}.
    375 		See remark above about {fname} |:sign-fname|.
    376 		If the file isn't displayed in window and the current file can
    377 		not be |abandon|ed this fails.
    378 
    379 :sig[n] jump {id} group={group} file={fname}
    380 		Same but jump to the sign in group {group}
    381 
    382 :sig[n] jump {id} [buffer={nr}]				*E934*
    383 		Same, but use buffer {nr}.  This fails if buffer {nr} does not
    384 		have a name.  If the buffer argument is not given, use the
    385 		current buffer.
    386 
    387 :sig[n] jump {id} group={group} [buffer={nr}]
    388 		Same but jump to the sign in group {group}
    389 
    390 
    391 ==============================================================================
    392 3. Functions					*sign-functions-details*
    393 
    394 sign_define({name} [, {dict}])				*sign_define()*
    395 sign_define({list})
    396 		Define a new sign named {name} or modify the attributes of an
    397 		existing sign.  This is similar to the |:sign-define| command.
    398 
    399 		Prefix {name} with a unique text to avoid name collisions.
    400 		There is no {group} like with placing signs.
    401 
    402 		The {name} can be a String or a Number.  The optional {dict}
    403 		argument specifies the sign attributes.  The following values
    404 		are supported:
    405 		   icon		full path to the bitmap file for the sign.
    406 		   linehl	highlight group used for the whole line the
    407 				sign is placed in.
    408 		   priority	default priority value of the sign
    409 		   numhl	highlight group used for the line number where
    410 				the sign is placed.
    411 		   text		text that is displayed when there is no icon
    412 				or the GUI is not being used.
    413 		   texthl	highlight group used for the text item
    414 		   culhl	highlight group used for the text item when
    415 				the cursor is on the same line as the sign and
    416 				'cursorline' is enabled.
    417 
    418 		If the sign named {name} already exists, then the attributes
    419 		of the sign are updated.
    420 
    421 		The one argument {list} can be used to define a list of signs.
    422 		Each list item is a dictionary with the above items in {dict}
    423 		and a "name" item for the sign name.
    424 
    425 		Returns 0 on success and -1 on failure.  When the one argument
    426 		{list} is used, then returns a List of values one for each
    427 		defined sign.
    428 
    429 		Examples: >
    430 			call sign_define("mySign", {
    431 				\ "text" : "=>",
    432 				\ "texthl" : "Error",
    433 				\ "linehl" : "Search"})
    434 			call sign_define([
    435 				\ {'name' : 'sign1',
    436 				\  'text' : '=>'},
    437 				\ {'name' : 'sign2',
    438 				\  'text' : '!!'}
    439 				\ ])
    440 <
    441 		Can also be used as a |method|: >
    442 			GetSignList()->sign_define()
    443 <
    444 		Return type: |Number|
    445 
    446 
    447 sign_getdefined([{name}])				*sign_getdefined()*
    448 		Get a list of defined signs and their attributes.
    449 		This is similar to the |:sign-list| command.
    450 
    451 		If the {name} is not supplied, then a list of all the defined
    452 		signs is returned.  Otherwise the attribute of the specified
    453 		sign is returned.
    454 
    455 		Each list item in the returned value is a dictionary with the
    456 		following entries:
    457 		   icon		full path to the bitmap file of the sign
    458 		   linehl	highlight group used for the whole line the
    459 				sign is placed in; not present if not set
    460 		   name		name of the sign
    461 		   priority	default priority value of the sign
    462 		   numhl	highlight group used for the line number where
    463 				the sign is placed; not present if not set
    464 		   text		text that is displayed when there is no icon
    465 				or the GUI is not being used.
    466 		   texthl	highlight group used for the text item; not
    467 				present if not set
    468 		   culhl	highlight group used for the text item when
    469 				the cursor is on the same line as the sign and
    470 				'cursorline' is enabled; not present if not
    471 				set
    472 
    473 		Returns an empty List if there are no signs and when {name} is
    474 		not found.
    475 
    476 		Examples: >
    477 			" Get a list of all the defined signs
    478 			echo sign_getdefined()
    479 
    480 			" Get the attribute of the sign named mySign
    481 			echo sign_getdefined("mySign")
    482 <
    483 		Can also be used as a |method|: >
    484 			GetSignList()->sign_getdefined()
    485 <
    486 		Return type: list<dict<string>> or list<any>
    487 
    488 
    489 sign_getplaced([{buf} [, {dict}]])			*sign_getplaced()*
    490 		Return a list of signs placed in a buffer or all the buffers.
    491 		This is similar to the |:sign-place-list| command.
    492 
    493 		If the optional buffer name {buf} is specified, then only the
    494 		list of signs placed in that buffer is returned.  For the use
    495 		of {buf}, see |bufname()|.  The optional {dict} can contain
    496 		the following entries:
    497 		   group	select only signs in this group
    498 		   id		select sign with this identifier
    499 		   lnum		select signs placed in this line.  For the use
    500 				of {lnum}, see |line()|.
    501 		If {group} is '*', then signs in all the groups including the
    502 		global group are returned.  If {group} is not supplied or is
    503 		an empty string, then only signs in the global group are
    504 		returned.  If no arguments are supplied, then signs in the
    505 		global group placed in all the buffers are returned.
    506 		See |sign-group|.
    507 
    508 		Each list item in the returned value is a dictionary with the
    509 		following entries:
    510 			bufnr	number of the buffer with the sign
    511 			signs	list of signs placed in {bufnr}.  Each list
    512 				item is a dictionary with the below listed
    513 				entries
    514 
    515 		The dictionary for each sign contains the following entries:
    516 			group	 sign group.  Set to '' for the global group.
    517 			id	 identifier of the sign
    518 			lnum	 line number where the sign is placed
    519 			name	 name of the defined sign
    520 			priority sign priority
    521 
    522 		The returned signs in a buffer are ordered by their line
    523 		number and priority.
    524 
    525 		Returns an empty list on failure or if there are no placed
    526 		signs.
    527 
    528 		Examples: >
    529 			" Get a List of signs placed in eval.c in the
    530 			" global group
    531 			echo sign_getplaced("eval.c")
    532 
    533 			" Get a List of signs in group 'g1' placed in eval.c
    534 			echo sign_getplaced("eval.c", {'group' : 'g1'})
    535 
    536 			" Get a List of signs placed at line 10 in eval.c
    537 			echo sign_getplaced("eval.c", {'lnum' : 10})
    538 
    539 			" Get sign with identifier 10 placed in a.py
    540 			echo sign_getplaced("a.py", {'id' : 10})
    541 
    542 			" Get sign with id 20 in group 'g1' placed in a.py
    543 			echo sign_getplaced("a.py", {'group' : 'g1',
    544 							\  'id' : 20})
    545 
    546 			" Get a List of all the placed signs
    547 			echo sign_getplaced()
    548 <
    549 		Can also be used as a |method|: >
    550 			GetBufname()->sign_getplaced()
    551 <
    552 		Return type: list<dict<any>>
    553 
    554 
    555 sign_jump({id}, {group}, {buf})				*sign_jump()*
    556 		Open the buffer {buf} or jump to the window that contains
    557 		{buf} and position the cursor at sign {id} in group {group}.
    558 		This is similar to the |:sign-jump| command.
    559 
    560 		If {group} is an empty string, then the global group is used.
    561 		For the use of {buf}, see |bufname()|.
    562 
    563 		Returns the line number of the sign.  Returns -1 if the
    564 		arguments are invalid.
    565 
    566 		Example: >
    567 			" Jump to sign 10 in the current buffer
    568 			call sign_jump(10, '', '')
    569 <
    570 		Can also be used as a |method|: >
    571 			GetSignid()->sign_jump()
    572 <
    573 		Return type: |Number|
    574 
    575 
    576 							*sign_place()*
    577 sign_place({id}, {group}, {name}, {buf} [, {dict}])
    578 		Place the sign defined as {name} at line {lnum} in file or
    579 		buffer {buf} and assign {id} and {group} to sign.  This is
    580 		similar to the |:sign-place| command.
    581 
    582 		If the sign identifier {id} is zero, then a new identifier is
    583 		allocated.  Otherwise the specified number is used.  {group}
    584 		is the sign group name.  To use the global sign group, use an
    585 		empty string.  {group} functions as a namespace for {id}, thus
    586 		two groups can use the same IDs.  Refer to |sign-identifier|
    587 		and |sign-group| for more information.
    588 
    589 		{name} refers to a defined sign.
    590 		{buf} refers to a buffer name or number.  For the accepted
    591 		values, see |bufname()|.
    592 
    593 		The optional {dict} argument supports the following entries:
    594 			lnum		line number in the file or buffer
    595 					{buf} where the sign is to be placed.
    596 					For the accepted values, see |line()|.
    597 			priority	priority of the sign.  See
    598 					|sign-priority| for more information.
    599 
    600 		If the optional {dict} is not specified, then it modifies the
    601 		placed sign {id} in group {group} to use the defined sign
    602 		{name}.
    603 
    604 		Returns the sign identifier on success and -1 on failure.
    605 
    606 		Examples: >
    607 			" Place a sign named sign1 with id 5 at line 20 in
    608 			" buffer json.c
    609 			call sign_place(5, '', 'sign1', 'json.c',
    610 							\ {'lnum' : 20})
    611 
    612 			" Updates sign 5 in buffer json.c to use sign2
    613 			call sign_place(5, '', 'sign2', 'json.c')
    614 
    615 			" Place a sign named sign3 at line 30 in
    616 			" buffer json.c with a new identifier
    617 			let id = sign_place(0, '', 'sign3', 'json.c',
    618 							\ {'lnum' : 30})
    619 
    620 			" Place a sign named sign4 with id 10 in group 'g3'
    621 			" at line 40 in buffer json.c with priority 90
    622 			call sign_place(10, 'g3', 'sign4', 'json.c',
    623 					\ {'lnum' : 40, 'priority' : 90})
    624 <
    625 		Can also be used as a |method|: >
    626 			GetSignid()->sign_place(group, name, expr)
    627 <
    628 		Return type: |Number|
    629 
    630 
    631 sign_placelist({list})				*sign_placelist()*
    632 		Place one or more signs.  This is similar to the
    633 		|sign_place()| function.  The {list} argument specifies the
    634 		List of signs to place.  Each list item is a dict with the
    635 		following sign attributes:
    636 		    buffer	Buffer name or number.  For the accepted
    637 				values, see |bufname()|.
    638 		    group	Sign group.  {group} functions as a namespace
    639 				for {id}, thus two groups can use the same
    640 				IDs.  If not specified or set to an empty
    641 				string, then the global group is used.   See
    642 				|sign-group| for more information.
    643 		    id		Sign identifier.  If not specified or zero,
    644 				then a new unique identifier is allocated.
    645 				Otherwise the specified number is used.  See
    646 				|sign-identifier| for more information.
    647 		    lnum	Line number in the buffer where the sign is to
    648 				be placed.  For the accepted values, see
    649 				|line()|.
    650 		    name	Name of the sign to place.  See |sign_define()|
    651 				for more information.
    652 		    priority	Priority of the sign.  When multiple signs are
    653 				placed on a line, the sign with the highest
    654 				priority is used.  If not specified, the
    655 				default value of 10 is used, unless specified
    656 				otherwise by the sign definition.  See
    657 				|sign-priority| for more information.
    658 
    659 		If {id} refers to an existing sign, then the existing sign is
    660 		modified to use the specified {name} and/or {priority}.
    661 
    662 		Returns a List of sign identifiers.  If failed to place a
    663 		sign, the corresponding list item is set to -1.
    664 
    665 		Examples: >
    666 			" Place sign s1 with id 5 at line 20 and id 10 at line
    667 			" 30 in buffer a.c
    668 			let [n1, n2] = sign_placelist([
    669 				\ {'id' : 5,
    670 				\  'name' : 's1',
    671 				\  'buffer' : 'a.c',
    672 				\  'lnum' : 20},
    673 				\ {'id' : 10,
    674 				\  'name' : 's1',
    675 				\  'buffer' : 'a.c',
    676 				\  'lnum' : 30}
    677 				\ ])
    678 
    679 			" Place sign s1 in buffer a.c at line 40 and 50
    680 			" with auto-generated identifiers
    681 			let [n1, n2] = sign_placelist([
    682 				\ {'name' : 's1',
    683 				\  'buffer' : 'a.c',
    684 				\  'lnum' : 40},
    685 				\ {'name' : 's1',
    686 				\  'buffer' : 'a.c',
    687 				\  'lnum' : 50}
    688 				\ ])
    689 <
    690 		Can also be used as a |method|: >
    691 			GetSignlist()->sign_placelist()
    692 <
    693 		Return type: list<number> or list<any>
    694 
    695 
    696 sign_undefine([{name}])					*sign_undefine()*
    697 sign_undefine({list})
    698 		Deletes a previously defined sign {name}.  This is similar to
    699 		the |:sign-undefine| command.  If {name} is not supplied, then
    700 		deletes all the defined signs.
    701 
    702 		The one argument {list} can be used to undefine a list of
    703 		signs.  Each list item is the name of a sign.
    704 
    705 		Returns 0 on success and -1 on failure.  For the one argument
    706 		{list} call, returns a list of values one for each undefined
    707 		sign.
    708 
    709 		Examples: >
    710 			" Delete a sign named mySign
    711 			call sign_undefine("mySign")
    712 
    713 			" Delete signs 'sign1' and 'sign2'
    714 			call sign_undefine(["sign1", "sign2"])
    715 
    716 			" Delete all the signs
    717 			call sign_undefine()
    718 <
    719 		Can also be used as a |method|: >
    720 			GetSignlist()->sign_undefine()
    721 <
    722 		Return type: |Number|
    723 
    724 
    725 sign_unplace({group} [, {dict}])			*sign_unplace()*
    726 		Remove a previously placed sign in one or more buffers.  This
    727 		is similar to the |:sign-unplace| command.
    728 
    729 		{group} is the sign group name.  To use the global sign group,
    730 		use an empty string.  If {group} is set to '*', then all the
    731 		groups including the global group are used.
    732 		The signs in {group} are selected based on the entries in
    733 		{dict}.  The following optional entries in {dict} are
    734 		supported:
    735 			buffer	buffer name or number.  See |bufname()|.
    736 			id	sign identifier
    737 		If {dict} is not supplied, then all the signs in {group} are
    738 		removed.
    739 
    740 		Returns 0 on success and -1 on failure.
    741 
    742 		Examples: >
    743 			" Remove sign 10 from buffer a.vim
    744 			call sign_unplace('', {'buffer' : "a.vim", 'id' : 10})
    745 
    746 			" Remove sign 20 in group 'g1' from buffer 3
    747 			call sign_unplace('g1', {'buffer' : 3, 'id' : 20})
    748 
    749 			" Remove all the signs in group 'g2' from buffer 10
    750 			call sign_unplace('g2', {'buffer' : 10})
    751 
    752 			" Remove sign 30 in group 'g3' from all the buffers
    753 			call sign_unplace('g3', {'id' : 30})
    754 
    755 			" Remove all the signs placed in buffer 5
    756 			call sign_unplace('*', {'buffer' : 5})
    757 
    758 			" Remove the signs in group 'g4' from all the buffers
    759 			call sign_unplace('g4')
    760 
    761 			" Remove sign 40 from all the buffers
    762 			call sign_unplace('*', {'id' : 40})
    763 
    764 			" Remove all the placed signs from all the buffers
    765 			call sign_unplace('*')
    766 
    767 <		Can also be used as a |method|: >
    768 			GetSigngroup()->sign_unplace()
    769 <
    770 		Return type: |Number|
    771 
    772 
    773 sign_unplacelist({list})				*sign_unplacelist()*
    774 		Remove previously placed signs from one or more buffers.  This
    775 		is similar to the |sign_unplace()| function.
    776 
    777 		The {list} argument specifies the List of signs to remove.
    778 		Each list item is a dict with the following sign attributes:
    779 		    buffer	buffer name or number.  For the accepted
    780 				values, see |bufname()|.  If not specified,
    781 				then the specified sign is removed from all
    782 				the buffers.
    783 		    group	sign group name.  If not specified or set to
    784 				an empty string, then the global sign group is
    785 				used.  If set to '*', then all the groups
    786 				including the global group are used.
    787 		    id		sign identifier.  If not specified, then all
    788 				the signs in the specified group are removed.
    789 
    790 		Returns a List where an entry is set to 0 if the corresponding
    791 		sign was successfully removed or -1 on failure.
    792 
    793 		Example: >
    794 			" Remove sign with id 10 from buffer a.vim and sign
    795 			" with id 20 from buffer b.vim
    796 			call sign_unplacelist([
    797 				\ {'id' : 10, 'buffer' : "a.vim"},
    798 				\ {'id' : 20, 'buffer' : 'b.vim'},
    799 				\ ])
    800 <
    801 		Can also be used as a |method|: >
    802 			GetSignlist()->sign_unplacelist()
    803 <
    804 		Return type: list<number> or list<any>
    805 
    806  vim:tw=78:ts=8:noet:ft=help:norl: