vim

Fork of vim, an acceptable text editor
git clone git://git.laack.co/vim.git
Log | Files | Refs | README | LICENSE

vim9.vim (4437B)


      1 vim9script
      2 
      3 # Vim runtime support library
      4 #
      5 # Maintainer:   The Vim Project <https://github.com/vim/vim>
      6 # Last Change:  2026 Jul 01
      7 
      8 export def IsSafeExecutable(filetype: string, executable: string): bool
      9   if empty(exepath(executable))
     10     return v:false
     11   endif
     12   var cwd = getcwd()
     13   return get(g:, filetype .. '_exec', get(g:, 'plugin_exec', 0))
     14     && (fnamemodify(exepath(executable), ':p:h') !=# cwd
     15       || (split($PATH, has('win32') ? ';' : ':')->index(cwd) != -1
     16         && cwd != '.'))
     17 enddef
     18 
     19 def Redir(): string
     20   if get(g:, 'netrw_suppress_gx_mesg', true)
     21     if &srr =~# "%s"
     22       return printf(&srr, has("win32") ? "nul" : "/dev/null")
     23     elseif &srr =~# '>&\?$'
     24       return &srr .. (has("win32") ? "nul" : "/dev/null")
     25     else
     26       return &srr .. (has("win32") ? "> nul" : "> /dev/null")
     27     endif
     28   endif
     29   return ''
     30 enddef
     31 
     32 if has('unix')
     33   if has('win32unix')
     34     # Cygwin provides cygstart
     35     if executable('cygstart')
     36       export def Launch(args: string)
     37         execute $'silent ! cygstart --hide {args} {Redir()}' | redraw!
     38       enddef
     39     elseif !empty($MSYSTEM) && executable('start')
     40       # MSYS2/Git Bash comes by default without cygstart; see
     41       # https://www.msys2.org/wiki/How-does-MSYS2-differ-from-Cygwin
     42       # Instead it provides /usr/bin/start script running `cmd.exe //c start`
     43       # Adding "" //b` sets void title, hides cmd window and blocks path conversion
     44       # of /b to \b\ " by MSYS2; see https://www.msys2.org/docs/filesystem-paths/
     45       export def Launch(args: string)
     46         execute $'silent !start "" //b {args} {Redir()}' | redraw!
     47       enddef
     48     else
     49       # imitate /usr/bin/start script for other environments and hope for the best
     50       export def Launch(args: string)
     51         execute $'silent !cmd /c start "" /b {args} {Redir()}' | redraw!
     52       enddef
     53     endif
     54   elseif exists('$WSL_DISTRO_NAME') && executable('cmd.exe') # use cmd.exe to start GUI apps in WSL
     55     export def Launch(args: string)
     56       const command = (args =~? '\v<\f+\.(exe|com|bat|cmd)>')
     57         ? $'cmd.exe /c start /b {args} {Redir()}'
     58         : $'nohup {args} {Redir()} &'
     59       execute $'silent ! {command}' | redraw!
     60     enddef
     61   else
     62     export def Launch(args: string)
     63       # Use job_start, because using !xdg-open is known not to work with zsh
     64       # ignore signals on exit
     65       job_start(['sh', '-c', args], {'stoponexit': '', 'in_io': 'null', 'out_io': 'null', 'err_io': 'null'})
     66     enddef
     67   endif
     68 elseif has('win32')
     69   export def Launch(args: string)
     70     try
     71       execute ':silent !start' args | redraw!
     72     catch /^Vim(!):E371:/
     73       echohl ErrorMsg
     74       echom "dist#vim9#Launch(): can not start" args
     75       echohl None
     76     endtry
     77   enddef
     78 else
     79   export def Launch(dummy: string)
     80     echom 'No common launcher found'
     81   enddef
     82 endif
     83 
     84 var os_viewer = null_string
     85 # Git Bash
     86 if has('win32unix')
     87   # (cyg)start suffices
     88   os_viewer = ''
     89 # Windows
     90 elseif has('win32')
     91   os_viewer = '' # Use :!start
     92 # MacOS
     93 elseif has('osx')
     94   os_viewer = 'open'
     95 # WSL
     96 elseif executable('explorer.exe')
     97   os_viewer = 'explorer.exe'
     98 # Linux / BSD
     99 elseif executable('xdg-open')
    100   os_viewer = 'xdg-open'
    101 endif
    102 
    103 def Viewer(): string
    104   # g:Openprg could be a string of program + its arguments, test if first
    105   # argument is executable
    106   var user_viewer = get(g:, "Openprg", get(g:, "netrw_browsex_viewer", ""))
    107 
    108   # Take care of an off-by-one check for "for" too
    109   if executable(trim(user_viewer))
    110     return user_viewer
    111   endif
    112 
    113   var args = split(user_viewer, '\s\+\zs')
    114   var viewer = get(args, 0, '')
    115 
    116   for arg in args[1 :]
    117     if executable(trim(viewer))
    118       return user_viewer
    119     endif
    120 
    121     viewer ..= arg
    122   endfor
    123 
    124   if os_viewer == null
    125     echoerr "No program to open this path found. See :help Open for more information."
    126   endif
    127 
    128   return os_viewer
    129 enddef
    130 
    131 export def Open(file: string)
    132   # disable shellslash for shellescape, required on Windows #17995
    133   if exists('+shellslash') && &shellslash
    134     defer setbufvar('%', '&shellslash', true)
    135     &shellslash = false
    136   endif
    137   if &shell == 'pwsh' || &shell == 'powershell'
    138     defer setbufvar('%', '&shell', &shell)
    139     setlocal shell&
    140   endif
    141   if has('unix') && !has('win32unix') && !exists('$WSL_DISTRO_NAME')
    142     Launch($"{Viewer()} {shellescape(file)}")
    143   else
    144     Launch($"{Viewer()} {shellescape(file, 1)}")
    145   endif
    146 enddef
    147 
    148 # Uncomment this line to check for compilation errors early
    149 # defcompile
    150 
    151 # vim: ts=8 sts=2 sw=2 et