vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

tar.vim (30361B)


      1 " tar.vim: Handles browsing tarfiles -  AUTOLOAD PORTION
      2 " Date:		Mar 01, 2025
      3 " Version:	32b  (with modifications from the Vim Project)
      4 " Maintainer:	This runtime file is looking for a new maintainer.
      5 " Former Maintainer: Charles E Campbell
      6 " License:	Vim License  (see vim's :help license)
      7 " Last Change:
      8 "   2024 Jan 08 by Vim Project: fix a few problems (#138331, #12637, #8109)
      9 "   2024 Feb 19 by Vim Project: announce adoption
     10 "   2024 Nov 11 by Vim Project: support permissions (#7379)
     11 "   2025 Feb 06 by Vim Project: add support for lz4 (#16591)
     12 "   2025 Feb 28 by Vim Project: add support for bzip3 (#16755)
     13 "   2025 Mar 01 by Vim Project: fix syntax error in tar#Read()
     14 "   2025 Mar 02 by Vim Project: escape the filename before using :read
     15 "   2025 Mar 02 by Vim Project: determine the compression using readblob()
     16 "                               instead of shelling out to file(1)
     17 "   2025 Apr 16 by Vim Project: decouple from netrw by adding s:WinPath()
     18 "   2025 May 19 by Vim Project: restore working directory after read/write
     19 "   2025 Jul 13 by Vim Project: warn with path traversal attacks
     20 "   2025 Jul 16 by Vim Project: update minimum vim version
     21 "   2026 Feb 06 by Vim Project: consider 'nowrapscan' (#19333)
     22 "   2026 Feb 07 by Vim Project: make the path traversal detection more robust (#19341)
     23 "   2026 Apr 06 by Vim Project: fix bugs with lz4 support (#19925)
     24 "   2026 Apr 09 by Vim Project: fix bugs with zstd support (#19930)
     25 "   2026 Apr 09 by Vim Project: fix bug with dotted filename (#19930)
     26 "   2026 Apr 15 by Vim Project: fix more path traversal issues (#19981)
     27 "   2026 Apr 16 by Vim Project: use g:tar_secure in tar#Extract()
     28 "   2026 May 14 by Vim Project: use correct shellescape() call in Vimuntar()
     29 "   2026 Jun 16 by Vim Project: fix lz4 extraction on non-linux systemd (#20555)
     30 "
     31 "	Contains many ideas from Michael Toren's <tar.vim>
     32 "
     33 " Copyright:    Copyright (C) 2005-2017 Charles E. Campbell {{{1
     34 "               Permission is hereby granted to use and distribute this code,
     35 "               with or without modifications, provided that this copyright
     36 "               notice is copied with it. Like anything else that's free,
     37 "               tar.vim and tarPlugin.vim are provided *as is* and comes
     38 "               with no warranty of any kind, either expressed or implied.
     39 "               By using this plugin, you agree that in no event will the
     40 "               copyright holder be liable for any damages resulting from
     41 "               the use of this software.
     42 " ---------------------------------------------------------------------
     43 " Load Once: {{{1
     44 if &cp || exists("g:loaded_tar")
     45  finish
     46 endif
     47 let g:loaded_tar= "v32b"
     48 if v:versionlong < 9011024
     49  echohl WarningMsg
     50  echo "***warning*** this version of tar needs vim 9.1.1024"
     51  echohl Normal
     52  finish
     53 endif
     54 let s:keepcpo= &cpo
     55 set cpo&vim
     56 
     57 " ---------------------------------------------------------------------
     58 "  Default Settings: {{{1
     59 if !exists("g:tar_browseoptions")
     60  let g:tar_browseoptions= "tf"
     61 endif
     62 if !exists("g:tar_readoptions")
     63  let g:tar_readoptions= "pxf"
     64 endif
     65 if !exists("g:tar_cmd")
     66  let g:tar_cmd= "tar"
     67 endif
     68 if !exists("g:tar_writeoptions")
     69  let g:tar_writeoptions= "uf"
     70 endif
     71 if !exists("g:tar_delfile")
     72  " Note: not supported on BSD
     73  let g:tar_delfile="--delete -f"
     74 endif
     75 if !exists("g:netrw_cygwin")
     76  if has("win32") || has("win95") || has("win64") || has("win16")
     77   if &shell =~ '\%(\<bash\>\|\<zsh\>\)\%(\.exe\)\=$'
     78    let g:netrw_cygwin= 1
     79   else
     80    let g:netrw_cygwin= 0
     81   endif
     82  else
     83   let g:netrw_cygwin= 0
     84  endif
     85 endif
     86 if !exists("g:tar_copycmd")
     87  if !exists("g:netrw_localcopycmd")
     88   if has("win32") || has("win95") || has("win64") || has("win16")
     89    if g:netrw_cygwin
     90     let g:netrw_localcopycmd= "cp"
     91    else
     92     let g:netrw_localcopycmd= "copy"
     93    endif
     94   elseif has("unix") || has("macunix")
     95    let g:netrw_localcopycmd= "cp"
     96   else
     97    let g:netrw_localcopycmd= ""
     98   endif
     99  endif
    100  let g:tar_copycmd= g:netrw_localcopycmd
    101 endif
    102 if !exists("g:tar_extractcmd")
    103  let g:tar_extractcmd= "tar -pxf"
    104 endif
    105 
    106 " set up shell quoting character
    107 if !exists("g:tar_shq")
    108  if exists("+shq") && exists("&shq") && &shq != ""
    109   let g:tar_shq= &shq
    110  elseif has("win32") || has("win95") || has("win64") || has("win16")
    111   if exists("g:netrw_cygwin") && g:netrw_cygwin
    112    let g:tar_shq= "'"
    113   else
    114    let g:tar_shq= '"'
    115   endif
    116  else
    117   let g:tar_shq= "'"
    118  endif
    119 endif
    120 
    121 let g:tar_secure=' -- '
    122 let g:tar_leading_pat='\m^\%([.]\{,2\}/\)\+'
    123 
    124 " ----------------
    125 "  Functions: {{{1
    126 " ----------------
    127 
    128 " ---------------------------------------------------------------------
    129 " s:Msg: {{{2
    130 fun! s:Msg(func, severity, msg)
    131   redraw!
    132   if a:severity =~? 'error'
    133     echohl Error
    134   else
    135     echohl WarningMsg
    136   endif
    137   echo $"***{a:severity}*** ({a:func}) {a:msg}"
    138   echohl None
    139 endfunc
    140 
    141 " ---------------------------------------------------------------------
    142 " tar#Browse: {{{2
    143 fun! tar#Browse(tarfile)
    144   let repkeep= &report
    145   set report=10
    146 
    147   " sanity checks
    148   if !executable(g:tar_cmd)
    149    call s:Msg('tar#Browse', 'error', $"{g:tar_cmd} not available on your system")
    150    let &report= repkeep
    151    return
    152   endif
    153   if !filereadable(a:tarfile)
    154    if a:tarfile !~# '^\a\+://'
    155     " if it's an url, don't complain, let url-handlers such as vim do its thing
    156     call s:Msg('tar#Browse', 'error', $"File not readable<{a:tarfile}>")
    157    endif
    158    let &report= repkeep
    159    return
    160   endif
    161   if &ma != 1
    162    set ma
    163   endif
    164   let b:tarfile= a:tarfile
    165 
    166   setlocal noswapfile
    167   setlocal buftype=nofile
    168   setlocal bufhidden=hide
    169   setlocal nobuflisted
    170   setlocal nowrap
    171   set ft=tar
    172 
    173   " give header
    174   let lastline= line("$")
    175   call setline(lastline+1,'" tar.vim version '.g:loaded_tar)
    176   call setline(lastline+2,'" Browsing tarfile '.a:tarfile)
    177   call setline(lastline+3,'" Select a file with cursor and press ENTER, "x" to extract a file')
    178   keepj $put =''
    179   keepj sil! 0d
    180   keepj $
    181 
    182   let tarfile= a:tarfile
    183   if has("win32unix") && executable("cygpath")
    184    " assuming cygwin
    185    let tarfile=substitute(system("cygpath -u ".shellescape(tarfile,0)),'\n$','','e')
    186   endif
    187   let curlast= line("$")
    188 
    189   if tarfile =~# '\.\(gz\)$'
    190    exe "sil! r! gzip -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    191 
    192   elseif tarfile =~# '\.\(tgz\)$' || tarfile =~# '\.\(tbz\)$' || tarfile =~# '\.\(txz\)$' ||
    193                           \ tarfile =~# '\.\(tzst\)$' || tarfile =~# '\.\(tlz4\)$'
    194    let header= s:Header(tarfile)
    195 
    196    if header =~? 'bzip2'
    197     exe "sil! r! bzip2 -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    198    elseif header =~? 'bzip3'
    199     exe "sil! r! bzip3 -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    200    elseif header =~? 'xz'
    201     exe "sil! r! xz -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    202    elseif header =~? 'zstd'
    203     exe "sil! r! zstd --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    204    elseif header =~? 'lz4'
    205     exe "sil! r! lz4 --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    206    elseif header =~? 'gzip'
    207     exe "sil! r! gzip -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    208    endif
    209 
    210   elseif tarfile =~# '\.lrp'
    211    exe "sil! r! cat -- ".shellescape(tarfile,1)."|gzip -d -c -|".g:tar_cmd." -".g:tar_browseoptions." - "
    212   elseif tarfile =~# '\.\(bz2\|tbz\|tb2\)$'
    213    exe "sil! r! bzip2 -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    214   elseif tarfile =~# '\.\(bz3\|tb3\)$'
    215    exe "sil! r! bzip3 -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    216   elseif tarfile =~# '\.\(lzma\|tlz\)$'
    217    exe "sil! r! lzma -d -c -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    218   elseif tarfile =~# '\.\(xz\|txz\)$'
    219    exe "sil! r! xz --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    220   elseif tarfile =~# '\.\(zst\|tzst\)$'
    221    exe "sil! r! zstd --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    222   elseif tarfile =~# '\.\(lz4\|tlz4\)$'
    223    exe "sil! r! lz4 --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_browseoptions." - "
    224   else
    225    if tarfile =~ '^\s*-'
    226     " A file name starting with a dash is taken as an option.  Prepend ./ to avoid that.
    227     let tarfile = substitute(tarfile, '-', './-', '')
    228    endif
    229    exe "sil! r! ".g:tar_cmd." -".g:tar_browseoptions." ".shellescape(tarfile,1)
    230   endif
    231   if v:shell_error != 0
    232    call s:Msg('tar#Browse', 'warning', $"please check your g:tar_browseoptions '<{g:tar_browseoptions}>'")
    233    return
    234   endif
    235 
    236   " remove tar: Removing leading '/' from member names
    237   " Note: the message could be localized
    238   if search('\m^g\?tar: ', 'w') > 0 || search(g:tar_leading_pat, 'w') > 0
    239     call append(3,'" Note: Path Traversal Attack detected!')
    240     let b:leading_slash = 1
    241     " remove the message output
    242     sil g/^tar: /d
    243   endif
    244 
    245   " set up maps supported for tar
    246   setlocal noma nomod ro
    247   noremap <silent> <buffer>	<cr>		:call <SID>TarBrowseSelect()<cr>
    248   noremap <silent> <buffer>	x	 	:call tar#Extract()<cr>
    249   if &mouse != ""
    250    noremap <silent> <buffer>	<leftmouse>	<leftmouse>:call <SID>TarBrowseSelect()<cr>
    251   endif
    252 
    253   let &report= repkeep
    254 endfun
    255 
    256 " ---------------------------------------------------------------------
    257 " TarBrowseSelect: {{{2
    258 fun! s:TarBrowseSelect()
    259   let repkeep= &report
    260   set report=10
    261   let fname= getline(".")
    262   let ls= get(b:, 'leading_slash', 0)
    263 
    264   " sanity check
    265   if fname =~ '^"'
    266    let &report= repkeep
    267    return
    268   endif
    269 
    270   " about to make a new window, need to use b:tarfile
    271   let tarfile= b:tarfile
    272   let curfile= expand("%")
    273   if has("win32unix") && executable("cygpath")
    274    " assuming cygwin
    275    let tarfile=substitute(system("cygpath -u ".shellescape(tarfile,0)),'\n$','','e')
    276   endif
    277 
    278   " open a new window (tar#Read will read a file into it)
    279   noswapfile new
    280   if !exists("g:tar_nomax") || g:tar_nomax == 0
    281    wincmd _
    282   endif
    283   let s:tblfile_{winnr()}= curfile
    284   let b:leading_slash= ls
    285   call tar#Read("tarfile:".tarfile.'::'.fname)
    286   filetype detect
    287   set nomod
    288   exe 'com! -buffer -nargs=? -complete=file TarDiff	:call tar#Diff(<q-args>,"'.fnameescape(fname).'")'
    289 
    290   let &report= repkeep
    291 endfun
    292 
    293 " ---------------------------------------------------------------------
    294 " tar#Read: {{{2
    295 fun! tar#Read(fname)
    296   let repkeep= &report
    297   set report=10
    298   let tarfile = substitute(a:fname,'tarfile:\(.\{-}\)::.*$','\1','')
    299   let fname   = substitute(a:fname,'tarfile:.\{-}::\(.*\)$','\1','')
    300   " be careful not to execute special crafted files
    301   let escape_file = fname->substitute(g:tar_leading_pat, '', '')->fnameescape()
    302 
    303   let curdir= getcwd()
    304   let b:curdir= curdir
    305   let tmpdir= tempname()
    306   let b:tmpdir= tmpdir
    307   if tmpdir =~ '\.'
    308    let tmpdir= substitute(tmpdir,'\.[^.]*$','','e')
    309   endif
    310   call mkdir(tmpdir,"p")
    311 
    312   " attempt to change to the indicated directory
    313   try
    314    exe "lcd ".fnameescape(tmpdir)
    315   catch /^Vim\%((\a\+)\)\=:E344/
    316    call s:Msg('tar#Read', 'error', "cannot lcd to temporary directory")
    317    let &report= repkeep
    318    return
    319   endtry
    320 
    321   " place temporary files under .../_ZIPVIM_/
    322   if isdirectory("_ZIPVIM_")
    323    call s:Rmdir("_ZIPVIM_")
    324   endif
    325   call mkdir("_ZIPVIM_")
    326   lcd _ZIPVIM_
    327 
    328   if has("win32unix") && executable("cygpath")
    329    " assuming cygwin
    330    let tarfile=substitute(system("cygpath -u ".shellescape(tarfile,0)),'\n$','','e')
    331   endif
    332 
    333   if  fname =~ '\.bz2$' && executable("bzcat")
    334    let decmp= "|bzcat"
    335    let doro = 1
    336   elseif  fname =~ '\.bz3$' && executable("bz3cat")
    337    let decmp= "|bz3cat"
    338    let doro = 1
    339   elseif  fname =~ '\.t\=gz$'  && executable("zcat")
    340    let decmp= "|zcat"
    341    let doro = 1
    342   elseif  fname =~ '\.lzma$' && executable("lzcat")
    343    let decmp= "|lzcat"
    344    let doro = 1
    345   elseif  fname =~ '\.xz$' && executable("xzcat")
    346    let decmp= "|xzcat"
    347    let doro = 1
    348   elseif  fname =~ '\.zst$' && executable("zstdcat")
    349    let decmp= "|zstdcat"
    350    let doro = 1
    351   elseif  fname =~ '\.lz4$' && executable("lz4cat")
    352    let decmp= "|lz4cat"
    353    let doro = 1
    354   else
    355    let decmp=""
    356    let doro = 0
    357    if fname =~ '\.bz2$\|\.bz3$\|\.gz$\|\.lzma$\|\.xz$\|\.zip$\|\.Z$'
    358     setlocal bin
    359    endif
    360   endif
    361 
    362 
    363   if tarfile =~# '\.bz2$'
    364    exe "sil! r! bzip2 -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    365    exe "read ".escape_file
    366   elseif tarfile =~# '\.bz3$'
    367    exe "sil! r! bzip3 -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    368    exe "read ".escape_file
    369   elseif tarfile =~# '\.\(gz\)$'
    370    exe "sil! r! gzip -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    371    exe "read ".escape_file
    372   elseif tarfile =~# '\(\.tgz\|\.tbz\|\.txz\)'
    373    let filekind= s:Header(tarfile)
    374    if filekind =~? "bzip2"
    375     exe "sil! r! bzip2 -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    376     exe "read ".escape_file
    377    elseif filekind =~ "bzip3"
    378     exe "sil! r! bzip3 -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    379     exe "read ".escape_file
    380    elseif filekind =~? "xz"
    381     exe "sil! r! xz -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    382     exe "read ".escape_file
    383    elseif filekind =~? "zstd"
    384     exe "sil! r! zstd --decompress --stdout -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    385     exe "read ".escape_file
    386    elseif filekind =~? "gzip"
    387     exe "sil! r! gzip -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    388     exe "read ".escape_file
    389    endif
    390 
    391   elseif tarfile =~# '\.lrp$'
    392    exe "sil! r! cat -- ".shellescape(tarfile,1)." | gzip -d -c - | ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    393    exe "read ".escape_file
    394   elseif tarfile =~# '\.lzma$'
    395    exe "sil! r! lzma -d -c -- ".shellescape(tarfile,1)."| ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    396    exe "read ".escape_file
    397   elseif tarfile =~# '\.\(xz\|txz\)$'
    398    exe "sil! r! xz --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    399    exe "read ".escape_file
    400   elseif tarfile =~# '\.\(lz4\|tlz4\)$'
    401    exe "sil! r! lz4 --decompress --stdout -- ".shellescape(tarfile,1)." | ".g:tar_cmd." -".g:tar_readoptions." - ".g:tar_secure.shellescape(fname,1).decmp
    402    exe "read ".escape_file
    403   else
    404    if tarfile =~ '^\s*-'
    405     " A file name starting with a dash is taken as an option.  Prepend ./ to avoid that.
    406     let tarfile = substitute(tarfile, '-', './-', '')
    407    endif
    408    exe "silent r! ".g:tar_cmd." -".g:tar_readoptions.shellescape(tarfile,1)." ".g:tar_secure.shellescape(fname,1).decmp
    409    exe "read ".escape_file
    410   endif
    411   if get(b:, 'leading_slash', 0)
    412     sil g/^tar: /d
    413   endif
    414 
    415    redraw!
    416 
    417   if v:shell_error != 0
    418    lcd ..
    419    call s:Rmdir("_ZIPVIM_")
    420    exe "lcd ".fnameescape(curdir)
    421    call s:Msg('tar#Read', 'error', $"sorry, unable to open or extract {tarfile} with {fname}")
    422   endif
    423 
    424   if doro
    425    " because the reverse process of compressing changed files back into the tarball is not currently supported
    426    setlocal ro
    427   endif
    428 
    429   let b:tarfile= a:fname
    430 
    431   " cleanup
    432   keepj sil! 0d
    433   set nomod
    434 
    435   let &report= repkeep
    436   exe "lcd ".fnameescape(curdir)
    437   silent exe "file tarfile::". fname->fnameescape()
    438 endfun
    439 
    440 " ---------------------------------------------------------------------
    441 " tar#Write: {{{2
    442 fun! tar#Write(fname)
    443   let pwdkeep= getcwd()
    444   let repkeep= &report
    445   set report=10
    446   let curdir= b:curdir
    447   let tmpdir= b:tmpdir
    448 
    449   " sanity checks
    450   if !executable(g:tar_cmd)
    451    redraw!
    452    let &report= repkeep
    453    return
    454   endif
    455   let tarfile = substitute(b:tarfile,'tarfile:\(.\{-}\)::.*$','\1','')
    456   let fname   = substitute(b:tarfile,'tarfile:.\{-}::\(.*\)$','\1','')
    457 
    458   if get(b:, 'leading_slash', 0)
    459    call s:Msg('tar#Write', 'error', $"sorry, not attempting to update {tarfile} with {fname}")
    460    let &report= repkeep
    461    return
    462   endif
    463 
    464   if !isdirectory(fnameescape(tmpdir))
    465     call mkdir(fnameescape(tmpdir), 'p')
    466   endif
    467   exe $"lcd {fnameescape(tmpdir)}"
    468   if isdirectory("_ZIPVIM_")
    469     call s:Rmdir("_ZIPVIM_")
    470   endif
    471   call mkdir("_ZIPVIM_")
    472   lcd _ZIPVIM_
    473   let dir = fnamemodify(fname, ':p:h')
    474   if dir !~# '_ZIPVIM_$'
    475     call mkdir(dir)
    476   endif
    477 
    478   " handle compressed archives
    479   if tarfile =~# '\.bz2'
    480    call system("bzip2 -d -- ".shellescape(tarfile,0))
    481    let tarfile = substitute(tarfile,'\.bz2','','e')
    482    let compress= "bzip2 -- ".shellescape(tarfile,0)
    483   elseif tarfile =~# '\.bz3'
    484    call system("bzip3 -d -- ".shellescape(tarfile,0))
    485    let tarfile = substitute(tarfile,'\.bz3','','e')
    486    let compress= "bzip3 -- ".shellescape(tarfile,0)
    487   elseif tarfile =~# '\.gz'
    488    call system("gzip -d -- ".shellescape(tarfile,0))
    489    let tarfile = substitute(tarfile,'\.gz','','e')
    490    let compress= "gzip -- ".shellescape(tarfile,0)
    491   elseif tarfile =~# '\.tgz'
    492    call system("gzip -d -- ".shellescape(tarfile,0))
    493    let tarfile = substitute(tarfile,'\.tgz','.tar','e')
    494    let compress= "gzip -- ".shellescape(tarfile,0)
    495    let tgz     = 1
    496   elseif tarfile =~# '\.xz'
    497    call system("xz -d -- ".shellescape(tarfile,0))
    498    let tarfile = substitute(tarfile,'\.xz','','e')
    499    let compress= "xz -- ".shellescape(tarfile,0)
    500   elseif tarfile =~# '\.zst'
    501    call system("zstd --decompress --rm -- ".shellescape(tarfile,0))
    502    let tarfile = substitute(tarfile,'\.zst','','e')
    503    let compress= "zstd --rm -- ".shellescape(tarfile,0)
    504   elseif tarfile =~# '\.lz4'
    505    call system("lz4 --decompress --rm -- ".shellescape(tarfile,0))
    506    let tarfile = substitute(tarfile,'\.lz4','','e')
    507    let compress= "lz4 --rm -- ".shellescape(tarfile,0)
    508   elseif tarfile =~# '\.lzma'
    509    call system("lzma -d -- ".shellescape(tarfile,0))
    510    let tarfile = substitute(tarfile,'\.lzma','','e')
    511    let compress= "lzma -- ".shellescape(tarfile,0)
    512   endif
    513   " Note: no support for name.tar.tbz/.txz/.tgz/.tlz4/.tzst
    514 
    515   if v:shell_error != 0
    516    call s:Msg('tar#Write', 'error', $"sorry, unable to update {tarfile} with {fname}")
    517   else
    518 
    519    if fname =~ '/'
    520     let dirpath = substitute(fname,'/[^/]\+$','','e')
    521     if has("win32unix") && executable("cygpath")
    522      let dirpath = substitute(system("cygpath ".shellescape(dirpath, 0)),'\n','','e')
    523     endif
    524     call mkdir(dirpath,"p")
    525    endif
    526    if tarfile !~ '/'
    527     let tarfile= curdir.'/'.tarfile
    528    endif
    529    if tarfile =~ '^\s*-'
    530     " A file name starting with a dash may be taken as an option.  Prepend ./ to avoid that.
    531     let tarfile = substitute(tarfile, '-', './-', '')
    532    endif
    533 
    534    " don't overwrite a file forcefully
    535    exe "w ".fnameescape(fname)
    536    if has("win32unix") && executable("cygpath")
    537     let tarfile = substitute(system("cygpath ".shellescape(tarfile,0)),'\n','','e')
    538    endif
    539 
    540    " delete old file from tarfile
    541    " Note: BSD tar does not support --delete flag
    542    call system(g:tar_cmd." ".g:tar_delfile." ".shellescape(tarfile,0).g:tar_secure.shellescape(fname,0))
    543    if v:shell_error != 0
    544     call s:Msg('tar#Write', 'error', $"sorry, unable to update {fnameescape(tarfile)} with {fnameescape(fname)} --delete not supported?")
    545    else
    546     " update tarfile with new file
    547     call system(g:tar_cmd." -".g:tar_writeoptions." ".shellescape(tarfile,0).g:tar_secure.shellescape(fname,0))
    548     if v:shell_error != 0
    549      call s:Msg('tar#Write', 'error', $"sorry, unable to update {fnameescape(tarfile)} with {fnameescape(fname)}")
    550     elseif exists("compress")
    551      call system(compress)
    552      if exists("tgz")
    553       call rename(tarfile.".gz",substitute(tarfile,'\.tar$','.tgz','e'))
    554      endif
    555     endif
    556    endif
    557 
    558    " support writing tarfiles across a network
    559    if s:tblfile_{winnr()} =~ '^\a\+://'
    560     let tblfile= s:tblfile_{winnr()}
    561     1split|noswapfile enew
    562     let binkeep= &l:binary
    563     let eikeep = &ei
    564     set binary ei=all
    565     exe "noswapfile e! ".fnameescape(tarfile)
    566     call netrw#NetWrite(tblfile)
    567     let &ei       = eikeep
    568     let &l:binary = binkeep
    569     q!
    570     unlet s:tblfile_{winnr()}
    571    endif
    572   endif
    573 
    574   " cleanup and restore current directory
    575   lcd ..
    576   call s:Rmdir("_ZIPVIM_")
    577   exe "lcd ".fnameescape(pwdkeep)
    578   setlocal nomod
    579 
    580   let &report= repkeep
    581 endfun
    582 
    583 " ---------------------------------------------------------------------
    584 " tar#Diff: {{{2
    585 fun! tar#Diff(userfname,fname)
    586   let fname= a:fname
    587   if a:userfname != ""
    588    let fname= a:userfname
    589   endif
    590   exe "lcd ".fnameescape(b:tmpdir). '/_ZIPVIM_'
    591   if filereadable(fname)
    592    " sets current file (from tarball) for diff'ing
    593    " splits window vertically
    594    " opens original file, sets it for diff'ing
    595    " sets up b:tardiff_otherbuf variables so each buffer knows about the other (for closing purposes)
    596    diffthis
    597    wincmd v
    598    exe "noswapfile e ".fnameescape(fname)
    599    diffthis
    600   else
    601    redraw!
    602    echo "***warning*** unable to read file<".fname.">"
    603   endif
    604 endfun
    605 
    606 " ---------------------------------------------------------------------
    607 " tar#Extract: extract a file from a (possibly compressed) tar archive {{{2
    608 fun! tar#Extract()
    609 
    610   let repkeep= &report
    611   set report=10
    612   let fname= getline(".")
    613 
    614   " sanity check
    615   if fname =~ '^"'
    616    let &report= repkeep
    617    return
    618   endif
    619   if fname =~ '^[.]\?[.]/' || simplify(fname) =~ '\.\.[/\\]'
    620    call s:Msg('tar#Extract', 'error', "Path Traversal Attack detected, not extracting!")
    621    let &report= repkeep
    622    return
    623   endif
    624   if has("unix")
    625    if fname =~ '^/'
    626     call s:Msg('tar#Extract', 'error', "Path Traversal Attack detected, not extracting!")
    627     let &report= repkeep
    628     return
    629    endif
    630   else
    631    if fname =~ '^\%(\a:[\\/]\|[\\/]\)'
    632     call s:Msg('tar#Extract', 'error', "Path Traversal Attack detected, not extracting!")
    633     let &report= repkeep
    634     return
    635    endif
    636   endif
    637 
    638   let extractcmd= s:WinPath(g:tar_extractcmd)
    639   let tarball = expand("%")
    640   if !filereadable(tarball)
    641    let &report= repkeep
    642    return
    643   endif
    644 
    645   if tarball =~# "\.tar$"
    646    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    647    if v:shell_error != 0
    648     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    649    else
    650     echo "***note*** successfully extracted ". fname
    651    endif
    652 
    653   elseif tarball =~# "\.tgz$"
    654    let extractcmd= substitute(extractcmd,"-","-z","")
    655    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    656    if v:shell_error != 0
    657     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    658    else
    659     echo "***note*** successfully extracted ".fname
    660    endif
    661 
    662   elseif tarball =~# "\.tar\.gz$"
    663    let extractcmd= substitute(extractcmd,"-","-z","")
    664    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    665    if v:shell_error != 0
    666     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    667    else
    668     echo "***note*** successfully extracted ".fname
    669    endif
    670 
    671   elseif tarball =~# "\.tbz$"
    672    let extractcmd= substitute(extractcmd,"-","-j","")
    673    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    674    if v:shell_error != 0
    675     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    676    else
    677     echo "***note*** successfully extracted ".fname
    678    endif
    679 
    680   elseif tarball =~# "\.tar\.bz2$"
    681    let extractcmd= substitute(extractcmd,"-","-j","")
    682    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    683    if v:shell_error != 0
    684     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    685    else
    686     echo "***note*** successfully extracted ".fname
    687    endif
    688 
    689   elseif tarball =~# "\.tar\.bz3$"
    690    let extractcmd= substitute(extractcmd,"-","-j","")
    691    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    692    if v:shell_error != 0
    693     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    694    else
    695     echo "***note*** successfully extracted ".fname
    696    endif
    697 
    698   elseif tarball =~# "\.txz$"
    699    let extractcmd= substitute(extractcmd,"-","-J","")
    700    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    701    if v:shell_error != 0
    702     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    703    else
    704     echo "***note*** successfully extracted ".fname
    705    endif
    706 
    707   elseif tarball =~# "\.tar\.xz$"
    708    let extractcmd= substitute(extractcmd,"-","-J","")
    709    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    710    if v:shell_error != 0
    711     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    712    else
    713     echo "***note*** successfully extracted ".fname
    714    endif
    715 
    716   elseif tarball =~# "\.tzst$"
    717    let extractcmd= substitute(extractcmd,"-","--zstd -","")
    718    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    719    if v:shell_error != 0
    720     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    721    else
    722     echo "***note*** successfully extracted ".fname
    723    endif
    724 
    725   elseif tarball =~# "\.tar\.zst$"
    726    let extractcmd= substitute(extractcmd,"-","--zstd -","")
    727    call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    728    if v:shell_error != 0
    729     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    730    else
    731     echo "***note*** successfully extracted ".fname
    732    endif
    733 
    734   elseif tarball =~# "\.tlz4$"
    735    if has("linux")
    736     let extractcmd= substitute(extractcmd,"-","-I lz4 -","")
    737     call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    738    else
    739     call system("lz4 --decompress --stdout -- ".shellescape(tarball)." | ".extractcmd." - ".g:tar_secure.shellescape(fname))
    740    endif
    741    if v:shell_error != 0
    742     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    743    else
    744     echo "***note*** successfully extracted ".fname
    745    endif
    746 
    747   elseif tarball =~# "\.tar\.lz4$"
    748    if has("linux")
    749     let extractcmd= substitute(extractcmd,"-","-I lz4 -","")
    750     call system(extractcmd." ".shellescape(tarball)." ".g:tar_secure.shellescape(fname))
    751    else
    752     call system("lz4 --decompress --stdout -- ".shellescape(tarball)." | ".extractcmd." - ".g:tar_secure.shellescape(fname))
    753    endif
    754    if v:shell_error != 0
    755     call s:Msg('tar#Extract', 'error', $"{extractcmd} {tarball} {fname}: failed!")
    756    else
    757     echo "***note*** successfully extracted ".fname
    758    endif
    759   endif
    760 
    761   " restore option
    762   let &report= repkeep
    763 endfun
    764 
    765 " ---------------------------------------------------------------------
    766 " s:Rmdir: {{{2
    767 fun! s:Rmdir(fname)
    768   call delete(a:fname, 'rf')
    769 endfun
    770 
    771 " s:FileHeader: {{{2
    772 fun! s:Header(fname)
    773   let header= readblob(a:fname, 0, 6)
    774   if header[0:2] == str2blob(['BZh']) " bzip2 header
    775     return "bzip2"
    776   elseif header[0:2] == str2blob(['BZ3']) " bzip3 header
    777     return "bzip3"
    778   elseif header == str2blob(["\3757zXZ\n"]) " xz header
    779     return "xz"
    780   elseif header[0:3] == str2blob(["\x28\xB5\x2F\xFD"]) " zstd header
    781     return "zstd"
    782   elseif header[0:3] == str2blob(["\004\"M\030"]) " lz4 header
    783     return "lz4"
    784   elseif (header[0:1] == str2blob(["\037\235"]) ||
    785        \  header[0:1] == str2blob(["\037\213"]) ||
    786        \  header[0:1] == str2blob(["\037\236"]) ||
    787        \  header[0:1] == str2blob(["\037\240"]) ||
    788        \  header[0:1] == str2blob(["\037\036"]))
    789     return "gzip"
    790   endif
    791   return "unknown"
    792 endfun
    793 
    794 " ---------------------------------------------------------------------
    795 " s:WinPath: {{{2
    796 fun! s:WinPath(path)
    797   if (!g:netrw_cygwin || &shell !~ '\%(\<bash\>\|\<zsh\>\)\%(\.exe\)\=$') && has("win32")
    798     " remove cygdrive prefix, if present
    799     let path = substitute(a:path, '/cygdrive/\(.\)', '\1:', '')
    800     " remove trailing slash (Win95)
    801     let path = substitute(path, '\(\\\|/\)$', '', 'g')
    802     " remove escaped spaces
    803     let path = substitute(path, '\ ', ' ', 'g')
    804     " convert slashes to backslashes
    805     let path = substitute(path, '/', '\', 'g')
    806   else
    807     let path = a:path
    808   endif
    809 
    810   return path
    811 endfun
    812 
    813 " ---------------------------------------------------------------------
    814 " tar#Vimuntar: installs a tarball in the user's .vim / vimfiles directory {{{2
    815 fun! tar#Vimuntar(...)
    816   let tarball = expand("%")
    817   let tarbase = substitute(tarball,'\..*$','','')
    818   let tarhome = expand("%:p")
    819   if has("win32") || has("win95") || has("win64") || has("win16")
    820    let tarhome= substitute(tarhome,'\\','/','g')
    821   endif
    822   let tarhome= substitute(tarhome,'/[^/]*$','','')
    823   let tartail = expand("%:t")
    824   let curdir  = getcwd()
    825   " set up vimhome
    826   if a:0 > 0 && a:1 != ""
    827    let vimhome= a:1
    828   else
    829    let vimhome= vimball#VimballHome()
    830   endif
    831 
    832   if simplify(curdir) != simplify(vimhome)
    833    " copy (possibly compressed) tarball to .vim/vimfiles
    834    call system(s:WinPath(g:tar_copycmd)." ".shellescape(tartail)." ".shellescape(vimhome))
    835    exe "lcd ".fnameescape(vimhome)
    836   endif
    837 
    838   " if necessary, decompress the tarball; then, extract it
    839   if tartail =~ '\.tgz'
    840    if executable("gunzip")
    841     silent exe "!gunzip ".shellescape(tartail, 1)
    842    elseif executable("gzip")
    843     silent exe "!gzip -d ".shellescape(tartail, 1)
    844    else
    845     echoerr "unable to decompress<".tartail."> on this system"
    846     if simplify(curdir) != simplify(tarhome)
    847      " remove decompressed tarball, restore directory
    848      call delete(tartail.".tar")
    849      exe "lcd ".fnameescape(curdir)
    850     endif
    851     return
    852    endif
    853   else
    854    call vimball#Decompress(tartail,0)
    855   endif
    856   let extractcmd= s:WinPath(g:tar_extractcmd)
    857   call system(extractcmd." ".shellescape(tarbase.".tar"))
    858 
    859   " set up help
    860   if filereadable("doc/".tarbase.".txt")
    861    exe "helptags ".getcwd()."/doc"
    862   endif
    863 
    864   if simplify(tarhome) != simplify(vimhome)
    865    " remove decompressed tarball, restore directory
    866    call delete(vimhome."/".tarbase.".tar")
    867    exe "lcd ".fnameescape(curdir)
    868   endif
    869 endfun
    870 
    871 " =====================================================================
    872 " Modelines And Restoration: {{{1
    873 let &cpo= s:keepcpo
    874 unlet s:keepcpo
    875 " vim:ts=8 fdm=marker